指標(biāo)編寫技巧總匯
1、間隔點：
20,colorred,pointdot,linethick2;
80,colorred,pointdot,linethick2;
50,colorred,pointdot,linethick2;
{不需要粗線條就把粗細(xì)面條linethick2去掉}
2、間隔線
20,colorred；
80,colorred;
50,colorred;
3、信號字
LC := REF(CLOSE,1);
RSI1:SMA(MAX(CLOSE-LC,0),6,1)/SMA(ABS(CLOSE-LC),6,1)*100,colorwhite;
RSI2:=SMA(MAX(CLOSE-LC,0),12,1)/SMA(ABS(CLOSE-LC),12,1)*100;
DRAWTEXT(RSI1<10,RSI2,'買');
DRAWTEXT(RSI1>85,RSI1,'賣');
4、笑哭臉
LLC:=REF(CLOSE,1);
VR26:SUM(IF(CLOSE>LLC,VOL,0),26)/SUM(IF(CLOSE<=LLC,VOL,0),26)*100,colorwhite;
DRAWICON(VR26<40,VR26+30,1);
DRAWICON(VR26>350,VR26,2);
5、一線提示
cross("kdj.j"(9,3,3),"kdj.d"(9,3,3)) and "kdj.j"(9,3,3)<20,colorred;
6、一柱頂天
Var1m:=(CLOSE-REF(CLOSE,1))/REF(CLOSE,1)*100;
Var2m:=(EMA(CLOSE, 6)-EMA(CLOSE, 12))*100;
獵莊:Var2m<13 AND Var1m>9,stick,ColorFFFFFF,linethick2;
7、小人作怪
多方趨勢:7*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*30,4,1)
-3*SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*30,4,1),3,1)
-sma(SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*30,4,1)
,3,1),2,1),,Color8811FF;
主升線:=14;
天線:=78.89;
抄底:=CROSS(多方趨勢,主升線);
逃頂:=cross(天線,多方趨勢);
DRAWICON(抄底,多方趨勢,1);
DRAWICON(逃頂,多方趨勢,2);
8、小人
V1:=EMA(CLOSE,8);
H2:=EMA(V1,20);
V2:=CROSS(V1,H2) AND (V1<MA(CLOSE,120) OR V1<H2);
黑馬起步:if(v2,1,0),stick,colorred,linethick2;
drawicon(黑馬起步,1.1,1);
Vark1:=(CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100;
Vark3:=SMA(Vark1,3,1);
波段王:=SMA(Vark3,3,1),COLORRED,linethick2;
波段鬼:=SMA(波段王,2.5,1),coloryellow,linethick2;
趨勢線:=3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1);
賣:IF((CROSS(波段鬼,波段王) or CROSS(波段鬼,趨勢線) or CROSS(波段王,趨勢線) ) AND 波段鬼>65,1,0),stick,color00ff00,linethick3;
drawicon(賣,1.1,2);
9、粗細(xì)面條
LINETHICK2
愛把線設(shè)多粗細(xì)都行。
10、方塊STICKLINE
AA:=VOL/((HIGH-LOW)*2-ABS(CLOSE-OPEN));
買盤:IF(CLOSE>OPEN,AA*(HIGH-LOW),IF(CLOSE<OPEN,AA*((HIGH-OPEN)+(CLOSE-LOW)),VOL/2));
賣盤:IF(CLOSE>OPEN,0-AA*((HIGH-CLOSE)+(OPEN-LOW)),IF(CLOSE<OPEN,0-AA*(HIGH-LOW),0-VOL/2));
qq:=買盤+賣盤;
STICKLINE(賣盤<0,0,VOL,5,1),COLORlime;
STICKLINE(買盤>0,0,買盤,5,0),COLORRED;
結(jié)果:ma(qq,5)*5,COLORRED,LINETHICK2；
VOL后面的5，1是方塊大少。VOL是坐標(biāo)，也就是方塊所放的地方。
11、3D效果
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,9,0 ),COLORaaaaaa;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,6,0 ),COLORbbbbbb;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,2.4,0 ),COLORcccccc;
STICKLINE(OPEN>=CLOSE ,CLOSE ,OPEN,1.1,0 ),COLORdddddd;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,9,0 ),COLOr6666cc;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,6 ,0 ),COLOR7777dd;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,2.4 ,0 ),COLOR8888ee;
STICKLINE(CLOSE>OPEN,CLOSE,OPEN,1.1 ,0 ),COLOR9999ff;
STICKLINE(CLOSE>OPEN,OPEN,LOW,0.5,0 ),COLOR1199ff;
STICKLINE(CLOSE>OPEN,CLOSE,HIGH,0.5 ,0 ),COLOR1199ff;
STICKLINE(OPEN>=CLOSE,CLOSE,LOW,0.5 ,0 ),COLORcccccc;
STICKLINE(OPEN>=CLOSE,OPEN,HIGH,0.5 ,0 ),COLORcccccc;
12、顏色
大智慧只能用淺色調(diào)，一用深綠深藍(lán)就看不見了。調(diào)了幾個淺色的，夠大智慧用的。
COLORRED;COLORWHITE;COLORLIME;COLORYELLOW;COLORaabbcc;COLORffaabb;COLORabcdef;
COLOR999999;COLORC0C0C0.
13、變色
變色可分3種：
(1)用DRAWTEXT：
ma10:ma(c,10),colorwhite;
llv(h,30),colorffcc66;
llv(l,30),coloryellow;
vhh:hhv(h,30),colorred;
vhl:hhv(l,30),color00ff00;
v1:=ma(HIGH,30)*1.15 ;
v2:=ma(HIGH,3)*1.03;
v3:=ma(LOW,3)*0.97;
v4:=ma(LOW,30)*0.85;
小通道上:=ma(v2,30);
小通道下:=ma(v3,30);
A2:=小通道上-REF(小通道上,1);
A3:=小通道下-REF(小通道下,1);
K:A2>0 and ref(A2<0,1),colorblue;
K1:A3>0 and ref(A3<0,1),colorff00ff;
K2:c<小通道下 and h<小通道下,color0099ff;
K3:c<小通道下 and A3>0,colorffcccc;
K4:h<小通道下 and A3>0,colorffbbff;
DRAWTEXT(A2>0 ,小通道上,'°'),colorred;
DRAWTEXT(A2<0 ,小通道上,'°'),color00ff00;
DRAWTEXT(A3>0 ,小通道下,'°'),colorred;
DRAWTEXT(A3<0 ,小通道下,'°'),color00ff00;
DRAWTEXT(A2=0 ,小通道上,'°'),COLORWHITE;
DRAWTEXT(A2=0 ,小通道下,'°'),COLORWHITE;
DRAWTEXT(A3=0 ,小通道上,'°'),COLORWHITE;
DRAWTEXT(A3=0 ,小通道下,'°'),COLORWHITE;
{在拼音狀態(tài)下用句號 °做變色線條，當(dāng)然也可用其他符號}
(2)用IF
主圖公式1：
A1:=Ma(C,5);{5日移動平均線}
A2:=Ma(C,10);{10日移動平均線}
A3:=(A1+A2)/2;{5、10日移動平均線之和除2的平均線，也就是中心線}
IF (A1>A2,A1,A3),Colorred,linethick2;{5日線大于10日且5日線交叉A3線顯示粗紅線}
IF (A1>A2,A2,A3),Colorred,linethick2;{5日線大于10日且10日線交叉A3線顯示粗紅線}
IF (A1<=A2,A1,A3),Color00ff00,linethick2;{5日線小于等于10日且5日線交叉A3線顯示粗綠線}
IF (A1<=A2,A2,A3),Color00ff00,linethick2;{5日線小于等于10日且10日線交叉A3線顯示粗綠線}
A3,colorwhite,linethick2;{中心線顯示粗白線}
這是以中心線為軸通過A1、A2這兩條線與中心線的交叉來變換顏色的。
主圖公式2：
MA1:=MA(CLOSE,5);{5日移動平均線}
MA2:=MA(CLOSE,10);{10日移動平均線}
MA3:=MA(CLOSE,20);{20日移動平均線}
MA4:=MA(CLOSE,30);{30日移動平均線}
MAA:=MA(CLOSE,60);{60日移動平均線}
MA5:IF(MA1<MA4,MA1,MA4),COLOR00ff00;{MA1線小于MA4且MA1線交叉MA4線顯示綠色線}
IF(MA1<MA4,MA4,MA1),coloryellow;{MA1線小于MA4且MA4線交叉MA1線顯示黃色線}
MA10:if(ma2<ma4,ma2,ma4),colorffcc66;{MA2線小于MA4且MA2線交叉MA4線顯示青色線}
if(ma2<ma4,ma4,ma2),color0099ff;{MA2線小于MA4且MA4線交叉MA2線顯示橘黃色線}
MA20:if(ma3<ma4,ma3,ma4),colorwhite;{MA3線小于MA4且MA3線交叉MA4線顯示白色線}
if(ma3<ma4,ma4,ma3),colorblue;{MA3線小于MA4且MA4線交叉MA3線顯示青色線}
MA30:if(ma4<maa,ma4,maa),colorff00ff,linethick2;{MA4線小于MAA且MA4線交叉MAA線顯示粉色粗線}
if(ma4<maa,maa,ma4),colorred,linethick2;{MA4線小于MAA且MAA線交叉MA4線顯示紅色粗線}
MA60:if(ma4>maa,maa,maa),linethick2,colorblue;{MA4線大于MAA且MAA線交叉MAA線顯示蘭色粗線}
這是分別以MA4、MAA線為軸通過向上交叉和向下交叉來變換顏色的。
單條變色線{主圖}
ma10:ma(c,10);
if(ma10>ref(ma10,1),ma10,0),Circledot,COLORRED,LINETHICK2;
if(ma10<ref(ma10,1),ma10,0),Circledot,COLOR00FF00,LINETHICK2;
顯然不那么好看，因大智慧沒有變色線的函數(shù)，也只有這么將就了。
一、線形函數(shù)
線形函數(shù)要和其它指標(biāo)函數(shù)一起用才能發(fā)揮效力，因為它們都是描述其它指標(biāo)函數(shù)的。正確用好線形函數(shù)可以使主副圖指標(biāo)顯示豐富多彩，色彩繽紛。
1、函數(shù):STICK 說明：畫棒狀線，STICK的英文是棍、棒的意思。
如副圖公式:C>REF(C,1) AND C>REF(C,2),STICK;
2、函數(shù):COLORSTICK 說明：以零軸為中心畫彩色棒狀線，零軸下為陰線顏色，零軸上為陽線顏色,這樣零軸就如楚漢交界，涇渭分明了。
如副圖公式:C-REF(C,1),COLORSTICK;
3、函數(shù):LINESTICK 說明：同時畫棒狀線與指標(biāo)線。LINE是線，STICK是棒，LINESTICK自然是線棒一起顯示了。如副圖公式:
A:=C-REF(C,1);
A,LINESTICK;
即想顯示指標(biāo)線和棒狀線，又想以零軸為中心上下顯示兩種彩色棒狀線，可以用分開的兩句語句來達(dá)到目的,如副圖公式:
A:=C-REF(C,1);
A,LINESTICK;
A,COLORSTICK;
4、函數(shù):VOLSTICK 說明:畫成交量柱狀線。這是專門為顯示成交量設(shè)計的。如副圖公式:
VOL,VOLSTICK;
5、函數(shù):CROSSDOT 說明:畫叉狀線或x狀線。CROSS是交叉，DOT是點。如副圖公式:
ma1:ma(c,30),CROSSDOT;
6、函數(shù)：CIRCLEDOT 說明：畫小圓圈線,如副圖公式:
ma1:ma(c,30),CIRCLEDOT;
7、函數(shù)：LINETHICK 說明:改變指標(biāo)線粗細(xì)。取1、2、3、4......放在LINETHICK后面如:LINETHICK2,數(shù)字越大，線越粗，最大可取7。如副圖公式:
例1:ma1:ma(close,30),COLORFF00FF,linethick2;
例2:A:=C-REF(C,1);
A,COLORSTICK,LINETHICK4;
8、函數(shù)：POINTDOT 說明:畫點狀線,POINT是點、加點的意思。這個點狀線看起來有點太小了，可以用加粗線函數(shù)。如副圖公式:
ma1:ma(c,30),COLOR00FF00,POINTDOT,LINETHICK2;
我們編個指標(biāo)，看看都用了哪些線形函數(shù)。
{頂?shù)字笜?biāo)}
股價趨勢:3*SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1)-2*SMA(SMA((CLOSE-LLV(LOW,27))/(HHV(HIGH,27)-LLV(LOW,27))*100,5,1),3,1),COLORFF00FF,LINETHICK2;
底部警戒:10,COLORFFCCCC,POINTDOT;
買入警戒:IF(股價趨勢<=10,40,0),stick,linethick3,coloryellow;
買入信號:IF(CROSS(股價趨勢,底部警戒),80,0),stick,linethick3,colorblue;
強弱分界:50,COLORWHITE,POINTDOT,LINETHICK2;
頂部警戒:90,COLORFFCC66,POINTDOT;
賣出警戒:IF(股價趨勢>=85,40,0),stick,linethick3,colorred;
賣出信號:IF(CROSS(股價趨勢,頂部警戒),80,0),stick,linethick3,color00ff00;
頂?shù)字笜?biāo)指標(biāo)解析：
股價趨勢:3*移動平均((收盤價-最低值(最低價,27))/(最高值(最高價,27)-最低值(最低價,27))*100,5,1)-2*移動平均(移動平均((收盤價-最低值(最低價,27))/(最高值(最高價,27)-最低值(最低價,27))*100,5,1),3,1),COLORFF00FF,LINETHICK2;
底部警戒:10,COLORFFCCCC,POINTDOT;{點狀線}
買入警戒:條件函數(shù)(股價趨勢<=10,40,0),棒狀線,linethick3,coloryellow;{黃粗棒狀}
買入信號:條件函數(shù)(交叉函數(shù)(股價趨勢,底部警戒),80,0),棒狀線,linethick3,colorblue;{藍(lán)粗棒狀}
強弱分界:50,COLORWHITE,點狀線,LINETHICK2;{粗點狀線}
頂部警戒:90,COLORFFCC66,POINTDOT;{點狀線}
賣出警戒:條件函數(shù)(股價趨勢>=85,40,0),棒狀線,linethick3,colorred;{紅粗棒狀}
賣出信號:條件函數(shù)(交叉函數(shù)(股價趨勢,頂部警戒),80,0),棒狀線,linethick3,color00ff00;{綠粗棒狀}
二、繪圖函數(shù)
繪圖函數(shù)的功能是在主圖或副圖上設(shè)定條件輸出圖標(biāo)、直線、文字、數(shù)字、指標(biāo)線、指標(biāo)柱等。運用恰當(dāng)使編制出的主副圖指標(biāo)給以視覺上的美感。
1、函數(shù):DRAWICON
用法:DRAWICON(COND,PRICE,TYPE),當(dāng)COND條件滿足時,在PRICE位置畫TYPE號圖標(biāo)。
說明:在圖形上繪制小圖標(biāo)，其中TYPE可選3種圖標(biāo),編碼為1-3(1為紅臉、2為綠臉、3為平臉)。
示例：DRAWICON(CLOSE>OPEN,LOW,1);表示當(dāng)收陽時在最低價位置畫1號圖標(biāo)，也就是紅臉。
DRAWICON(CLOSE<OPEN,high,2);表示當(dāng)收陰時在最高價位置畫2號圖標(biāo)，也就是綠臉。
月均線主圖指標(biāo)示例：
ma1:ma(close,5),colorwhite,linethick2;{畫一條5日收盤價的均線，設(shè)置該線為粗白色}
ma2:ma(close,10),colorff00ff,linethick2;{畫一條10日收盤價的均線，設(shè)置該線為粗粉色}
ma3:ma(close,20),color00ff00,linethick2;{畫一條20日收盤價的均線，設(shè)置該線為粗綠色}
a1:=cross(ma1,ma2);{5日均線上穿10日均線，金叉}
a2:=cross(ma2,ma1);{10日均線下穿5日均線，死叉}
DRAWICON(a1,low,1);{當(dāng)a1條件滿足時，在最低價位置上顯示紅臉，表示此處可作為買入點}
DRAWICON(a2,high,2);{當(dāng)a2條件滿足時，在最高價位置上顯示綠臉，表示此處可作為賣出點}
