（特別感謝匯編高手 dREAMtHEATER 對我的代碼作出了相當好的優(yōu)化！請參觀他的主頁）上一節(jié)我們介紹了花指令，不過花指令畢竟是一種很簡單的東西，基本上入了門的Cracker都可以對付得了。所以，我們很有必要給自己的軟件加上更好的保護。CRC校驗就是其中的一種不錯的方法。
CRC是什么東西呢？其實我們大家都不應(yīng)該會對它陌生，回憶一下？你用過RAR和ZIP等壓縮軟件嗎？它們是不是常常會給你一個惱人的“CRC校驗錯誤”信息呢？我想你應(yīng)該明白了吧，CRC就是塊數(shù)據(jù)的計算值，它的全稱是“Cyclic Redundancy Check”，中文名是“循環(huán)冗余碼”，“CRC校驗”就是“循環(huán)冗余校驗”。（哇，真拗口，希望大家不要當我是唐僧，呵呵。^_^）
CRC有什么用呢？它的應(yīng)用范圍很廣泛，最常見的就是在網(wǎng)絡(luò)傳輸中進行信息的校對。其實我們大可以把它應(yīng)用到軟件保護中去，因為它的計算是非常非常非常嚴格的。嚴格到什么程度呢？你的程序只要被改動了一個字節(jié)（甚至只是大小寫的改動），它的值就會跟原來的不同。Hoho，是不是很厲害呢？所以只要給你的“原”程序計算好CRC值，儲存在某個地方，然后在程序中隨機地再對文件進行CRC校驗，接著跟第一次生成并保存好的CRC值進行比較，如果相等的話就說明你的程序沒有被修改/破解過，如果不等的話，那么很可能你的程序遭到了病毒的感染，或者被Cracker用16進制工具暴力破解過了。
廢話說完了，我們先來看看CRC的原理。
（由于CRC實現(xiàn)起來有一定的難度，所以具體怎樣用它來保護文件，留待下一節(jié)再講。）
首先看兩個式子：
式一：9 / 3 = 3 （余數(shù) = 0）
式二：(9 + 2 ) / 3 = 3 （余數(shù) = 2）
在小學(xué)里我們就知道，除法運算就是將被減數(shù)重復(fù)地減去除數(shù)X次，然后留下余數(shù)。
所以上面的兩個式子可以用二進制計算為：（什么？你不會二進制計算？我倒～～～）
式一：
1001 --> 9
0011 - --> 3
---------
0110 --> 6
0011 - --> 3
---------
0011 --> 3
0011 - --> 3
---------
0000 --> 0，余數(shù)
一共減了3次，所以商是3，而最后一次減出來的結(jié)果是0，所以余數(shù)為0
式二：
1011 --> 11
0011 - --> 3
---------
1000 --> 8
0011 - --> 3
---------
0101 --> 5
0011 - --> 3
---------
0010 --> 2,余數(shù)
一共減了3次，所以商是3，而最后一次減出來的結(jié)果是2，所以余數(shù)為2
看明白了吧？很好，let’s go on!
二進制減法運算的規(guī)則是，如果遇到0-1的情況，那么要從高位借1，就變成了(10+0)-1=1
CRC運算有什么不同呢？讓我們看下面的例子：
這次用式子30 / 9，不過請讀者注意最后的余數(shù)：
11110 --> 30
1001 - --> 9
---------
1100 --> 12 （很奇怪吧？為什么不是21呢？）
1001 - --> 9
--------
101 --> 3，余數(shù) --> the CRC!
這個式子的計算過程是不是很奇怪呢？它不是直接減的，而是用XOR的方式來運算（程序員應(yīng)該都很熟悉XOR吧），最后得到一個余數(shù)。
對啦，這個就是CRC的運算方法，明白了嗎？CRC的本質(zhì)是進行XOR運算，運算的過程我們不用管它，因為運算過程對最后的結(jié)果沒有意義；我們真正感興趣的只是最終得到的余數(shù)，這個余數(shù)就是CRC值。
進行一個CRC運算我們需要選擇一個除數(shù)，這個除數(shù)我們叫它為“poly”，寬度W就是最高位的位置，所以我剛才舉的例子中的除數(shù)9，這個poly 1001的W是3，而不是4，注意最高位總是1。（別問為什么，這個是規(guī)定）
如果我們想計算一個位串的CRC碼，我們想確定每一個位都被處理過，因此，我們要在目標位串后面加上W個0位?，F(xiàn)在讓我們根據(jù)CRC的規(guī)范來改寫一下上面的例子：
Poly = 1001，寬度W = 3
位串Bitstring = 11110
Bitstring + W zeroes = 11110 + 000 = 11110000
11110000
1001|||| -
-------------
1100|||
1001||| -
------------
1010||
1001|| -
-----------
0110|
0000| -
----------
1100
1001 -
---------
101 --> 3，余數(shù) --> the CRC!
還有兩點重要聲明如下：
1、只有當Bitstring的最高位為1，我們才將它與poly進行XOR運算，否則我們只是將Bitstring左移一位。
2、XOR運算的結(jié)果就是被操作位串Bitstring與poly的低W位進行XOR運算，因為最高位總為0。
呵呵，是不是有點頭暈?zāi)X脹的感覺了？看不懂的話，再從頭看一遍，其實是很好理解的。（就是一個XOR運算嘛！）
好啦，原理介紹到這里，下面我講講具體怎么編程。
由于速度的關(guān)系，CRC的實現(xiàn)主要是通過查表法，對于CRC-16和CRC-32，各自有一個現(xiàn)成的表，大家可以直接引入到程序中使用。（由于這兩個表太長，在這里不列出來了，請讀者自行在網(wǎng)絡(luò)上查找，很容易找到的。）
如果我們沒有這個表怎么辦呢？或者你跟我一樣，懶得自己輸入？不用急，我們可以“自己動手，豐衣足食”。
你可能會說，自己編程來生成這個表，會不會太慢了？其實大可不必擔心，因為我們是在匯編代碼的級別進行運算的，而這個表只有區(qū)區(qū)256個雙字，根本影響不了速度。
這個表的C語言描述如下：
for (i = 0; i < 256; i++)
{
crc = i;
for (j = 0; j < 8; j++)
{
if (crc & 1)
crc = (crc >> 1) ^ 0xEDB88320;
else
crc >>= 1;
}
crc32tbl[i] = crc;
}
生成表之后，就可以進行運算了。
我們的算法如下：
1、將寄存器向右邊移動一個字節(jié)。
2、將剛移出的那個字節(jié)與我們的字符串中的新字節(jié)進行XOR運算，得出一個指向值表table[0..255]的索引。
3、將索引所指的表值與寄存器做XOR運算。
4、如果數(shù)據(jù)沒有全部處理完，則跳到步驟1。
這個算法的C語言描述如下：
temp = (oldcrc ^ abyte) & 0x000000FF;
crc = (( oldcrc >> 8) & 0x00FFFFFF) ^ crc32tbl[temp];
return crc;
好啦，所有的東東都說完啦，最后獻上一個完整的Win32Asm例子，請讀者仔細研究吧！
（匯編方面的CRC-32資料極少啊，我個人認為下面給出的是很寶貴的資料。）
;***********************************************************************************************
;程序名稱：演示CRC32原理
;作者：羅聰
;日期：2002-8-24
;出處：http://laoluoc.yeah.net（老羅的繽紛天地）
;注意事項：如欲轉(zhuǎn)載，請保持本程序的完整，并注明：轉(zhuǎn)載自“老羅的繽紛天地”（http://laoluoc.yeah.net）
;
;特別感謝Win32ASM高手—— dREAMtHEATER 為我的代碼作了相當好的優(yōu)化！
;請各位前去 http://NoteXPad.yeah.net 下載他的小巧的“cool 記事本”—— NoteXPad 來試用?。?00% Win32ASM 編寫）
;
;***********************************************************************************************
.386
.model flat, stdcall
option casemap:none
include windows.inc
include kernel32.inc
include user32.inc
includelib kernel32.lib
includelib user32.lib
WndProc proto :DWORD, :DWORD, :DWORD, :DWORD
init_crc32table proto
arraycrc32 proto
.const
IDC_BUTTON_OPEN equ 3000
IDC_EDIT_INPUT equ 3001
.data
szDlgName db "lc_dialog", 0
szTitle db "CRC demo by LC", 0
szTemplate db "字符串 ""%s"" 的 CRC32 值是：%X", 0
crc32tbl dd 256 dup(0) ;CRC-32 table
szBuffer db 255 dup(0)
.data?
szText db 300 dup(?)
.code
main:
invoke GetModuleHandle, NULL
invoke DialogBoxParam, eax, offset szDlgName, 0, WndProc, 0
invoke ExitProcess, eax
WndProc proc uses ebx hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
.if uMsg == WM_CLOSE
invoke EndDialog, hWnd, 0
.elseif uMsg == WM_COMMAND
mov eax,wParam
mov edx,eax
shr edx,16
movzx eax, ax
.if edx == BN_CLICKED
.IF eax == IDCANCEL
invoke EndDialog, hWnd, NULL
.ELSEIF eax == IDC_BUTTON_OPEN || eax == IDOK
;******************************************
;關(guān)鍵代碼開始：（當當當當……）
;******************************************
;取得用戶輸入的字符串：
invoke GetDlgItemText, hWnd, IDC_EDIT_INPUT, addr szBuffer, 255
;初始化crc32table：
invoke init_crc32table
;下面賦值給寄存器ebx，以便進行crc32轉(zhuǎn)換：
;EBX是待轉(zhuǎn)換的字符串的首地址：
lea ebx, szBuffer
;進行crc32轉(zhuǎn)換：
invoke arraycrc32
;格式化輸出：
invoke wsprintf, addr szText, addr szTemplate, addr szBuffer, eax
;好啦，讓我們顯示結(jié)果：
invoke MessageBox, hWnd, addr szText, addr szTitle, MB_OK
.ENDIF
.endif
.ELSE
mov eax,FALSE
ret
.ENDIF
mov eax,TRUE
ret
WndProc endp
;**********************************************************
;函數(shù)功能：生成CRC-32表
;**********************************************************
init_crc32table proc
;如果用C語言來表示，應(yīng)該如下：
;
; for (i = 0; i < 256; i++)
; {
; crc = i;
; for (j = 0; j < 8; j++)
; {
; if (crc & 1)
; crc = (crc >> 1) ^ 0xEDB88320;
; else
; crc >>= 1;
; }
; crc32tbl[i] = crc;
; }
;
;呵呵，讓我們把上面的語句改成assembly的：
mov ecx, 256 ; repeat for every DWORD in table
mov edx, 0EDB88320h
$BigLoop:
lea eax, [ecx-1]
push ecx
mov ecx, 8
$SmallLoop:
shr eax, 1
jnc @F
xor eax, edx
@@:
dec ecx
jne $SmallLoop
pop ecx
mov [crc32tbl+ecx*4-4], eax
dec ecx
jne $BigLoop
ret
init_crc32table endp
;**************************************************************
;函數(shù)功能：計算CRC-32
;**************************************************************
arraycrc32 proc
;計算 CRC-32 ，我采用的是把整個字符串當作一個數(shù)組，然后把這個數(shù)組的首地址賦值給 EBX，把數(shù)組的長度賦值給 ECX，然后循環(huán)計算，返回值（計算出來的 CRC-32 值）儲存在 EAX 中：
;
; 參數(shù)：
; EBX = address of first byte
; 返回值：
; EAX = CRC-32 of the entire array
; EBX = ?
; ECX = 0
; EDX = ?
mov eax, -1 ; 先初始化eax
or ebx, ebx
jz $Done ; 避免出現(xiàn)空指針
@@:
mov dl, [ebx]
or dl, dl
je $Done ;判斷是否對字符串掃描完畢
;這里我用查表法來計算 CRC-32 ，因此非?？焖伲?/font>
;因為這是assembly代碼，所以不需要給這個過程傳遞參數(shù)，只需要把oldcrc賦值給EAX，以及把byte賦值給DL：
;
; 在C語言中的形式：
;
; temp = (oldcrc ^ abyte) & 0x000000FF;
; crc = (( oldcrc >> 8) & 0x00FFFFFF) ^ crc32tbl[temp];
;
; 參數(shù)：
; EAX = old CRC-32
; DL = a byte
; 返回值：
; EAX = new CRC-32
; EDX = ?
xor dl, al
movzx edx, dl
shr eax, 8
xor eax, [crc32tbl+edx*4]
inc ebx
jmp @B
$Done:
not eax
ret
arraycrc32 endp
end main
;*************************** over ***************************************
;by LC
下面是它的.rc文件：
#include "resource.h"
#define IDC_BUTTON_OPEN 3000
#define IDC_EDIT_INPUT 3001
#define IDC_STATIC -1
LC_DIALOG DIALOGEX 10, 10, 195, 60
STYLE DS_SETFONT | DS_CENTER | WS_MINIMIZEBOX | WS_VISIBLE | WS_CAPTION |
WS_SYSMENU
CAPTION "lc’s assembly framework"
FONT 9, "宋體", 0, 0, 0x0
BEGIN
LTEXT "請輸入一個字符串（區(qū)分大小寫）：",IDC_STATIC,11,7,130,10
EDITTEXT IDC_EDIT_INPUT,11,20,173,12,ES_AUTOHSCROLL
DEFPUSHBUTTON "Ca&lc",IDC_BUTTON_OPEN,71,39,52,15
END
如果你能夠完全理解本節(jié)的內(nèi)容，那么請留意我的下一講，我將具體介紹如何運用CRC-32對你的文件進行保護。（呵呵，好戲在后頭……）
