K線數(shù)據(jù)，可以只寫開頭第一個(gè)字母。
開盤價(jià):OPEN;{O}
收盤價(jià):CLOSE;{C}
最高價(jià):HIGH;{H}
最低價(jià):LOW;{L}
大盤K線數(shù)據(jù)，必須下載完整盤后數(shù)據(jù)。Drawkline——畫K線，數(shù)據(jù)順序——最高價(jià)、開盤價(jià)、最低價(jià)、收盤價(jià)。
DRAWKLINE(INDEXH,INDEXO,INDEXL,INDEXC);
{H、O、L、C}
上漲家數(shù)和下跌家數(shù)，第一組只在大盤窗口才有數(shù)據(jù)，第二組哪個(gè)窗口都有數(shù)據(jù)。
漲家1:ADVANCE;
跌家1:DECLINE;
漲家2:INDEXADV;
跌家2:INDEXDEC;
在一定周期內(nèi)某項(xiàng)數(shù)據(jù)的最大值——hhv，在一定周期內(nèi)某項(xiàng)數(shù)據(jù)的最小值——llv。
HH:HHV(H,10);
LL:LLV(L,10);
MA1:MA(C,5);
HHMA:HHV(MA1,10);
LLMA:LLV(MA1,10);
創(chuàng)新高或者創(chuàng)新低。
創(chuàng)新高:H=HHV(H,60);
創(chuàng)新低:L=LLV(L,60);
當(dāng)前位置取得以前位置數(shù)據(jù)——ref，取得指定日期數(shù)據(jù)——refdate，注意日期的格式。
以前數(shù)據(jù):REF(C,1);
{以前數(shù)據(jù):REF(H,2);}
指定日期數(shù)據(jù):REFDATE(C,1090508);
{1998年5月25日——980525、2011年12月8日——1111208}
成交量——vol，可寫成V，單位是手。成交金額——amount，單位是元。Indexv——大盤成交量， indexa——大盤成交金額。Buyvol——外盤
， sellvol——內(nèi)盤，只能取得與最后一根K線相對(duì)應(yīng)的數(shù)據(jù)。
成交量:VOL;{V}
成交金額:=AMOUNT;
大盤成交量:=INDEXV;
大盤成交金額:=INDEXA;
外盤:BUYVOL;
內(nèi)盤:SELLVOL;
漲幅、振幅、均價(jià)，成交量復(fù)權(quán)：工具——系統(tǒng)設(shè)置——設(shè)置1——勾選“分析圖成交量復(fù)權(quán)”——按確定——再按確定——退出K線圖——重
新進(jìn)入K線圖。
漲幅:=(C-REF(C,1))/REF(C,1)*100;
振幅:=(H-L)/L*100;
均價(jià)1:(H+L+O+C)/4;
均價(jià)2:AMOUNT/(V*100);
即時(shí)行情函數(shù)只取得與最后一根K線相對(duì)應(yīng)的數(shù)據(jù)。
振幅1:DYNAINFO(13)*100;
振幅2:(H-L)/L*100;
finance(7)的單位是股，根據(jù)流通盤變化而變化。capital的單位是手，只取得最新流通盤。
流通盤1:FINANCE(7);
流通盤2:CAPITAL;
換手率，finance(7)寫的換手率更合理。
換手率1:V*100/FINANCE(7)*100;
換手率2:V/CAPITAL*100;
FINANCE(42)——上市日期，date——日期，date加19六個(gè)0，一號(hào)的日為0， year——年份，month——月份，day——日，weekday——星期。
上市日期:FINANCE(42);
日期1:DATE;
日期2:DATE+19000000;
年:YEAR;
月:MONTH;
日:DAY;
日期3:YEAR*10000+MONTH*100+DAY;
星期:WEEKDAY;
Time——時(shí)間，hour——小時(shí)，MINUTE——分鐘，只在日線以下周期有效。FROMOPEN——當(dāng)前時(shí)刻距離開盤分鐘數(shù)。
時(shí)間:TIME;
小時(shí):HOUR;
分鐘:MINUTE;
距開盤分鐘數(shù):FROMOPEN;
BARSCOUNT——某數(shù)據(jù)從第一個(gè)有效值到現(xiàn)在的周期數(shù)，TOTALBARSCOUNT——總周期數(shù)，下載完整盤后數(shù)據(jù)、不連接行情使用。CURRBARSCOUNT
——當(dāng)前K線到最后交易日周期數(shù)。
有效數(shù)據(jù)周期數(shù):BARSCOUNT(C);
總周期數(shù):TOTALBARSCOUNT;
到最后周期數(shù):CURRBARSCOUNT;
Cross——是否發(fā)生交叉，兩條指標(biāo)線不一定全是變化的曲線。Barslast——上一次條件成立到當(dāng)前的周期數(shù)，BARSSINCE——第一次條件成立
到當(dāng)前的周期數(shù)，count——統(tǒng)計(jì)在一定周期內(nèi)滿足條件的周期數(shù)。
K1:KDJ.K;
D1:KDJ.D;
金叉:CROSS(K1,D1)*10;
死叉:CROSS(D1,K1)*-10;
{K1上穿60:CROSS(K1,60);
K1下穿20:CROSS(20,K1);}
上次到現(xiàn)周期數(shù):BARSLAST(金叉);
首次到現(xiàn)周期數(shù):BARSSINCE(金叉),NODRAW;
統(tǒng)計(jì){N周期內(nèi)滿足條件}次數(shù):COUNT(金叉=10,20);
Hhvbars——某數(shù)據(jù)在一定周期內(nèi)的最大值到當(dāng)前的周期數(shù)，llvbars——某數(shù)據(jù)在一定周期內(nèi)的最小值到當(dāng)前的周期數(shù)。
上一高點(diǎn){到現(xiàn)在}周期:HHVBARS(H,20);
上一低點(diǎn){到現(xiàn)在}周期:LLVBARS(L,20);
某數(shù)據(jù)是近多少周期內(nèi)的最大值——TOPRANGE，某數(shù)據(jù)是近多少周期內(nèi)的最小值——LOWRANGE。
多少周期的最大:TOPRANGE(H);
多少周期的最小:LOWRANGE(L);
BARSLASTCOUNT——統(tǒng)計(jì)連續(xù)滿足條件的周期數(shù)，sumbars——某數(shù)據(jù)向前累加到指定值到當(dāng)前的周期數(shù)。
統(tǒng)計(jì){連續(xù)滿足條件}周期數(shù):BARSLASTCOUNT(C>REF(C,1));
加到指定值周期:SUMBARS(V,CAPITAL);
PERIOD——當(dāng)前窗口的周期類型。
窗口周期類型:PERIOD;
在不同周期類型使用不同參數(shù)。
參數(shù):=IF(PERIOD=5,20,IF(PERIOD=6,10,0));
MA1:MA(C,參數(shù));
最基本的比較判斷是用大于、小于、等于等等。某數(shù)據(jù)是否在某個(gè)范圍之內(nèi)——RANGE，某數(shù)據(jù)是否在某個(gè)范圍——BETWEEN。
寬幅震蕩:(H-L)/L*100>12;
是否在某個(gè)范圍1:RANGE(C,8,10);{X>A AND A<B}
是否在某個(gè)范圍2:BETWEEN(C,10,13);{X>=A AND X<=B};
是否發(fā)生交叉——cross，LONGCROSS——是否維持一定周期后發(fā)生交叉。
上穿:CROSS(MA(C,5),MA(C,10));
{持續(xù)}一段時(shí)間后上穿:LONGCROSS(MA(C,5),MA(C,10),10)*2;
UPNDAY——某數(shù)據(jù)在一定周期內(nèi)是否連漲，DOWNNDAY——某數(shù)據(jù)在一定周期內(nèi)是否連跌，NDAY——是否在一定周期內(nèi)前面的數(shù)據(jù)都大于后面的
數(shù)據(jù)，ISLASTBAR——當(dāng)前周期是否是最后一個(gè)周期。
連漲:UPNDAY(C,5);
連跌:DOWNNDAY(C,5);
連大:NDAY(C,O,5);
是否最后周期:ISLASTBAR;
EXIST——是否在一定周期內(nèi)存在符合某種條件的情況，EVERY——是否在一定周期內(nèi)一直存在符合條件的情況，LAST——是否在某一段周期內(nèi)
一直存在符合某種條件的情況，not——是否不符合條件。
存在:EXIST(C>REF(C,1)*1.099,10);
一直存在:EVERY(C>O,5);
持續(xù)存在:LAST(C>O,10,5);
并非:NOT(C>O);
If——是否符合條件，符合條件輸出前面的數(shù)據(jù)，不符合條件輸出后面的數(shù)據(jù)， max——哪個(gè)更大輸出哪個(gè)，min——哪個(gè)更小輸出哪個(gè)。
條件:=CROSS(MA(C,5),MA(C,10));
如果:IF(條件,5,-5);
較大者:MAX(C,O);
較小者:MIN(C,O);
FILTER——過濾連續(xù)出現(xiàn)的信號(hào)。
J大于80:"KDJ.J">80;
過濾:FILTER(J大于80,10)*2;
Abs——取得數(shù)據(jù)的絕對(duì)值，sum——求的數(shù)據(jù)在一定周期內(nèi)的總和。
漲幅:(C-REF(C,1))/REF(C,1)*100;
零軸:0;
絕對(duì)值:ABS(漲幅);
求和:SUM(漲幅,5);
Ma——簡(jiǎn)單移動(dòng)平均值，ema——指數(shù)移動(dòng)平均值，sma——加權(quán)移動(dòng)平均值（前面參數(shù)大于后面參數(shù)），dma——?jiǎng)討B(tài)移動(dòng)平均值（參數(shù)小于1
），后面三個(gè)函數(shù)降低本周期的權(quán)重、減少波動(dòng)性而使輸出變得相對(duì)平滑穩(wěn)定，同時(shí)也降低了靈敏度。
簡(jiǎn)單移動(dòng)平均:MA(C,5);{(C0+C1+C2+…+C(N-1))/N}
指數(shù)移動(dòng)平均:EMA(C,5);{Y=2*X/(N+1)+(N-1)/(N+1)*Y',Y'上一周期Y}
加權(quán)移動(dòng)平均:SMA(C,5{N},1{M});{Y=(M*X+(N-M)*Y')/N, Y'上一周期Y,N必須大于M}
動(dòng)態(tài)移動(dòng)平均:DMA(C,0.5);{Y=N*X+(1-N)*Y',Y'上一周期Y,N必須小于1};
LINETHICK——粗細(xì)，color——顏色，stick——柱狀線，CROSSDOT——小交叉線，CIRCLEDOT——小圓圈線，POINTDOT——小圓點(diǎn)線。
MA1:MA(C,5);
MA2:MA(C,20),LINETHICK3,COLORRED;
均線差值1:(MA1-MA2)*1,STICK;
均線差值2:(MA1-MA2)*3,CROSSDOT;
均線差值3:(MA1-MA2)*6,CIRCLEDOT;
均線差值4:(MA1-MA2)*9,POINTDOT;
LINESTICK——指標(biāo)線加柱狀線。
MA1:=MA(C,5);
MA2:=MA(C,10);
均線差值:MA1-MA2,LINESTICK;
COLORSTICK——彩色柱狀線。
MA1:=MA(C,5);
MA2:=MA(C,10);
均線差值:MA1-MA2,COLORSTICK;
VOLSTICK——成交量柱狀線。
MA1:=MA(C,5);
MA2:=MA(C,10);
均線差值:MA1-MA2,VOLSTICK;
DRAWTEXT——寫文字（必須寫在一對(duì)單引號(hào)內(nèi)），DRAWICON——畫圖標(biāo)。
MA1:MA(C,5);
MA2:MA(C,10);
金叉:=CROSS(MA1,MA2);
寫文字:DRAWTEXT(金叉,MA1,'金叉');
畫圖標(biāo):DRAWICON(金叉,MA2,1);
STICKLINE——畫柱線，0實(shí)心柱，-1虛線空心柱，1實(shí)線空心柱。后面的輸出會(huì)遮擋住前面的輸出。
MA5:MA(C,5);
畫柱線1:STICKLINE(C>O,C,O,2,0);
畫柱線2:STICKLINE(C>O,H,L,0,0),COLORBLUE;
畫柱線3:STICKLINE(C<O,H,L,1,1);
畫柱線4:STICKLINE(C<O,C,O,3,-1);
MA10:MA(C,10),COLORGREEN;
DRAWLINE——繪制直線段，0不延長(zhǎng)，1向右延長(zhǎng)。PLOYLINE——繪制折線。
畫直線:DRAWLINE(L=LLV(L,10),L,H=HHV(H,10),H,0);
畫折線:PLOYLINE(H=HHV(H,30),H);
均線變色，DRAWNULL——返回?zé)o效值。nodraw——只輸出數(shù)值、不輸出線條，不影響公式坐標(biāo)。LINETHICK0——只輸出數(shù)值、不輸出線條，在
其它軟件中不影響公式坐標(biāo)，在通達(dá)信中影響公式坐標(biāo)。
MA1:MA(C,5);
MA2:MA(C,10);
變色:IF(MA1>REF(MA1,1),MA1,DRAWNULL),LINETHICK2,COLORRED;
成交量:V,NODRAW;
MA1:MA(C,5);
MA2:MA(C,10);
變色:IF(MA1>MA2,MA1,DRAWNULL),LINETHICK2,COLORRED;
成交量:V,LINETHICK0;
Winner——獲利盤，cost——成本分布情況。
獲利盤:WINNER(C)*100;
成本分布:COST(80);
Zig——之字轉(zhuǎn)向，1最高價(jià)、2最低價(jià)、3收盤價(jià)。PEAK——波峰價(jià)格，1最高價(jià)、2最低價(jià)、3收盤價(jià)。TROUGH——波谷價(jià)格，1最高價(jià)、2最低價(jià)
、3收盤價(jià)。
之字轉(zhuǎn)向:ZIG(3,10);
波峰:PEAK(3,10,1);
波谷:TROUGH(3,10,1);
波峰到現(xiàn)在的周期數(shù)——PEAKBARS，波谷到現(xiàn)在的周期數(shù)——TROUGHBARS。
波峰到現(xiàn)在周期:PEAKBARS(3,10,1);
波谷到現(xiàn)在周期:TROUGHBARS(3,10,1);
BACKSET——回設(shè)，馬后炮。
MA10:MA(C,10);
回設(shè):=BACKSET(C/REF(C,1)>1.09,2);
A:=IF(REF(回設(shè),1)=0 AND 回設(shè)=1,1,0);
DRAWICON(A,L*0.98,1);
跨周期引用的公式也具有未來性質(zhì)。
周J:"KDJ.J#WEEK";
周D:"KDJ.D#WEEK";
金叉:CROSS(周J,周D)*30;
還有一種作弊手法——將公式信號(hào)限制在有行情的時(shí)段發(fā)出。
另外一種作弊:O<REF(C,1) AND DATE=1080918;
建議暫時(shí)關(guān)閉本教程，把講義中這一節(jié)的內(nèi)容挨個(gè)復(fù)制到你自己的軟件中，按照這一節(jié)開始時(shí)所講的函數(shù)學(xué)習(xí)方法復(fù)習(xí)一遍。
要將自己的思路用公式去表達(dá)出來，首先是確定需要哪些數(shù)據(jù)，然后觀察這些數(shù)據(jù)之間的關(guān)系，再按語(yǔ)句規(guī)則的要求用函數(shù)去定義觀察到的關(guān)
系。
{K線形態(tài)}
陰線:C<O;
陽(yáng)線:C>O;
上漲:C>REF(C,1);
下跌:C<REF(C,1);
平盤:C=REF(C,1);
大陽(yáng)線:C/REF(C,1)>1.05;
大陰線:C/REF(C,1)<0.95;
高開:O>REF(C,1);
低開:O<REF(C,1);
高開高走:O>REF(C,1) AND C>O;
高開低走:O>REF(C,1) AND C<O;
低開低走:O<REF(C,1) AND C<O;
低開高走:O<REF(C,1) AND C>O;
上跳空:L>REF(H,1);
下跳空:H<REF(L,1);
長(zhǎng)上影:H/MAX(O,C)>1.03;
長(zhǎng)下影:MIN(O,C)/L>1.03;
十字星:MAX(O,C)/MIN(O,C)<1.02 AND H/MAX(O,C)>1.01 AND MIN(O,C)/L>1.01;
正T字:O=C AND C=H AND L<H;
倒T字:O=C AND C=L AND H>L;
一字漲停:O=C AND C=H AND L=H AND C>REF(C,1);
一字跌停:O=C AND C=L AND L=H AND C<REF(C,1);
橫盤:HHV(H,20)/LLV(L,20)<1.15;
均線狀況——金叉和死叉。
MA1:MA(C,5);
MA2:MA(C,10);
金叉:CROSS(MA1,MA2);
死叉:CROSS(MA2,MA1);
均線上拐、下拐、將死未死。
MA1:MA(C,5);
MA2:MA(C,10);
上拐:=REF(MA1,1)<REF(MA1,2) AND MA1>REF(MA1,1);
下拐:=REF(MA1,1)>REF(MA1,2) AND MA1<REF(MA1,1);
將死未死:=COUNT(MA1>MA2,5)=5 AND 上拐;
DRAWICON(上拐,MA1*0.98,1);
DRAWICON(下拐,MA1*1.01,2);
DRAWICON(將死未死,MA1*0.96,11);
多頭排列、空頭排列。
MA1:MA(C,5);
MA2:MA(C,10);
MA3:MA(C,20);
多頭排列:=MA1>MA2 AND MA2>MA3;
空頭排列:=MA1<MA2 AND MA2<MA3;
STICKLINE(多頭排列,MA1,MA3,0,0),COLORRED;
STICKLINE(空頭排列,MA1,MA3,0,0),COLORGREEN;
均線粘合、粘合一段時(shí)間。
MA1:MA(C,5);
MA2:MA(C,10);
MA3:MA(C,20);
粘合:=MAX(MAX(MA1,MA2),MA3)/MIN(MIN(MA1,MA2),MA3)<1.02;
粘合一段時(shí)間:=COUNT(粘合,10)=10;
STICKLINE(粘合,MAX(MAX(MA1,MA2),MIN(MIN(MA1,MA2),MA3)),MA3,1,0),COLORRED;
DRAWICON(粘合一段時(shí)間,MA3*0.98,1);
三金叉。
DIF2:"MACD.DIF";
DEA2:"MACD.DEA";
單金叉:CROSS(DIF2,DEA2);
三金叉:(單金叉 AND COUNT(單金叉,10)>=3)*2;
成交量狀況——主要觀察成交量之間、成交量與均量線之間以及換手率之間的關(guān)系。放量、歷史天量。
放量1:V>REF(V,1)*2;
放量2:V>MA(V,60);
放量3:V*100/FINANCE(7)*100>8;
歷史天量:V=HHV(V,0);
連續(xù)放量。
連續(xù)放量1:COUNT(V>REF(V,1),5)=5;
連續(xù)放量2:(COUNT(V>MA(V,60),5)=5)*2;
連續(xù)放量3:(COUNT(V*100/FINANCE(7)*100>8,5)=5)*3;
縮量、歷史地量。
縮量1:V<REF(V,1)*0.5;
縮量2:V<MA(V,60);
縮量3:V*100/FINANCE(7)*100<1;
歷史地量:V=LLV(V,0);
連續(xù)縮量。
連續(xù)縮量1:COUNT(V<REF(V,1),5)=5;
連續(xù)縮量2:(COUNT(V<MA(V,60),5)=5)*2;
連續(xù)縮量3:(COUNT(V*100/FINANCE(7)*100<1,5)=5)*3;
籌碼低位密集。
籌碼密集:=(WINNER(C*1.1)-WINNER(C*0.9))*100>50;
相對(duì)低位:=(C-COST(0.01))/(COST(99.99)-COST(0.01))*100<10;
低位密集:籌碼密集 AND 相對(duì)低位;
聯(lián)系客服
