{空中休整----理想論壇一品茶緣編寫，通用版本副圖指標(biāo)}
INPUT.:N(2);
XYX:=ABS(C/REF(C,1)-1)*100<=N OR (ABS(C/O-1)*100<=N AND ABS(C/REF(C,1)-1)*100<=6);
GD:=H>=HHV(H,60)*0.9 AND COUNT(C>COST(75),3) AND (C/REF(C,1)-1)*100>=3.5;
GDSJ:=BARSLAST(GD);
目標(biāo):GDSJ<=8 AND COUNT(XYX,2)=2;圖片參考一：
舉例2：
下面指標(biāo)【一品抄底】，是個(gè)副圖指標(biāo)，既有線性輸出信號(hào)，也有買點(diǎn)提示信號(hào)，輸出類別眾多，就不是一個(gè)單獨(dú)的選股指標(biāo)。如何修改、拆分出自己需要的【底部】選股信號(hào)，成為一個(gè)單獨(dú)的選股指標(biāo)呢？如果還需要將【深坑】的信號(hào)，也單獨(dú)設(shè)置為選股指標(biāo)，又該如何修改呢？在此先當(dāng)做一個(gè)問(wèn)題吧，繼續(xù)看了后面（二）、（三）小節(jié)的引路，相信你自己來(lái)就行了！引用:
{一品抄底----理想論壇一品茶緣編寫，通用副圖指標(biāo)}
TYP := (HIGH + LOW + CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(*AVEDEV(TYP,14));
A:=REF(C,1);
RSI:=SMA(MAX(C-A,0),6,1)/SMA(ABS(C-A),6,1)*100;
A1:=(C/MA(C,5)-1)*100<-10;
A2:=(C/MA(C,13)-1)*100<-10;
A3:=(C/MA(C,34)-1)*100<-15;
A4:=RSI<18;
A5:=CCI<-120;
A6:=COUNT(ABS(C/REF(C,1)-1)*100>=6,30)>=1;
底部:A1 AND A2 AND A3 AND A4 AND A5 AND A6,COLOR00FFFF,LINETHICK2;
CDSJ:=BARSLAST(底部);
ZF:=(C/REF(C,1)-1)*100;
深坑:IF(BETWEEN(CDSJ,0,5) AND L<=REF(C,CDSJ) AND ZF<=-5,-0.5,0),COLORFF0000,LINETHICK2;
機(jī)會(huì):IF(CDSJ<=7 AND L<=REF(C,CDSJ),0.5,0),COLOR00FF00;圖片參考二：
（二）尋找選股信號(hào)的來(lái)源
所謂選股信號(hào)，多數(shù)都是屬于將已有的指標(biāo)公式中具有買點(diǎn)類的信號(hào)特征“剝離”出來(lái)。那么，在指標(biāo)中該保留哪些有用的源碼，刪除哪些無(wú)關(guān)的源碼呢？尋找選股信號(hào)的來(lái)源，就是最主要的過(guò)程。
尋找選股信號(hào)來(lái)源的方法，一般都是遵循從后往前尋找的原則。
具體步驟是：先找到發(fā)出指標(biāo)信號(hào)的那行代碼，然后查看該行代碼中的所有條件，需要用到上面哪些源碼，再?gòu)暮笸耙灰粚?duì)應(yīng)尋找出來(lái)；而其他無(wú)關(guān)的條件、修飾符號(hào)源碼，均可刪除。
舉例3：（本例子參考大慶老楊先生帖子，略有改動(dòng)）引用:
{股市馬經(jīng)----副圖指標(biāo)，源碼來(lái)自網(wǎng)絡(luò)}
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A2:=(黑馬線-REF(黑馬線,1))/REF(黑馬線,1)*100;
A3:=EMA(C,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢(shì)線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
A5:=(HHV(H,60)-C)/(HHV(H,60)-LLV(L,60))*100;
DRAWTEXT(FILTER(REF(黑馬線,1)>90 AND A2<0,7),黑馬線,'跑'),COLOR00FF00;
DRAWTEXT(CROSS(A1,黑馬線)AND 黑馬線<A5,黑馬線,'黑馬');
DRAWTEXT(CROSS(黑馬線,A5)AND 趨勢(shì)線<80,黑馬線,'追漲');
DRAWTEXT(CROSS(趨勢(shì)線,0)AND 黑馬線<40,5,'大黑馬');
底部:(A2<-10 AND A2>REF(A2,1))*25,colorred;
DRAWICON(底部 AND A3>REF(A3,1),25,4);
機(jī)會(huì)來(lái)臨:REF(IF((MA(C,5)-C)/C> AND (MA(C,10)-MA(C,5))/MA(C,5)>,30,0),1),COLORF00FF0;
大勢(shì)已去:IF(CROSS(黑馬線,A1)AND 黑馬線>70 AND 趨勢(shì)線>80,90,100),COLORFF0000;圖片參考三：
分析一下，這個(gè)公式中涉及“買”的信號(hào)有黑馬、追漲、大黑馬、底部和機(jī)會(huì)來(lái)臨五個(gè)明顯的，另外還有一個(gè)畫圖標(biāo)信號(hào)。
假如我們提取其中的【機(jī)會(huì)來(lái)臨】，仔細(xì)分析后，就是一句話：
機(jī)會(huì)來(lái)臨:REF(IF((MA(C,5)-C)/C> AND (MA(C,10)-MA(C,5))/MA(C,5)>,30,0),1);
這個(gè)可看作簡(jiǎn)單提取。
如果提取【大黑馬】的話，從后向前推，涉及趨勢(shì)線和黑馬線兩個(gè)定義，這部分都有用：
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢(shì)線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
DRAWTEXT(CROSS(趨勢(shì)線,0) AND 黑馬線<40,5,'大黑馬');（三）修改選股指標(biāo)的方法
根據(jù)以上選股公式的特征，結(jié)合尋找選股信號(hào)來(lái)源的方法，自己動(dòng)手修改選股信號(hào)，應(yīng)該就沒有太大的難度了！
舉例4：繼續(xù)承接上面（二）的例子。
修改步驟：
①先將線性輸出的A1、黑馬線、A4、趨勢(shì)線均限制輸出，方法很簡(jiǎn)單，就是在他們的冒號(hào)后面直接加上等號(hào)=；
②再刪去修飾符LINETHICK2,COLOR6600FF：
③將本來(lái)是文字輸出的“黑馬線”修改成信號(hào)輸出；先將“黑馬線”三個(gè)字移動(dòng)到最前面，并加上冒號(hào)：；然后保留符合黑馬線的限制條件CROSS(趨勢(shì)線,0) AND 黑馬線<40；同時(shí)刪除其余無(wú)關(guān)的代碼，包括文字輸出函數(shù)DRAWTEXT、位置、括號(hào)（）等。
修改成選股指標(biāo)后的源碼如下：引用:
A1:=3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:=EMA(A1,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢(shì)線:=(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2));
大黑馬:CROSS(趨勢(shì)線,0) AND 黑馬線<40;舉例5：
下面附圖指標(biāo)【大三浪】中，如何選出出現(xiàn)“買”字提示信號(hào)的選股指標(biāo)？引用:
{大三浪----理想論壇一品茶緣編寫，通用副圖指標(biāo)}
{大三浪指標(biāo)使用說(shuō)明:
均線粘合且多頭,長(zhǎng)期未漲莊吸籌;
目標(biāo)鎖定先跟蹤,出擊買入等豐收!}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
多頭粘合:IF(多頭 AND 粘合,1,0),COLORFF00FF,POINTDOT,LINETHICK0;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
莊股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標(biāo):IF(多頭 AND 粘合 AND 莊股,5,0),COLORFFFFFF,LINETHICK2;
跟蹤:IF(目標(biāo),BARSLAST(CROSS(目標(biāo),0))+1,0),COLOR00FF00,POINTDOT,LINETHICK2;
出擊:IF(CROSS(0.1,目標(biāo)) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
MJSJ:=BARSLAST(出擊>0);
漲幅:IF(MJSJ<=120,(C/REF(C,MJSJ)-1)*100,0),COLOR0000FF,POINTDOT,LINETHICK0;
日漲:IF(MJSJ<=120,漲幅/MJSJ,0),COLORFFFFFF,POINTDOT,LINETHICK0;
TPX:=MIN(MA65*,MA21*);
突破:IF(CROSS(C,TPX) AND 粘合 AND MA65>REF(MA65,1),10,0),COLOR0000FF,LINETHICK2;
{以下設(shè)置副圖顯示方式}
STICKLINE(多頭粘合,0,1,8,0),COLORFF00FF;
STICKLINE(莊股,0,MACD*10,8,0),COLORFFFF00;
DRAWTEXT(出擊=8,10,'★買'),COLOR00FFFF;
VERTLINE(CROSS(漲幅,20) AND COUNT(CROSS(漲幅,20),MJSJ)=1,2),COLOR0000FF;圖片參考四：
根據(jù)選股指標(biāo)的步驟，一步一步來(lái)：
①首先找到出現(xiàn)“★買”提示的一行代碼，發(fā)現(xiàn)她其實(shí)就是“出擊”的信號(hào)；
②從后往前，找到“出擊”信號(hào)的條件，發(fā)現(xiàn)他與“目標(biāo)”、MACD有關(guān)；
再次往前尋找，又發(fā)現(xiàn)“目標(biāo)”信號(hào)的條件，與“多頭”、“粘合”、“莊股”三個(gè)條件有關(guān)，由此，保留相關(guān)條件代碼，其余刪除，如下：
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
莊股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標(biāo):IF(多頭 AND 粘合 AND 莊股,5,0),COLORFFFFFF,LINETHICK2;
出擊:IF(CROSS(0.1,目標(biāo)) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
③限制輸出數(shù)量，只保留“出擊”信號(hào)的輸出，其他的輸出信號(hào)均加上等號(hào)=加以限制輸出；
④刪除多余的修飾符號(hào)，如：COLORFFFF00,POINTDOT,LINETHICK0等。
⑤IF格式也可簡(jiǎn)化，只保留需要的條件，輸出信號(hào)自動(dòng)為1。“出擊”兩字也可修改為“買”。
修改完最后保留的源碼如下：引用:
{大三浪----選股指標(biāo)}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
莊股:=COUNT(MACD<0,10)=10;
目標(biāo):=IF(多頭 AND 粘合 AND 莊股,5,0);
買:CROSS(0.1,目標(biāo)) AND CROSS(MACD,0);（四）導(dǎo)入選股指標(biāo)的途徑
①修改完后的選股指標(biāo)源碼，想做成選股指標(biāo)，并非放在指標(biāo)系統(tǒng)之下的【技術(shù)指標(biāo)】分類，一般是放入【條件選股】分類；便于設(shè)置預(yù)警、自動(dòng)選股。
②還可將選股指標(biāo)加入交易系統(tǒng)中，但需要注意的是：輸出信號(hào)必須為英文單詞的買入ENTERLONG、賣出EXITLONG信號(hào)。在應(yīng)用時(shí)，飛狐軟件輸入該交易系統(tǒng)指標(biāo)名稱，即可在主圖自動(dòng)顯示買賣信號(hào)的提示。
源碼如下：
ENTERLONG:CROSS(MA(C,3),MA(C,8));----表示輸出多頭買入信號(hào)。
EXITLONG:CROSS(MA(C,8),MA(C,3));----表示輸出空頭賣出信號(hào)。
圖片參考五：（五）選股指標(biāo)與一般副圖指標(biāo)的運(yùn)用區(qū)別
看了以上修改選股指標(biāo)的方法后，也許你應(yīng)該明白該如何從一個(gè)指標(biāo)中“剝離”出自己所需要的信號(hào)了；這時(shí)，你就可以利用盤中的預(yù)警功能，通過(guò)設(shè)置預(yù)警，讓軟件自動(dòng)監(jiān)控出現(xiàn)信號(hào)的目標(biāo)，并給出相應(yīng)的提示。（提醒：預(yù)警可能占用較大的內(nèi)存，要求電腦本身的配置不能過(guò)低。）
其實(shí)，原本的主、副圖指標(biāo)，只要有信號(hào)直接輸出的（非文字、柱狀線等的符號(hào)提示），就同樣可以用于盤中的手動(dòng)選股；只要看清輸出信號(hào)的數(shù)值變化，就可以利用數(shù)值的大小變化進(jìn)行對(duì)應(yīng)信號(hào)的選股了。（注意本地磁盤中應(yīng)該下載有需要用到的完整數(shù)據(jù)，選出的結(jié)果才是準(zhǔn)確的。）
圖片參考六、七：總結(jié)：本貼僅僅為指標(biāo)菜鳥提供最簡(jiǎn)單的、將一個(gè)指標(biāo)的某個(gè)信號(hào)剝離出來(lái)，修改為選股信號(hào)的指標(biāo)；本貼前面的指標(biāo)【一品抄底】，你需要什么信號(hào)呢？還是想再加入其他的條件？自己動(dòng)手試試看，相信你現(xiàn)在一定能行了！
至于更加復(fù)雜的、需要自己設(shè)定條件進(jìn)一步優(yōu)化的選股指標(biāo)，還請(qǐng)自己學(xué)習(xí)、掌握一定的指標(biāo)編寫基礎(chǔ)知識(shí)后，再去考慮。該問(wèn)題不在本貼的交流范圍之列。
聯(lián)系客服
