国产一级a片免费看高清,亚洲熟女中文字幕在线视频,黄三级高清在线播放,免费黄色视频在线看

八、在EXCEL中快速輸入上標(biāo)形式的平方、立方(收集):

　　按ALT+178輸入平方，按ALT+179輸入立方。并且用這種方法輸入的上標(biāo)“平方”和“立方”還可以用在函數(shù)和公式中。

九、VLOOKUP函數(shù)查找右邊列的值后得到同一行左邊列的值:

　　比如在SHEET2表的B1單元格通過公式在SHEET1表的B列查找SHEET2表中A1的值,找到后返回SHEET1表中同一行中A列的值,公式如下:

=VLOOKUP(A1,IF({1,0},SHEET1!B$1:B$1000,SHEET1!A$1:A$1000),2,0)

公式可向下復(fù)制.

要點:公式中IF函數(shù)中的兩個區(qū)域不能引用整列。否則公式會出錯。

當(dāng)然，這種公式其實可以用INDEX和MATCH兩個函數(shù)代替。

十、如何將A1單元格中輸入的數(shù)值累加到B2單元格中？

　　先點"工具"->"選項"->"重新計算"，選中"自動重算"和"迭代計算"，將"最多迭代次數(shù)"設(shè)為1，然后在B2單元格輸入公式:

=IF((CELL("ROW")=ROW()-1)*(CELL("COL")=1),A1+B2,B2)

這樣設(shè)置好后,在A1輸入的數(shù)值會自動累加的B2單元格中，而在其他單元格輸入數(shù)值時，B2單元格的數(shù)值不會變化。

十一、快速輸入數(shù)值尾部多個零的簡便方法:

　　在單元格中直接輸入:

        =125**6

       單元格值自動會變?yōu)?25000000.

       如果先將單元格格式設(shè)為自定義類型"0",就可以不用輸入等號,直接輸入125**6即可.

EXCEL實用操作技巧(二)

一、如何改變Excel中起始頁的頁號？

假如起始頁頁號要為7，點"視圖"->"頁眉頁腳",點"自定義頁腳,將"第 &[頁碼] 頁"改為"第 &[頁碼]+6 頁",點兩次"確定"。

二、Excel中當(dāng)被引用單元格發(fā)生剪切操作時,如何保持引用單元格的內(nèi)容仍然引用原位置的內(nèi)容？

例如，A1等于B5時,當(dāng)B5的內(nèi)容剪切到C8時,A1將等于C8的內(nèi)容。如果要求不管B5作什么操作, A1始終要等于B5的內(nèi)容，A1單元格公式如下：

=INDIRECT("B5")

三、如何在公式單元格前面插入或刪除列時始終引用當(dāng)前單元格左邊相鄰單元格的值？

比如C1單元格，目前引用的是B1單元格的值。要求，當(dāng)在C列前面插入一列時，公式單元格（變?yōu)?span>D1）仍然引用相鄰左邊單元格C1的值。而當(dāng)在C列前面刪除一列時，公式單元格（變?yōu)?span>B1）仍然引用相鄰左邊單元格A1的值。

公式：

=OFFSET(A1,0,COLUMN()-2,1,1)

四、如何只顯示（篩選）奇數(shù)行或偶數(shù)行？

在后面空白列(假定為F列)的第2行輸入篩選條件:
=MOD(ROW(A2),2)=0
選定該表所有數(shù)據(jù)列,點"數(shù)據(jù)"->"篩選"->"高級篩選",條件區(qū)域選擇:
=$F$1:$F$2
點"確定"。這樣就只顯示偶數(shù)行。
如果要只顯示奇數(shù)行，將公式改為：
=MOD(ROW(A2),2)

五、如何僅通過自定義單元格格式設(shè)置讓數(shù)據(jù)縮小1000倍顯示，并且千分位后的內(nèi)容不顯示？

比如讓333000111顯示成333,000

輸入數(shù)字后,將單元格格式設(shè)為"自定義",在"類型"框中輸入:
#,##0,""
點"確定"。

六、在excel表格中的涉密內(nèi)容如何不讓其顯示？

用exce記錄合同信息，有些合同涉密，不希望顯示出來，或者用*號顯示，比如：在一個單元格里輸入“合同名稱”四個字，但我希望別人打開這個表格時看到的這個單元格里顯示的是“****”，而我通過某種途徑還可以知道這個“****”后面的內(nèi)容是“合同名稱”。

先在那個單元格輸入公式:
=IF(IV1=123,"合同名稱","****")
然后選定全表,點"格式->"單元格"->"保護",取消"鎖定"前面的對勾。
再選定公式單元格,點"格式->"單元格"->"保護",選中"鎖定"和"隱藏"。
點"工具"->"保護"->"保護工作表",輸入兩次密碼,點"確定"。
這樣設(shè)置好后別人看到的就是星號，也不能對這個單元格刪除和修改。
你自己要看的時候，點"工具"->"保護"->"撤消工作表保護",輸入密碼，這時點擊該單元格時編輯欄可以看到公式內(nèi)容，但單元格顯示的還是星號。你再在IV1單元格輸入123，該單元格就顯示為“合同名稱”了。

七、如何將excel表中所有的空單元格填上某個數(shù)字?

選定表格區(qū)域范圍,點"編輯"->"定位",點"條件定位",選中"空值",點"確定",輸入某個數(shù)字,按Ctrl+回車。

八、如何根據(jù)A列的身份證號碼在B列判斷女的是否大于40歲，男的是否大于50歲？

在B1輸入公式:
=IF(YEAR(TODAY())-1*TEXT((LEN(A1)=15)*19&MID(A1,7,2+(LEN(A1)=18)*2),"0000")>IF(MOD(MID(A1,15,3),2),50,40),"是","否")
將公式向下復(fù)制。

九、如何計算單元格中數(shù)學(xué)表達式的值？

假定A1內(nèi)容為21*17+5/4,要在B1單元格計算其結(jié)果。

單擊B1，然后點“插入”菜單選擇“名稱”命令中的“定義”子命令，出現(xiàn)“定義名稱”對話框。
在“在當(dāng)前工作表中的名稱”中輸入定義的名稱“X”，在下方的“引用位置”編輯欄中輸入:
=EVALUATE(A1)
單擊[確認(rèn)]按鈕退出。
在 B1中輸入“=X” (注:不含引號)

公式可向下復(fù)制。

十、如何將EXCEL中的信息導(dǎo)入Outlook Express的聯(lián)系人中？

在EXCEL中點"文件"->"另存為","保存類型"中選擇"CSV(逗號分隔)(*.csv)",文件名任起。 在Outlook Express中點"文件"->"導(dǎo)入"->"其他通訊薄",選中"文本文件(以逗號分隔)",點"導(dǎo)入",找到你保存的*.csv文件,按提示分別導(dǎo)入各項內(nèi)容即可。
Outlook 2003可以直接導(dǎo)入EXCEL文件（需要安裝轉(zhuǎn)換插件）。

十一、如何求單元格中任意數(shù)字的所有各個位數(shù)之和？

如5126各位數(shù)的和5+1+2+6=14，公式如下：

=SUMPRODUCT(1*MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))

注：A1可以為任意位數(shù)字。

十二、如何讓用戶在C1單元格選擇的月份后，A列中自動顯示當(dāng)年當(dāng)月所有日期，而在B列自動填充對應(yīng)的星期幾？

假定C1單元格用數(shù)據(jù)有效性設(shè)置一個選擇(1-12)月份的下拉菜單,A1單元格輸入公式:
=IF(C$1="","",IF(C$1<>MONTH(DATE(YEAR(TODAY()),C$1,ROW())),"",DATE(YEAR(TODAY()),C$1,ROW())))
B1單元格輸入公式:
=IF(A1="","",TEXT(WEEKDAY(A1),"AAAA"))
將兩個公式向下復(fù)制到第31行。

將A列單元格格式設(shè)置為你要的日期格式。

十三、如何在單元格中引用工作表名、工作簿名、工作簿所在文件夾名？

在工作簿已經(jīng)保存的情況下，CELL("filename")可以得到帶完整路徑的工作表名。用字符函數(shù)截取相應(yīng)的部分即可。

引用工作表名：

=RIGHT(CELL("filename"),LEN(CELL("filename"))-FIND("]",CELL("filename")))

引用工作簿名：

=MID(CELL("filename"),FIND("[",CELL("filename"))+1,FIND("]",CELL("filename"))-FIND("[",CELL("filename"))-5)

引用工作簿所在文件夾名：

=TRIM(LEFT(RIGHT(SUBSTITUTE(CELL("filename"),"\",REPT(" ",100)),200),100))

十四、如何填充特殊序列（如第一期、第二期……，第壹號、第貳號……）？

有兩種方法：

一是設(shè)置“自定義”單元格格式，“類型”分別為：

[DBNum1]"第"G/通用格式"期"

[DBNum2]"第"G/通用格式"號"

然后輸入阿拉伯?dāng)?shù)字進行填充。

二是利用公式直接生成，公式分別為：

="第"&TEXT(ROW(A1),"[DBNum1]G/通用格式")&"期"

="第"&TEXT(ROW(A1),"[DBNum2]G/通用格式")&"號"

十五、EXCEL中如何使用自定義函數(shù)？

打開EXCEL，按Alt+F11調(diào)出VBA編輯器，點“插入”->“模塊”，將自定義的函數(shù)模塊內(nèi)容加入進去。

比如“將單元格字符串反序輸出”的函數(shù)模塊：

Public Function MyStrReverse(ByVal sString As Variant) As String
       Application.Volatile
       Dim strResult As String
       strResult = StrReverse(sString)
       MyStrReverse = strResult
End Function

如果你要對軟件保密的話，在“模塊”上按右鍵，[VBAproject屬性]→[保護中設(shè)置密碼]，別人就看不到你的源程序了。

退出VBA編輯器，返回到EXCEL界面，點“文件”->“另存為”，“保存類型”選擇“Microsoft Office Excel加載宏”，取名為“字符串反序輸出”，會自動加上擴展名.xla。

使用時，點“工具”->“加載宏”，點“瀏覽”找到你保存的“字符串反序輸出.xla”文件，點“確定”。

如果“可用加載宏”里面已經(jīng)有此項，選中后點“確定”即可。

假定A1為“ijdf152中國人id897”，在B1直接輸入自定義的函數(shù)：

= MyStrReverse(A1)

即可得到結(jié)果“798di人國中251fdji”。

十六、EXCEL中如何設(shè)置二級關(guān)聯(lián)下拉菜單?
          將你的一級菜單的內(nèi)容輸入到SHEET1工作表的第一行(假定為A1:G1),選定A1:G1,將該區(qū)域命名為"一級"(注:不含引號),將一級菜單對應(yīng)的二級菜單內(nèi)容分別輸入到A至G列第二行以下的各行中(假定為第2至10行)。
          在SHEET2中，第一行為表頭，選定A2:A10(可根據(jù)你的需要改變范圍)，點"數(shù)據(jù)"->"有效性"->"設(shè)置",允許下面選擇"序列",在來源框中輸入
=一級
          點"確定"。
          用鼠標(biāo)選定B2:B10,點"數(shù)據(jù)"->"有效性"->"設(shè)置",允許下面選擇"序列",在來源框中輸入下面的公式:
=INDIRECT("sheet1!"&CHAR(64+MATCH(A2,一級,0))&"2:"&CHAR(64+MATCH(A2,一級,0))&"10")
          點"確定"。
          這樣SHEET2工作表中A2:A10有一級下拉菜單的內(nèi)容供選擇，B2:B10有對應(yīng)的二級下拉菜單內(nèi)容供選擇。

十七、EXCEL中如何提取漢字的拼音首字母?(收集)
=IF(A1="","",LOOKUP(CODE(A1),45217+{0,36,544,1101,1609,1793,2080,2560,2902,3845,4107,4679,5154,5397,5405,5689,6170,6229,7001,7481,7763,8472,9264},{"A","B","C","D","E","F","G","H","J","K","L","M","N","O","P","Q","R","S","T","W","X","Y","Z"}))
或者:
=LOOKUP(CODE(A1),45217+{0,36,544,1101,1609,1793,2080,2560,2902,3845,4107,4679,5154,5397,5405,5689,6170,6229,7001,7481,7763,8472,9264},MID("ABCDEFGHJKLMNOPQRSTWXYZ",ROW($1:$23),1))

注:公式只對常用漢字有效，部分生辟漢字未按拼音排列，無法用公式找到。

十八、EXCEL中如何禁止輸入完全相同的行

      假定你準(zhǔn)備將數(shù)據(jù)輸入到A1:C100區(qū)域(三列100行),先用鼠標(biāo)選定該區(qū)域,點"數(shù)據(jù)"->"有效性"->"設(shè)置","允許"下面選擇"自定義",在"公式"下面的框中輸入:
=SUMPRODUCT(($A$1:$A$100=$A1)*($B$1:$B$100=$B1)*($C$1:$C$100=$C1))=1
點"確定"。

      這樣就不能輸入完全相同的行了，必須重新輸入該行直到?jīng)]有重復(fù)的行它才會接受你輸入的數(shù)據(jù)。

如果你的列數(shù)超過三列，將公式作相應(yīng)修改即可。

十九、如何查找某列中不重復(fù)的數(shù)據(jù)并連續(xù)存放在另一列中?

     假定原數(shù)據(jù)在A1:A100區(qū)域中，其中有若干數(shù)據(jù)重復(fù)，先將A1數(shù)據(jù)復(fù)制到B1，然后在B2單元格輸入數(shù)組公式：

=IF(SUMPRODUCT(1/COUNTIF(A$1:A$100,A$1:A$100))<ROW(),"",INDEX(A:A,MIN(IF(COUNTIF(B$1:B1,A$1:A$100)=0,ROW(A$1:A$100)))))

   將公式向下復(fù)制，直到出現(xiàn)空白為止。
   
    補充：下面這個數(shù)組公式可以從B1單元格直接輸入:
     =INDEX(A:A,SMALL(IF(MATCH(A$1:A$100,A$1:A$100,)=ROW(A$1:A$100),ROW(A$1:A$100),65536),ROW()))&""
       公式以CTRL+SHIFT+回車結(jié)束。

二十、如何將一個單元格中的數(shù)字去掉重復(fù)的后從小到大排序輸出在另一個單元格中?

假定A1為209537233，要在B1得到023579，公式如下：
=IF(ISERROR(FIND(0,A1)),"","0")&SUBSTITUTE(SUM(IF(FIND(ROW($1:$9),A1&"123456789")<=LEN(A1),ROW($1:$9)*10^(9-ROW($1:$9)))),0,"")
公式以CTRL+SHIFT+回車結(jié)束