国产一级a片免费看高清,亚洲熟女中文字幕在线视频,黄三级高清在线播放,免费黄色视频在线看

'**************************************************
  '函數(shù)ID：0020[創(chuàng)建MsAccess數(shù)據(jù)庫]
  '函數(shù)名：CrDb_MsAccess
  '作 用：創(chuàng)建MsAccess數(shù)據(jù)庫
  '參 數(shù)：DbPath ---- 目標目錄信息
  '參 數(shù)：DbFileName ---- 目標庫文件名稱
  '參 數(shù)：DbUpwd ---- 目標庫打開密碼
  '返回值：建立成功返回 True 否則 False
  '**************************************************
  Public Function CrDb_MsAccess(ByVal DbPath,ByVal DbFileName,ByVal DbUpwd)
   CrDb_MsAccess=False
   On Error GoTo 0
   On Error Resume Next
   DIM fxztxt,fu_fu_db_str,fu_db_str
   fxztxt=Chr(60)&"%Response.end()%"&Chr(62)
   If Right(DbPath,1)<>"\" Then DbPath=DbPath & "\"
   fu_fu_db_str="Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&DbPath&"temp.mdb;"
   fu_db_str ="Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&DbPath&DbFileName&";Jet OLEDB:Database Password="&DbUpwd&";"
   Set fu_Ca = Server.CreateObject("ADOX.Catalog")
   fu_Ca.Create fu_fu_db_str
   Set fu_Ca = Nothing
   Set fu_Je = Server.CreateObject("JRO.JetEngine")
   fu_Je.CompactDatabase fu_fu_db_str,fu_db_str
   Set fu_fso = CreateObject("Scripting.FileSystemObject")
   fu_fso.DeleteFile(DbPath&"temp.mdb")
   Set fu_Je = Nothing
   Set fu_fso = Nothing
   set fu_Conn =server.createobject("ADODB.Connection")
   set fu_Rs =server.createobject("ADODB.Recordset")
   fu_Conn.open fu_db_str
   fu_Sql_Str="CREATE TABLE [0] ([0] Text DEFAULT Notxt NOT NULL,[11] int IDENTITY (1, 1) NOT NULL PRIMARY KEY)"
   fu_Conn.Execute(fu_Sql_Str)
   fu_Sql_Str="Select * From [0]"
   fu_Rs.open fu_Sql_Str,fu_Conn,1,3
   fu_Rs.addnew
   fu_Rs("0")=fxztxt
   fu_Rs.update
   fu_Rs.Close
   fu_Conn.Close
   Set fu_Rs = Nothing
   Set fu_Conn = Nothing
   If Err.Number = 0 Then
   CrDb_MsAccess=True
   End If
   On Error GoTo 0
  End function
  '**************************************************
  '函數(shù)ID：0021[創(chuàng)建MsSQLServer數(shù)據(jù)庫]
  '函數(shù)名：CrDb_MsSQLServer
  '作 用：創(chuàng)建MsSQLServer數(shù)據(jù)庫
  '參 數(shù)：DbIp ---- 數(shù)據(jù)庫所在IP或主機名稱
  '參 數(shù)：DbSamc ---- 數(shù)據(jù)庫超管用戶名稱
  '參 數(shù)：DbSapwd---- 數(shù)據(jù)庫超管用戶口令
  '參 數(shù)：DbName ---- 新建數(shù)據(jù)庫名稱
  '參 數(shù)：DbUpmc ---- 新建數(shù)據(jù)庫所屬用戶名稱
  '參 數(shù)：DbUpwd ---- 新建數(shù)據(jù)庫所屬用戶密碼
  '返回值：建立成功返回 True 否則 False
  '**************************************************
  Public Function CrDb_MsSQLServer(ByVal DbIp,ByVal DbSamc,ByVal DbSapwd,ByVal DbName,ByVal DbUpmc,ByVal DbUpwd)
   CrDb_MsSQLServer=False
   On Error GoTo 0
   On Error Resume Next
   DIM fu_Sa_Str,fu_Ua_Str,fu_Conn,fu_Rs,fu_Sql_Str,fxztxt
   fxztxt=Chr(60)&"%Response.end()%"&Chr(62)
   fu_Sa_Str ="DRIVER=SQL Server;UID="&DbSamc&";DATABASE=master;SERVER="&DbIp&";PWD="&DbSapwd&";"
   fu_Ua_Str ="DRIVER=SQL Server;UID="&DbUpmc&";DATABASE="&DbName&";SERVER="&DbIp&";PWD="&DbUpwd&";"
   Set fu_Conn = Server.CreateObject("ADODB.Connection")
   fu_Conn.Open fu_Sa_Str
   fu_Conn.Execute "CREATE DATABASE " &DbName
   fu_Conn.Close
   fu_DB_Conn_Str="DRIVER=SQL Server;UID="&DbSamc&";DATABASE="&DbName&";SERVER="&DbIp&";PWD="&DbSapwd&";"
   fu_Conn.Open fu_DB_Conn_Str
   fu_Sql_Str="EXEC sp_addlogin '"&DbUpmc&"','"&DbUpwd&"','"&DbName&"'"
   fu_Conn.Execute fu_Sql_Str
   fu_Sql_Str="EXEC sp_grantdbaccess '"&DbUpmc&"'"
   fu_Conn.Execute fu_Sql_Str
   fu_Sql_Str="EXEC sp_addrolemember 'db_owner', '"&DbUpmc&"'"
   fu_Conn.Execute fu_Sql_Str
   fu_Sql_Str="EXEC sp_defaultdb "&DbUpmc&","&DbName
   fu_Conn.Execute fu_Sql_Str
   fu_Conn.Close
   fu_Conn.open fu_Ua_Str
   fu_Sql_Str="CREATE TABLE [0] ([0] Text DEFAULT ('Notxt') NOT NULL,[11] int IDENTITY (1, 1) NOT NULL PRIMARY KEY)"
   fu_Conn.Execute fu_Sql_Str
   Set fu_Rs=server.createobject("ADODB.Recordset")
   fu_Sql_Str="Select * From [0]"
   fu_Rs.open fu_Sql_Str,fu_Conn,1,3
   fu_Rs.addnew
   fu_Rs("0")=fxztxt
   fu_Rs.update
   fu_Rs.Close
   fu_Conn.Close
   Set fu_Rs = Nothing
   Set fu_Conn=Nothing
   If Err.Number = 0 Then
   CrDb_MsSQLServer=True
   End If
   On Error GoTo 0
  End function
  '**************************************************
  '函數(shù)ID：0022[通過JMAIL發(fā)信]
  '函數(shù)名：MSMail
  '作 用：通過JMAIL發(fā)信
  '參 數(shù)：subject ---- 郵件的標題
  '參 數(shù)：mailaddress ---- 郵件服務(wù)器地址
  '參 數(shù)：senderName ---- 發(fā)件人名稱
  '參 數(shù)：email ---- 收件人E-MAIL地址
  '參 數(shù)：content ---- 郵件內(nèi)容
  '參 數(shù)：fromer ---- 發(fā)件人E-MAIL地址
  '參 數(shù)：serEmailUser ---- 郵件服務(wù)器權(quán)限用戶名
  '參 數(shù)：serEmailPass ---- 郵件服務(wù)器權(quán)限用戶密碼
  '返回值：發(fā)送成功返回 True 否則 False
  '示 例：MSMail("test","smtp.163.com","mzy","mzymcm@yahoo.com.cn","test","mzymcm@163.com","mzymcm","abcmzy1029abc")
  '**************************************************
  Public Function MSMail(ByVal subject, ByVal mailaddress, ByVal senderName, ByVal email, ByVal content, ByVal fromer, ByVal serEmailUser, ByVal serEmailPass)
   dim JmailMsg
   MSMail=False
   set JmailMsg=server.createobject("jmail.message")
   JmailMsg.mailserverusername=serEmailUser
   JmailMsg.mailserverpassword=serEmailPass
   JmailMsg.addrecipient email
   JmailMsg.from=fromer
   JmailMsg.fromname=senderName
   JmailMsg.charset="gb2312"
   JmailMsg.logging=true
   JmailMsg.silent=true
   JmailMsg.subject=Subject
   JmailMsg.body=Server.HTMLEncode(content)
   JmailMsg.htmlbody=content
   if not JmailMsg.send(mailaddress) then
   MSMail=False
   else
   MSMail=True
   end if
   JmailMsg.close
   set JmailMsg=nothing
  End function
  '**************************************************
  '函數(shù)ID：0023[測試組件是否安裝]
  '函數(shù)名：IsObjInstalled
  '作 用：測試組件是否安裝
  '參 數(shù)：strClassString ---- 組件名稱或標識字串
  '返回值：測試成功返回 True 否則 False
  '示 例：IsObjInstalled("JMAIL.Message")
  '************************************

**************
  Public Function IsObjInstalled(ByVal strClassString)
   On Error Resume Next
   IsObjInstalled = False
   Err = 0
   Dim xTestObj
   Set xTestObj = Server.CreateObject(strClassString)
   If 0 = Err Then IsObjInstalled = True
   Set xTestObj = Nothing
   Err = 0
  End Function
  '**************************************************
  '函數(shù)名：GetObjVer
  '作 用：返回組件版本信息
  '參 數(shù)：strClassString ---- 組件名稱或標識字串
  '返回值：返回組件版本信息字串
  '示 例：GetObjVer("JMAIL.Message")
  '**************************************************
  Public Function GetObjVer(ByVal strClassString)
   On Error Resume Next
   GetObjVer=""
   Err = 0
   Dim xTestObj
   Set xTestObj = Server.CreateObject(strClassString)
   If 0 = Err Then GetObjVer=xtestobj.version
   Set xTestObj = Nothing
   Err = 0
  End Function
  '**************************************************
  '函數(shù)名：ListObjInfo
  '作 用：列出組件安裝信息
  '參 數(shù)： ----
  '返回值：列出組件安裝信息
  '示 例：ListObjInfo()
  '**************************************************
  Public Function ListObjInfo()
   Dim TempBs,TempBsXX,TempObjType,tmpObjs
   TempBs="×"
   TempBsXX=""
   TempObjType=""
   tmpObjs=""
   tmpObjs=tmpObjs& "JMail.Message|"
   tmpObjs=tmpObjs& "ADODB.Stream|"
   tmpObjs=tmpObjs& "MSWC.AdRotator|"
   tmpObjs=tmpObjs& "MSWC.BrowserType|"
   tmpObjs=tmpObjs& "MSWC.NextLink|"
   tmpObjs=tmpObjs& "MSWC.Tools|"
   tmpObjs=tmpObjs& "MSWC.Status|"
   tmpObjs=tmpObjs& "MSWC.Counters|"
   tmpObjs=tmpObjs& "MSWC.PermissionChecker|"
   tmpObjs=tmpObjs& "Scripting.FileSystemObject|"
   tmpObjs=tmpObjs& "adodb.connection|"
   tmpObjs=tmpObjs& "SoftArtisans.FileUp|"
   tmpObjs=tmpObjs& "SoftArtisans.FileManager|"
   tmpObjs=tmpObjs& ";CDONTS.NewMail|"
   tmpObjs=tmpObjs& "Persits.MailSender|"
   tmpObjs=tmpObjs& "LyfUpload.UploadFile|"
   tmpObjs=tmpObjs& "Persits.Upload.1|"
   tmpObjs=tmpObjs& "w3.upload|"
   tmpObjs=Split(tmpObjs,"|")
   Response.write "<center><table border='1' bordercolor='#000000' cellspacing='0' cellpadding='0' style='font-size: 9pt;"">宋體'><tr><td width='33%' valign='middle' align='center' style='border-left: 1 solid #808080; border-right: 1 solid #FFFFFF; border-top: 1 solid #FFFFFF; border-bottom: 1 solid #808080; padding-left: 2; padding-right: 2; padding-top: 1; padding-bottom: 1'>組件標識</td><td width='33%' valign='middle' align='center' style='border-left: 1 solid #808080; border-right: 1 solid #FFFFFF; border-top: 1 solid #FFFFFF; border-bottom: 1 solid #808080; padding-left: 2; padding-right: 2; padding-top: 1; padding-bottom: 1'>√|×</td><td width='34%' valign='middle' align='center' style='border-left: 1 solid #808080; border-right: 1 solid #FFFFFF; border-top: 1 solid #FFFFFF; border-bottom: 1 solid #808080; padding-left: 2; padding-right: 2; padding-top: 1; padding-bottom: 1'>版本</td></tr>" & vbCrlf
   For i = LBound(tmpObjs) To UBound(tmpObjs)
   If Trim(tmpObjs(i))<>"" Then
   If IsObjInstalled(tmpObjs(i)) Then
   TempObjType=tmpObjs(i)
   TempBs="√"
   TempBsXX=GetObjVer(tmpObjs(i))
   If TempBsXX="" Then TempBsXX=" "
   Else
   TempObjType="<font color='#800000'>"&tmpObjs(i)&"</font>"
   TempBs="<font color='#800000'>×</font>"
   TempBsXX=" "
   End If
   Response.write "<tr>" & vbCrlf
   Response.write "<td valign='middle' style='border-left: 1 solid #808080; border-right: 1 solid #FFFFFF; border-top: 1 solid #FFFFFF; border-bottom: 1 solid #808080; padding-left: 2; padding-right: 2; padding-top: 1; padding-bottom: 1'>"&TempObjType&"</td>" & vbCrlf
   Response.write "<td valign='middle' align='center' style='border-left: 1 solid #808080; border-right: 1 solid #FFFFFF; border-top: 1 solid #FFFFFF; border-bottom: 1 solid #808080; padding-left: 2; padding-right: 2; padding-top: 1; padding-bottom: 1'>"&TempBs&"</td>" & vbCrlf
   Response.write "<td valign='middle' align='center' style='border-left: 1 solid #808080; border-right: 1 solid #FFFFFF; border-top: 1 solid #FFFFFF; border-bottom: 1 solid #808080; padding-left: 2; padding-right: 2; padding-top: 1; padding-bottom: 1'>"&TempBsXX&"</td>" & vbCrlf
   Response.write "</tr>" & vbCrlf
   End If
   Next
   Response.write "</table></center>" & vbCrlf
  End Function
  '**************************************************
  '函數(shù)ID：0024[上傳文件的窗口]
  '函數(shù)名：PosImageWin
  '作 用：上傳選擇文件窗口，可自動提取文件名及類型
  '參 數(shù)：PfUrlstr ---- 處理二進制文件信息的URL地址
  '返回值：網(wǎng)頁HTML文件
  '示 例：庫結(jié)構(gòu)例子 CREATE TABLE [IMAGES] ([ID] int IDENTITY (1,1) NOT NULL PRIMARY KEY,[MC] varchar(50),[LX] varchar(20),[MEM] Text,[IMGS] image)
  '**************************************************
  Public Function PosImageWin(ByVal PfUrlstr)
   PosImageWin=""
   PosImageWin=PosImageWin & "<center><table border='0' width='0' cellspacing='0' cellpadding='0' style='font-size: 9pt'>" & vbCrlf
   PosImageWin=PosImageWin & "<SCRIPT LANGUAGE=javascript>"&vbCrlf
   PosImageWin=PosImageWin & "function ckfilelx(){"&vbCrlf
   PosImageWin=PosImageWin & "tempwjm=POFile.ImageFs.value;"&vbCrlf
   PosImageWin=PosImageWin & "fgwjm=tempwjm.split('.');"&vbCrlf
   PosImageWin=PosImageWin & "newwjm=fgwjm.reverse();"&vbCrlf
   PosImageWin=PosImageWin & "POMem.ImageType.value=newwjm[0].toUpperCase();"&vbCrlf
   PosImageWin=PosImageWin & "tempwjm=newwjm[1].toUpperCase();"&vbCrlf
   PosImageWin=PosImageWin & "fgwjm=tempwjm.split('\\');"&vbCrlf
   PosImageWin=PosImageWin & "newwjm=fgwjm.reverse();"&vbCrlf
   PosImageWin=PosImageWin & "POMem.ImageName.value=newwjm[0].toUpperCase();"&vbCrlf
   PosImageWin=PosImageWin & "POMem.ImageReadme.value=newwjm[0].toUpperCase();"&vbCrlf
   PosImageWin=PosImageWin & "}"&vbCrlf
   PosImageWin=PosImageWin & "function Reedit(){POFile.reset();POMem.reset();}"&vbCrlf
   PosImageWin=PosImageWin & "function PostDo(){if (POFile.ImageFs.value==''){alert('沒有選擇文件喲！');}else{bc.innerHTML='正在上傳，請稍后...';POFile.action=POFile.action+'&mc='+POMem.ImageName.value+'&lx='+POMem.ImageType.value+'&mem='+POMem.ImageReadme.value;bc.style.visibility='visible';ReEd.disabled=true;PoSe.disabled=true;POFile.submit();POFile.ImageFs.disabled=true;}}"&vbCrlf
   PosImageWin=PosImageWin & "</SCRIPT>"&vbCrlf
   PosImageWin=PosImageWin & "<tr><form method='POST' name='POFile' enctype='multipart/form-data' ACTION='"&PfUrlstr&"' target='tempa'><td width='100%' valign='middle'>" & vbCrlf
   PosImageWin=PosImageWin & "選擇文件：<input type='file' name='ImageFs' ONCHANGE='ckfilelx();' style='font-size: 9pt;width:300;'>" & vbCrlf
   PosImageWin=PosImageWin & "</td></form></tr>" & vbCrlf
   PosImageWin=PosImageWin & "<tr><form method='POST' name='POMem'><td width='100%' valign='middle'>" & vbCrlf
   PosImageWin=PosImageWin & "文件ID號：<input type='text' name='ImageID' ReadOnly style='font-size: 9pt;width:300;'><br>" & vbCrlf
   PosImageWin=PosImageWin & "文件名稱：<input type='text' name='ImageName' style='font-size: 9pt;width:300;'><br>" & vbCrlf
   PosImageWin=PosImageWin & "文件類型：<input type='text' name='ImageType' ReadOnly style='font-size: 9pt;width:300;'><br>" & vbCrlf
   PosImageWin=PosImageWin & "文件介紹：<textarea rows='8' name='ImageReadme' cols='20' style='font-size: 9pt;width:300;'>還沒有</textarea>" & vbCrlf
   PosImageWin=PosImageWin & "</td></form></tr>" & vbCrlf
   PosImageWin=PosImageWin & "<tr><td width='100%' valign='middle' align='center'>" & vbCrlf
   PosImageWin=PosImageWin & "<input type='button' value='重置' name='ReEd' OnClick='Reedit();'>  <input type='button' value='上傳' name='PoSe' OnClick='PostDo();'>" & vbCrlf
   PosImageWin=PosImageWin & "</td></tr></table></center><div id='bc' name='bc' style='position: absolute; left: 45%; top:40%; z-index: 0;background-color: #EAEAEA;visibility: hidden;' valign='middle' align='center'></div>" & vbCrlf
   PosImageWin=PosImageWin & "<iframe src='' ID='tempa' NAME='tempa' frameborder='0' width='0' height='0' style='width:0;Height:0;'>" & vbCrlf
  End Function

本站僅提供存儲服務(wù)，所有內(nèi)容均由用戶發(fā)布，如發(fā)現(xiàn)有害或侵權(quán)內(nèi)容，請點擊舉報。