国产一级a片免费看高清,亚洲熟女中文字幕在线视频,黄三级高清在线播放,免费黄色视频在线看

8 番外篇

標(biāo)題很奇怪？其實(shí)，您可以把它當(dāng)作一期OVA。

8.1 批量十六進(jìn)制二進(jìn)制格式轉(zhuǎn)換

想把數(shù)據(jù)(流)以十六進(jìn)制或二進(jìn)制的形式顯示出來？UltraEdit之類的編輯軟件一定是首選。即使是要自己親自轉(zhuǎn)出來，C/C++等語(yǔ)言也會(huì)方便的多。如果您跟我一樣選擇使用批處理來實(shí)現(xiàn)的話，那么很好，很有挑戰(zhàn)性。

::::::DataFormatConvert.bat:::::
@echo off

:Initialization
set TempFile=temp.tmp
set /a num = 0
set BinaryFormat=Bin
:: 默認(rèn)為二進(jìn)制數(shù)字0或1顯示
set ConvertOption=ConvertToHex
:: 默認(rèn)為十六進(jìn)制轉(zhuǎn)換
set ShowProgress=ShowProgressOn
:: 默認(rèn)為顯示轉(zhuǎn)換進(jìn)度
set BackSpace=[將本文底部評(píng)論3中的退格符替換到此處]
:: 退格符

set Source=z%1
:: 添加一個(gè)臨時(shí)字符 z
if %Source:~1,1%z%Source:~-1%=="z" set Source=z%Source:~2,-1%
:: 檢查變量參數(shù)1的第一個(gè)和最后一個(gè)字符是否為 "" ，是的話就去掉
set Source=%Source:~1%
:: 去掉臨時(shí)字符 z
if "%Source%"=="" goto :HelpInformation
if "%Source%"=="/?" goto :HelpInformation
if /i "%Source%"=="/help" goto :HelpInformation
if not exist "%Source%" echo 目標(biāo)文件不存在 & exit /b 2
:: 檢查參數(shù)1 [注1]

if /i "%2"=="/Bin"         set ConvertOption=ConvertToBin
if /i "%3"=="/Bin"         set ConvertOption=ConvertToBin
if /i "%2"=="/Block"       set ConvertOption=ConvertToBin & set BinaryFormat=BinBlock
if /i "%3"=="/Block"       set ConvertOption=ConvertToBin & set BinaryFormat=BinBlock
if /i "%2"=="/ProgressOff" set ShowProgress=ShowProgressOff
if /i "%3"=="/ProgressOff" set ShowProgress=ShowProgressOff
:: 檢查參數(shù)2和3 [注2]

for %%i in ("%Source%") do (
    set SourceDrivePathName=%%~dpni
    set FileSize=%%~zi
)
:: 獲得源文件的 驅(qū)動(dòng)器號(hào)+路徑+標(biāo)題名 ，以及文件大小。 d - drive, p - path, n - name, z - size
if "%FileSize%"=="0" echo 目標(biāo)文件為空 & exit /b 3
del %TempFile% >nul 2>nul
fsutil file createnew %TempFile% %FileSize% >nul
:: 創(chuàng)建一個(gè)大小與源文件一樣的空白文件，該文件里的所有字節(jié)均為0x00

goto :%ConvertOption%

:ConvertToHex
:: 十六進(jìn)制轉(zhuǎn)換
setlocal EnableDelayedExpansion
set OutputFile="%SourceDrivePathName%.Hex.txt"
echo 文件 %Source% 的十六進(jìn)制格式:>%OutputFile%
echo. & echo 正在轉(zhuǎn)換為十六進(jìn)制...

for /f "skip=1 tokens=1,3" %%i in ('fc /b %TempFile% "%Source%"') do (
    set index=0x%%i
    set index=!index:~0,-1!
    set /a offset = !index! - !num!

    for /l %%n in (1,1,!offset!) do (
        set /p=00<nul>>%OutputFile%
        set /a num += 1
    )
    set /p=%%j<nul>>%OutputFile%
    set /a num += 1
    call :%ShowProgress% !num!
)
:: 通過與大小相同內(nèi)容空白的文件進(jìn)行二進(jìn)制對(duì)比，獲得源文件的十六進(jìn)制碼 [注3]
endlocal
goto :ExitSuccess

:ConvertToBin
setlocal EnableDelayedExpansion
set OutputFile="%SourceDrivePathName%.%BinaryFormat%.txt"
echo 文件 %Source% 的二進(jìn)制格式:>%OutputFile%
echo. & echo 正在轉(zhuǎn)換為二進(jìn)制...

for /f "skip=1 tokens=1,3" %%i in ('fc /b %TempFile% "%Source%"') do (
    set index=0x%%i
    set index=!index:~0,-1!
    set /a offset = !index! - !num!

    for /l %%n in (1,1,!offset!) do (
        call :HexTo%BinaryFormat% 0
        call :HexTo%BinaryFormat% 0
        set /a num += 1
    )
    set HexData=%%j
    call :HexTo%BinaryFormat% !HexData:~0,1!
    call :HexTo%BinaryFormat% !HexData:~1,1!
    set /a num += 1
    call :%ShowProgress% !num!
)
endlocal
goto :ExitSuccess

:HexToBin
:: 函數(shù): HexToBin 用途: 以0或1的形式顯示
if %1==0 set /p=0000<nul>>%OutputFile%
if %1==1 set /p=0001<nul>>%OutputFile%
if %1==2 set /p=0010<nul>>%OutputFile%
if %1==3 set /p=0011<nul>>%OutputFile%
if %1==4 set /p=0100<nul>>%OutputFile%
if %1==5 set /p=0101<nul>>%OutputFile%
if %1==6 set /p=0110<nul>>%OutputFile%
if %1==7 set /p=0111<nul>>%OutputFile%
if %1==8 set /p=1000<nul>>%OutputFile%
if %1==9 set /p=1001<nul>>%OutputFile%
if %1==A set /p=1010<nul>>%OutputFile%
if %1==B set /p=1011<nul>>%OutputFile%
if %1==C set /p=1100<nul>>%OutputFile%
if %1==D set /p=1101<nul>>%OutputFile%
if %1==E set /p=1110<nul>>%OutputFile%
if %1==F set /p=1111<nul>>%OutputFile%
goto :EOF

:HexToBinBlock
:: 函數(shù): HexToBinBlock 用途: 以　或■的形式顯示[注3]
if %1==0 set /p=　　　　<nul>>%OutputFile%
if %1==1 set /p=　　　■<nul>>%OutputFile%
if %1==2 set /p=　　■　<nul>>%OutputFile%
if %1==3 set /p=　　■■<nul>>%OutputFile%
if %1==4 set /p=　■　　<nul>>%OutputFile%
if %1==5 set /p=　■　■<nul>>%OutputFile%
if %1==6 set /p=　■■　<nul>>%OutputFile%
if %1==7 set /p=　■■■<nul>>%OutputFile%
if %1==8 set /p=■　　　<nul>>%OutputFile%
if %1==9 set /p=■　　■<nul>>%OutputFile%
if %1==A set /p=■　■　<nul>>%OutputFile%
if %1==B set /p=■　■■<nul>>%OutputFile%
if %1==C set /p=■■　　<nul>>%OutputFile%
if %1==D set /p=■■　■<nul>>%OutputFile%
if %1==E set /p=■■■　<nul>>%OutputFile%
if %1==F set /p=■■■■<nul>>%OutputFile%
goto :EOF

:ShowProgressOn
:: 函數(shù): ShowProgressOn 用途: 顯示轉(zhuǎn)換進(jìn)度
set /a mod = %1 %% 50
if %mod% equ 0 (
    set /a percent = %1 * 100 / %FileSize%
    set /p=%BackSpace%%BackSpace%%BackSpace%<nul
    set /p=!percent!%%<nul
)
goto :EOF

:ShowProgressOff
:: 函數(shù): ShowProgressOff 用途: 不顯示轉(zhuǎn)換進(jìn)度
goto :EOF

:HelpInformation
:: 該批處理的幫助信息
echo 將文件轉(zhuǎn)換為十六進(jìn)制或二進(jìn)制的格式。
echo.
echo DataFormatConvert source [/Hex ^| /Bin ^| /Block] [/ProgressOn ^| /ProgressOff]
echo.
echo   source       指定要轉(zhuǎn)換的文件。
echo   /Hex         表示轉(zhuǎn)換為十六進(jìn)制格式(默認(rèn))。
echo   /Bin         表示轉(zhuǎn)換為二進(jìn)制格式。
echo   /Block       表示轉(zhuǎn)換為二進(jìn)制格式并以方塊的形式顯示。
echo   /ProgressOn　顯示轉(zhuǎn)換進(jìn)度(默認(rèn))。
echo   /ProgressOff 關(guān)閉顯示進(jìn)度。
exit /b 1

:ExitSuccess
:: 成功完成并退出
del %TempFile% >nul
set /p=%BackSpace%%BackSpace%%BackSpace%%BackSpace%<nul
echo 轉(zhuǎn)換完成!
exit /b 0
::::::::::::::::::::::::::::::::