1、我想選出、股價在開盤一小時內(nèi)，一直在均價上方運行的股票；
答：
IF(OPENMINUTES(HOUR<1),C>DYNAINFO(11),0);
2、N日最高的漲跌幅、運行空間的相對位置怎么求？
答：
今收盤對于N日內(nèi)最低收盤價的漲幅:(c-llv(c,n))/llv(c,n)*100;
今收盤價對于N日最高收盤價的跌幅:(HHV(C,N)-C)/HHV(C,N)*100;
在過去N日內(nèi)運行空間的相對位置:(C-LLV(L,N))/(HHV(H,N)-LLV(L,N))*100;
3、選出股價N天內(nèi)曾出現(xiàn)過漲停，怎么表達(dá)？
答：
f:=ref(c,1)*1.1-c<0.01;
count(f,n)>0;//N天內(nèi)出現(xiàn)過漲停
4、創(chuàng)新高后返回均線附近怎么寫？
答：
COUNT(C>=HHV(C,N),5)=1 AND C/MA(C,m)>=1 AND C/MA(C,m)<1.02;//N=日期 M=均線
5、低開收大陽、低開收大陰怎么寫？
答：
{01-低開收大陽}
qj1:O<ref(l,1) and (C/REF(C,1)-1)*100>6;
{02-低開收大陰}
qj2:O<ref(l,1) and (C/REF(C,1)-1)*100<-5.1;
6、我想在一個指標(biāo)中、同時引用30、60、日線、周線MACD能辦到嗎？
答：
qj1:="macd.macd#min30";//30分鐘
qj2:="macd.macd#min60";//60分鐘
qj3:="macd.macd";//日線
qj4:="macd.macd#WEEK";//周線
7、均線斜率怎么寫？
答：
XL:ATAN(MA(C,N)/REF(MA(C,N),1)-1)*100;
{XL為N日均線的斜率}。
8、千鈞老師聽說過“空中加油”，怎么寫呀？
答：
{空中加油}
barslast(cross(c,MA(c,250)))<barslast(cross(MA(c,250),c)) and
BARSLAST(CROSS(C,MA(C,20)))<BARSLAST(CROSS(MA(C,20),C));
9、求兩個價位之間的最大值、和最小值，怎么寫？
答：
最大值：MAX(CLOSE,REF(CLOSE,N));
最小值：MIN(CLOSE,REF(CLOSE,N));
10、選股時怎樣去掉“ST”股？
答：把這個加到你的選股指標(biāo)中。
STRNCMP(STKNAME, 'ST', 2)=0 and STRNCMP(STKNAME, '*ST', 3)=0;
INBLOCK('ST')=0
11、MACD死叉10天后、又金叉怎么寫？
答：
DIFF:= EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:= EMA(DIFF,9);
MACD:= 2*(DIFF-DEA);
qj:=BARSLAST(CROSS(DEA,DIFF));
xu:IF(COUNT(qj,10)>=10,CROSS(DIFF,DEA) AND DIFF<0,0);
12、四連陽怎樣寫？
答：
四連陽:C>O and COUNT(C>REF(C,1),4)=4;
13、千鈞老師、我發(fā)現(xiàn)無量創(chuàng)新高的股票、值得注意，可我不知道怎么寫？
答：
vol/capital<0.02 and h>=hhv(high,20) and close>open;
14、老師你好，我把連續(xù)兩天以上收陰線、今日成交量大于昨日的30%以上、且均線系統(tǒng)依然多頭排列的，判斷是主力洗盤。
老師能幫我寫一下嗎？
答：
xu:COUNT(C<REF(C,1),2)>=2 and C<O and VOL>REF(VOL, 1)*1.30
and (MA(C,3)>MA(C,5) and MA(C,5)>MA(C,10)) and (ma(C,13)>ma(C,26)
and ma(C,26)>ma(C,120));
15、我想求指定日期的收盤價，怎樣寫？
答：
IF(DATE>1070530,CLOSE,0);
這是去年5月30日的收盤價，時間你可以自己調(diào)整。
16、老師、股價在10日均線和20日均線之間運行，且10日均線是上升趨勢，如何表達(dá)？
答：
RANGE(CLOSE,MA(CLOSE,20),MA(CLOSE,10)) and COUNT(ma(CLOSE,10)>REF(MA(CLOSE,10),1),3)>=3;
17、千鈞老師、我想在飛狐上、畫像大智慧L那樣的直方圖、飛狐可以嗎？
答：
你好：
飛狐以其強(qiáng)大的編輯功能著稱、如果運用好的話、在它的身上幾乎沒有做不到的事。
這是直方圖的畫法、你可以舉一反三。
input:left(500,0,999),top(450,0,999),right(550,0,999),bottom(550,0,999);
k1:=SYSPARAM(4)-((SYSPARAM(4)-SYSPARAM(5))/1000*top);
k2:=SYSPARAM(4)-((SYSPARAM(4)-SYSPARAM(5))/1000*bottom);
k3:=ROUND((SYSPARAM(3)-SYSPARAM(2))/1000*left)+2+SYSPARAM(2);
k4:=ROUND((SYSPARAM(3)-SYSPARAM(2))/1000*right)+2+SYSPARAM(2);
STICKLINE(BARPOS>=k3 and BARPOS<=k4,K1,K2,60,0),colorred;
18、老師你好、飛狐有沒有這樣的功能？就是當(dāng)信號出現(xiàn)時、寫出文字。過了這天我就不需要看這個提示了，讓它消失、再次出現(xiàn)信號時再出來。這能做的到嗎？
答：
你好：
當(dāng)然可以！主圖疊加。
AA:MA(C,10);
BB:MA(C,21);
CC:MA(C,120);
P:=SYSPARAM(1);
DRAWTEXT(IF(ISLASTBAR,CROSS(MA(C,10),C),0),MA(C,10),'中線做空');
DRAWTEXT(IF(ISLASTBAR,CROSS(MA(C,21),MA(C,120)),0),MA(C,120),'長線做多');
19、我想在日線下畫內(nèi)外盤的兩條線或柱線，可是只能看當(dāng)天的，老師怎樣才能看歷史內(nèi)外盤？
答：
變通一下不就可以了嗎？
外盤:vol-DYNAINFO(22);
內(nèi)盤:vol-DYNAINFO(23);
20、我想在看個股的同時、也能看到大盤，是在主圖上，可能叫主圖疊加大盤吧。
老師可以嗎？
答：
input:N(1070101,0,9999999);
yfqj:=barssince(ref(date,1)<N and date>=N);
qj:=ref(o,yfqj)/ref(indexo, yfqj);
qj1:=indexo*qj;
qj2:=indexh*qj;
qj3:=indexl*qj;
qj4:=indexc*qj;
stickline(qj4>=qj1,qj3,qj2, 0.1, 0 ), colormagenta;
stickline(qj4>=qj1,qj1,qj4, 5, 0 ), colormagenta;
stickline(qj4<qj1,qj3,qj2, 0.1, 0 ), colorgreen;
stickline(qj4<qj1,qj1,qj4, 5, 0 ), colorgreen;
21、千鈞老師你好：
我想在公式中隨時能看到交易時間的時、分、秒、就像在指標(biāo)中安裝了一個電子鐘。我有其它的用途。老師飛狐能做到嗎？
答：
你好
盡管我不知道你用它來做什么？但起碼我覺得你是在做捕捉主力大單的出現(xiàn)頻率統(tǒng)計工作、很有想法！
后期運用我就不喧賓奪主了、你自己把握和運用吧。
P:=SYSPARAM(1);
AA:=TIME-OPENMINUTES(HOUR)-OPENMINUTES(MINUTE);
DRAWTEXTEX(C,1,20,50,'當(dāng)前時刻：'+NUMTOSTR(AA[P],0)+' 秒');
22、老師你好，我想隨時查看每一分、每一秒的成交量，請老師能不能給我寫個這樣的語句？我的問題是不是有些過分？
答：
你好：
愛思考、愛鉆研，是大好事，應(yīng)該得到支持與鼓勵！加：10分。
P:=SYSPARAM(1);
DV:IF(CURRENTDATE,vol,0);
DRAWTEXTEX(C,1,10,10,' 當(dāng)前時刻成交量：'+NUMTOSTR(DV[P],0));
可以通過光標(biāo)、隨時查閱毎一時刻的成交量，包括各個周期，全天候。
23、老師你好：
主圖上有文字這對看盤及時了解個股的運行情況很有幫助，但太多時就有些亂了。
我想讓它們隨光標(biāo)移動，就是不用光標(biāo)時，文字在后臺、使用光標(biāo)時、文字隨光標(biāo)移動。
老師能幫我嗎？
答：
這時你要的，文字隨光標(biāo)移動：
DRAWTEXT(SYSPARAM(1)=BARPOS,CLOSE,'制作:一發(fā)千鈞');
24、我想把副圖的左半部分用什么辦法遮住，然后在那上面寫文字。
答：
遮擋副圖的左半部分：
把它放在你的源碼的最后面，我把顏色定位黑色，因為一般的軟件底色都是黑色、這樣可以不露聲色的遮擋左半部分。寫文字部分的源碼、放在這段源碼的后面就行了。
STICKLINE(BARPOS=DATACOUNT-120,0,1000,900,0),COLOR000000;
25、請高人幫編一個在n天內(nèi),maN1二次上穿maN2的選股指標(biāo).
例:在20天內(nèi),出現(xiàn)ma5二次上穿ma10
答：
INPUT:N(20),N1(5,1,300),N2(10,5,900);
M1:=MA(C,N1);
M2:=MA(C,N2);
TJ:COUNT(CROSS(M1,M2),N)>1;
26、收盤價上穿周線和月線如何編寫公式?謝謝
答：
01、
Y10:"MA.M2#MONTH";//不要線顯示可加上等號
金叉:CROSS(C,Y10),LINETHICK;
DRAWICON(金叉,L,4);
02、
{背景色}
DRAWGBK(1, COLORRGB(255,0,0), COLORRGB(190,190,190),1);
寫在第一句，顏色自己調(diào)整。
死叉:CROSS(Y10,C),LINETHICK;
DRAWTEXT(金叉,L,'金叉'),COLOR8000EE,ALIGN;
27、求兩點之間的距離【天數(shù)】
答：
你好：
假設(shè)第一點為【AA】、第二點為【BB】、求兩點間距離：
AA:=FILTER(CROSS(ma(C,5),ma(C,20)) and COUNT(ma(c,5)>REF(ma(c,5),1),3)=3,13);
BB:=FILTER(CROSS(ma(C,20),ma(C,5)) and COUNT(ma(c,20)<REF(ma(c,20),1),3)=3,13);
點A:=barslast(AA);
點B:=barslast(BB);
起點:=if(點A>0 and 點A<點B,點A,0);
終點:=if(點B>0 and 點B<點A,點B,0);
DRAWTEXTEX(c,1,20,10,'進(jìn)入上拐點：'+NUMTOSTR(起點[SYSPARAM(1)],0)+' 天'),Color00A8FF;
DRAWTEXTEX(c,1,20,150,'跌進(jìn)下拐點：'+NUMTOSTR(終點[SYSPARAM(1)],0)+' 天'),Color00A8FF;
28、這可能是個很簡單的問題，但對我來說很難，還請版主幫忙。就是如何編寫這個選股條件，即MACD底部二次金叉，謝謝
答：
你好：
1、首先界定金叉條件：
JC:=COUNT(CROSS(DIFF,DEA),BARSLAST(DEA>=0));
2、定位金叉的次數(shù)：
CS:=CROSS(DIFF,DEA) AND DEA<0 AND JC=2;
3、完整的選股公式：
DIFF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
JC:=COUNT(CROSS(DIFF,DEA),BARSLAST(DEA>=0));
選股:CROSS(DIFF,DEA) AND DEA<0 AND JC=2;
29、圓弧底，或者叫W底怎么寫？
答：
input:n(10),GATE1(25),GATE2(55),GATE3(20);
p1:=peak(3,N,2);
p3:=peak(3,N,1);
p2:=trough(3,N,2);
p4:=trough(3,N,1);
t1:=troughbars(3,N,2)-peakbars(3,N,1);
t2:=peakbars(3,N,1)-troughbars(3,N,1);
b12:=p1-p2;
bpt:=max(p3-p2,p3-p4);
b24:=abs(p2-p4);
min(t1,t2)>20 {左右底周期跨度均大于20}
and abs(t1-t2)/min(t1,t2)*100<gate1 {左右底跨度之差與左(或右)底跨度的比值小于gate1}
and bpt/b12*100<gate2 {底部反彈幅度與前期深度跌幅的比值小于gate2}
and b24/bpt*100<gate3 {左右底股價的差與底不凡彈高度的比值小于gate3}
and cross(close,1.05*p3); {最新收盤價向上突破頸線的1.05倍}
30、想求出股價第三次創(chuàng)新低，不知道該如何表達(dá)？
答：
試試這個
qj:=CROSS(LLV(L,33),L);
A:=BARSLAST(qj);
B:SUMBARS(A,3);
ref(C,B-1);
31、想快速查出股票上市第一天的開盤價，怎么寫？
答：
試試這個
OO:=O;
OO[1];
32、股價兩次穿越10日均線【二次穿越】怎樣表達(dá)？
答：
試試這個
qj:=cross(c,ma(c,10));
ref(c,SUMBARS(qj,2)-1);//兩次(本次計1次)穿越10日均線
33、分析家5.0，求助30日內(nèi)有3根大陽線，想知道第二根，第一根陽線到現(xiàn)在的天數(shù)
回復(fù)【聽雪尋股】
大陽:(C-O)/O>0.08,LINETHICK0;
WZ1:=BARSLAST( 大陽);
WZ2:=REF(WZ1,WZ1+1)+1+WZ1;
WZ3:=REF(WZ2,WZ2)+WZ2;
第一大陽到現(xiàn)在:(SUM( 大陽,30 )>=3)*WZ1,COLORFF99FF;{ 第一根陽線到現(xiàn)在的天數(shù)}
第二大陽到現(xiàn)在:(SUM( 大陽,30 )>=3)*WZ2,COLOR99FF99;{ 第二根陽線到現(xiàn)在的天數(shù)};
第三大陽到現(xiàn)在:(SUM( 大陽,30 )>=3)*WZ3,COLOR99FFFF;{ 第三根陽線到現(xiàn)在的天數(shù)};
{注:只有當(dāng)30天內(nèi)大陽線大于等于3根才算}
VERTLINE( 大陽,4 ),COLOR9900EE;
34、請問編公式的高手們，在通達(dá)信軟件中，要取得KDJ從現(xiàn)在往前的第二個交叉日到現(xiàn)在的周期，如何做到，請多指點，謝謝！
回復(fù)【聽雪尋股】:
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:SMA(RSV,3,1);
D:SMA(K,3,1);
J:3*K-2*D;
KD金叉:CROSS(K,D),LINETHICK0;{條件}
{分別計算三次條件成立時間}
WZ1:=BARSLAST( KD金叉);
WZ2:=REF(WZ1,WZ1+1)+1+WZ1;
WZ3:=REF(WZ2,WZ2)+WZ2;
{以上原碼可通用,下面是在通達(dá)信中光標(biāo)指向最后一根K線時在標(biāo)簽欄顯示數(shù)值}
第一金叉到現(xiàn)在:ISLASTBAR*WZ1,COLORFF99FF,NODRAW;{ 第一金叉到現(xiàn)在的天數(shù)}
第二金叉到現(xiàn)在:ISLASTBAR*WZ2,COLOR99FF99,NODRAW;{ 第二金叉到現(xiàn)在的天數(shù)};
第三金叉到現(xiàn)在:ISLASTBAR*WZ3,COLOR99FFFF,NODRAW;{ 第三金叉到現(xiàn)在的天數(shù)};
STICKLINE( KD金叉,0,70,0,0 ),COLOR9900EE;
實例一、
1、10日與20日均價線均向上運行，二者距離相差不大角度越陡越好；
2、股價從10日線上方跌破10日線，接近20日均價線，最好4日線也跌破10日線；
3、62日與133日均價線，沒有反作用力最好；
4、隨后產(chǎn)生的成交陽量越大越好；
5、MACD指標(biāo)圖形為空中加油技巧最好.
回復(fù)【大慶老楊】：
A4:=MA(C,4);
A10:=MA(C,10);
A20:=MA(C,20);
A62:=MA(C,62);
A133:=MA(C,133);
B1:=A10>REF(A10,1)*1.003 AND A20>REF(A20,1)*1.003 AND(A10-A20)<C/10;
B2:=C<A10 AND C>A20 AND A4<=A10;
B3:=A62>=REF(A62,1) AND A133>=REF(A133,1);
B4:=V/MA(V,10)>1.2;
B1 AND B2 AND B3 AND B4;
MACD指標(biāo)圖形為空中加油形態(tài)未編。
實例二、
能否幫我編一個這樣的指標(biāo)選股公式,條件1昨天是根中陰線(收盤價在開盤價3%以下),今天是根中陽線,關(guān)鍵點是,今天的收盤價與昨天的開盤價相等,用紅色顯示.條件2:今天的收盤價比昨天的開盤價高(5分錢以內(nèi))用白色顯示,能同圖吧,謝謝
回復(fù)【一發(fā)千鈞】：
兄弟！
你的條件也太苛刻了些吧！這四個條件同時存在的股票，那可是千載難尋吶！
不過。我還是耐著性子為你義務(wù)勞動一次。
因為這是個主圖疊加，為了突出你要的股價相等、我把紅色改成黃色、這樣更直觀一些。
qj1:=between(ref(c,1)/ref(c,2),0.95,0.97);
qj2:=between(c/ref(c,1),1.03,1.06);
qj3:=c=ref(o,1);
qj4:=abs(C-ref(O,1))>0.01 and abs(C-ref(O,1))<0.05;
aa:=qj1 and qj2 and qj3 and qj4;
bb:=qj1 and qj2 and qj4;
stickline(bb,h,l,1,0),Color00FFFF;
stickline(bb,O,C,8,0),Color00FFFF;
stickline(aa,h,l,1,0),ColorFFFFFF;
stickline(aa,O,C,8,0),ColorFFFFFF;
drawtext(aa,C*0.98,'大牛股'),ColorFFFFFF;
drawtext(bb,C*0.98,'牛股'),Color00FFFF;
實例三
我知道，用技術(shù)指標(biāo)改成選股公式.只要標(biāo)注兩條線交叉，就是一個選股條件..
但我現(xiàn)在碰上了一個沒有兩條線交叉的技術(shù)指標(biāo)...想把它改成選股公式。。
請各位版主和高手幫忙給改一下。。衷心感謝。。
下面是三條均線粘合的技術(shù)指標(biāo)。。當(dāng)三條均線粘合度達(dá)到5％時，在圖形上畫
黃色柱線。請問怎么將公式改成選股公式。。即，能選出圖形上出現(xiàn)柱線時的股票..
三條均線粘合
AA:=MA(C,5);
BB:=MA(C,10);
DD:=MA(C,30);
A1:=ABS((AA-C)/C);
A2:=ABS((BB-C)/C);
A3:=ABS((DD-C)/C);
B:=A1<0.05 AND A2<0.05 AND A3<0.05;
FILTER(B,10)=1;
回復(fù)一【大慶老楊】：
01、三條均線粘合
AA:=MA(C,5);
BB:=MA(C,10);
DD:=MA(C,30);
A1:=ABS((AA-C)/C);
A2:=ABS((BB-C)/C);
A3:=ABS((DD-C)/C);
B:=A1<0.05 AND A2<0.05 AND A3<0.05;
FILTER(B,10)=1;
02、如果不過濾，則為：
AA:=MA(C,5);
BB:=MA(C,10);
DD:=MA(C,30);
A1:=ABS((AA-C)/C);
A2:=ABS((BB-C)/C);
A3:=ABS((DD-C)/C);
A1<0.05 AND A2<0.05 AND A3<0.05;
回復(fù)二【王照華】：
AA:=MA(C,5);
BB:=MA(C,10);
DD:=MA(C,30);
A1:=ABS((AA-C)/C);
A2:=ABS((BB-C)/C);
A3:=ABS((DD-C)/C);
B:FILTER(A1<0.05 AND A2<0.05 AND A3<0.05,10);
實例四
當(dāng)前時間跳空缺口公式應(yīng)該是：LOW>REF(HIGH,1)
但是如果我要選 特定時間內(nèi)。 比如選出“當(dāng)天 9:30分-9:45分 這根15分鐘K線 向上產(chǎn)生跳空缺口”的所有股票。
這個應(yīng)該怎么寫呀。請高手幫幫忙呀。
回復(fù)【平陽虎】：
var0:=L>REF(H,1);
選:ref(var0=1,sumbars(time<94600,1)-1)
實例五
老師你好：
能給我寫一個選股公式嗎？
要求：當(dāng)天收盤價位于60日均線之上，且MACD上穿0軸。
先謝謝了！ 飛狐或通達(dá)信能用就成。
回復(fù)【估界文】
試試這個了；
a1:=close>=ma(close,60);
a2:=cross("macd.macd"(12,26,9),0);
a1 and a2;
實例六
麻煩老師幫忙寫個選股公式:股價在10日均線附近(最好是10日均線的正負(fù)0.5%左右),且10日均線是向上的... 謝謝你了
回復(fù)【估界文】
a1:=ma(c,10);
a2:=count(a1>ref(a1,1),3)=3;
between(c,a1*1.05,a1*0.95) and a2;
實例七
求版主或是高手編寫飛狐公式!
如下圖
1、流通股般小于5000萬
2、上市交易天數(shù)大于365天
3、KDJ的J值小于30
4、RSI的RSI1大于30
5、DMA中的ADX值小于30
回復(fù)【一發(fā)千鈞】
你好：
試試這個，不過目前小于5000萬流通盤的個股已經(jīng)為數(shù)不多了。
fc:=close;
qj0:=FINANCE( 7)<5000;
qj1:="kdj.j"<30;
qj2:="rsi.rsi1">30;
qj3:="dmi.adx"<30;
qj4:=BARSCOUNT(c)>365;
qj0 and qj1 and qj2 and qj3 and qj4;
實例八
求教難題，每月第1到第23個交易日表示法
思路是這樣的
每個月最少20個交易日，最多23個交易日，放棄常規(guī)的日歷表示法，用每個月第一個交易日到最后一個交易日，1-23選值，這樣來表示
每個月的第一個交易日，到最后一個交易日，如何用飛狐公式表示出來
2、如何引用歷史上每月第N個交易日的所有（開盤價-收盤價）/歷史上每月第N個交易日的總個數(shù)
回復(fù)【平陽虎】
希望你說明白些，讓別人知道你具體要輸出什么樣的指標(biāo)結(jié)果！
input:y(2007,1990,2050),m(12,1,12),n(1,1,30);//y參數(shù)指定你要辨認(rèn)的年份 M參數(shù)指定月份 N參數(shù)指定該年該月的第幾個交易日
dte:=(y-1900)*100+m;
dte1:=intpart(date/100);
nn:=count(dte1=dte,0);
barslast(cross(dte1=dte,0.5))+1=min(n,nn[datacount]);
實例九
如何將停牌用公式表示？
回復(fù)【太冷】
{大智慧L2去除停牌和ST股}
ST:=STRFIND(stkname,'ST',1)>0;
S:=STRFIND(stkname,'S',1)>0;
停牌:=(DYNAINFO(4)=0);
not(ST) and not(停牌) and not(S);
實例十
希望論壇的高手幫遍個選股的公式：N天內(nèi)上漲M%（N，M均可手動調(diào)整）
回復(fù)【聽股2】
漲:CLOSE/REF(CLOSE, n)>=m;
跌:1-(REF(CLOSE, n)/CLOSE<=m);
實例十一
我有這樣一個思路能否幫我編成??
條件1: L>MA(C,250): 股價在年線附近盤整22日以上 LOW 不能下跌MA(C,250);如果 LOW 真的下跌MA(C,250);就再次 條件1
條件2: 盤整22日之後 任何K線的 C突破22日的 最高價
條件3: 22日的 最高價要半年(120日)的最高價:=買入
回復(fù)【大慶老楊】
你的后兩個條件其實是一個，C要突破22日的最高價，而22日的最高價以是半年的最高價，所以C要大于等于半年的最高價。
條件1:=COUNT(L>MA(C,250),22)=22 AND H/MA(C,250)<1.1;
條件2:=C>=REF(HHV(H,120),1);
買入:條件1 AND 條件2;
可能選不出股來。這個公式的兩個條件可分開作為兩個公式使用，如下：
公式1:COUNT(L>MA(C,250),22)=22 AND H/MA(C,250)<1.1;
公式2:C>=REF(HHV(H,120),1);
估計你想要的是這個：
條件1:=COUNT(L>MA(C,250),22)=22 AND H/MA(C,250)<1.1;
條件2:=C>=REF(HHV(H,22),1);
買入:條件1 AND 條件2;
實例十二、
求助，無助了，老師在嗎，求以前具體日期的主動買盤
input:n(10,1,1000);
input:p(1080129,1071001,1080410);
cc:=if(date=p,c,0);
dr:=IF(buyvol*cc/100>=n and date=p,buyvol*cc,0);
zdr:=SUM(dr,0);
dc:=IF(sellvol*cc/100>=n and date=p,sellvol*cc,0);
zdc:=SUM(dc,0);
手筆差:zdr-zdc;
準(zhǔn)備在飛狐里利用指標(biāo)排序看一下，主要是要計算以前日期里的分筆 主動買賣盤，但是出來的數(shù)據(jù)全是0，不知道哪里不對了，希望老師指點一下，弄了兩個晚上了，頭都大了，多謝！
回復(fù)【一發(fā)千鈞】
你好：
按照你一樓的敘述、你是想看以前的每筆手?jǐn)?shù)差是吧？
把一樓你的公式做成擴(kuò)展數(shù)據(jù)，如果你以前沒做過，就建在一號數(shù)據(jù)。
然后用這個語句調(diào)用：
{01}、這個是擴(kuò)展數(shù)據(jù)【分筆周期】：
dr:=sum(IF(buyvol*c/100>=100,buyvol*c,0),0);
dc:=sum(if(sellvol*c/100>=100,sellvol*c,0),0);
手差:dr-dc;
{02}、這個是你調(diào)用的N日數(shù)據(jù)【日線】：
input:p(1080128,1071001,1080410);
手?jǐn)?shù)差:=sum(if(date=p,EXTDATA(1),0),0);
DRAWTEXTEX(c,1,20,0,' 29日手?jǐn)?shù)差:'+NUMTOSTR(手?jǐn)?shù)差,0)+' 手');
實例十三、
因為時間的原因，沒辦法天天整理股票，請求寫一個這樣的指標(biāo)：
指定日期，找出兩市中所有漲幅大于等于５%（含ST漲停，如４.９９%），換手率在前３０名，振幅前３０名的股票。三個條件不要同時具備。
如“指定日期２００８年１月２１日，所有漲幅超過５%有股票、換手率在前３０名的股票，振幅前３０名的股票".
回復(fù)【估界文】
這個是否可行：
{n:5 30 10} {m:5 21 6}
(close/ref(close,1)-1)*100>=5 and vol/capital*100>n and (H/l-1)*100>=m;
隨時調(diào)整參數(shù)，可能含有停牌的。
實例十四【怎樣在飛狐分時上寫副圖指標(biāo)？】
求助：
請教一發(fā)千鈞老師如何在分時圖中將外盤(即分鐘成交量)和委賣(所有的開盤后委賣,包含委賣1、委賣2、委賣3)用曲線來顯示,并且把該曲線顯示在分時圖下方的成交量區(qū)域內(nèi)?
我想表達(dá)的是下面兩句：
1、委賣:=委賣量(1)+委賣量(2)+委賣量(3);
委賣總量:=求和(委賣,0);
2、外盤:=求和(主動性買單,0);
我想把下面兩句用曲線的形式在主圖中表現(xiàn)出來，剛才看了您在創(chuàng).幻給我發(fā)的圖，就是我想要表達(dá)的（只是內(nèi)容不是委賣總量和外盤），請老師在百忙中抽出時間幫助我，再次感謝您的幫助，謝謝
回復(fù)【一發(fā)千鈞】
01、案例：
樓主你好：
你是創(chuàng).幻的那位朋友吧？
下午收盤后，看了你的短信，你的問題、我已在創(chuàng).幻你的帖下作了回復(fù)。
現(xiàn)在重復(fù)一遍：
飛狐軟件默認(rèn)的功能中是不支持在分時圖上做副圖指標(biāo)的。
不過、可以通過分割分時主圖，達(dá)到把副圖做進(jìn)去的目的。
先分割分時主圖：
r:=DYNAINFO(3);
f:=max(hh-r,r-LL);
q1:=r-f*1.01;//主圖下邊線
q2:=r-2*f*1.0125;//副圖下邊線(0位線)
然后在做副圖指標(biāo)，用主圖疊加的方式，把它做到副圖下邊線的位置。
我給你做了一個分時疊加MACD，供你參考！
大同小異，依此類推。
你就可以把你要表達(dá)的委托價做到副圖的下變線里：
//在副圖1疊加macd
dk:="macd.macd";
k:="macd.diff";
d:="macd.dea";
kh:=hhv(max(d,k),0);
kL:=LLv(min(k,d),0);
kb:=(q1-q2)/(kh-kL);
ky:=(q1+q2-kb*(kh+kL))/2;
k*kb[q]+ky[q],Color0000FF,LINETHICK2;//DIFF畫在副圖下邊線
d*kb[q]+ky[q],Color00FF00,LINETHICK2;//DEA畫在副圖下邊線
STICKLINE(dk>0,r,r+dk*4,0,1),COLORRED;//MACD柱狀線畫在前收盤位置
STICKLINE(dk<0,r,r+dk*4,0,1),COLORCYAN;//MACD柱狀線畫在前收盤位置
注意！上面這個是案例！不能直接使用，切勿直接下載使用！
02、指標(biāo)
r:=DYNAINFO(3);
q:=DATACOUNT;
hh:=DYNAINFO(5);
LL:=DYNAINFO(6);
f:=MAX(hh-r,r-LL);
q1:=r-f*1.01;//主圖下邊線
q2:=r-2*f*1.0125;//副圖1下邊線(0位線)
//在副圖1疊加【委買賣】
qj1:=ASKVOL(1)+ASKVOL(2)+ASKVOL(3);
qj2:=BIDVOL(1)+BIDVOL(2)+BIDVOL(3);
qj3:=SUM(qj2,0);
qj4:=SUM(qj1,0);
kh:=HHV(MAX(qj4,qj3),0);
kL:=LLV(MIN(qj3,qj4),0);
kb:=(q1-q2)/(kh-kL);
ky:=(q1+q2-kb*(kh+kL))/2;
qj3*kb[q]+ky[q],Color0000FF,LINETHICK2;//在附圖下邊畫線
qj4*kb[q]+ky[q],Color00FF00,LINETHICK2;//在副圖下邊畫線
實例十五：
求助【問】：
在網(wǎng)上看到一個選股的思路，覺得很好。可是自己寫不了。想請楊版主寫一個選股公式。思路是：
1.股價前期（2至7天前）放量收大陽（6點以上）
2.橫盤期間，股價小陰小陽或收十字星
3.5日均線和10日均線呈多頭排列，橫盤期間5日線不交叉10日線并保持向上趨勢
4.橫盤期間，量能縮小
5.放量突破調(diào)整平臺時預(yù)警
回復(fù)：【大慶老楊】
A1:=COUNT(C/REF(C,1)>1.06,10)=1;
A2:=COUNT(BETWEEN(C/REF(C,1),0.985,1.015),3)=2;
A3:=MA(C,5)>REF(MA(C,5),1)AND MA(C,10)>REF(MA(C,10),1)AND COUNT(MA(C,5)>MA(C,10),3)=3;
A4:=COUNT(V/MA(V,10)<0.95,4)=3;
ENTERLONG:V/MA(V,10)>1.2 AND A1 AND A2 AND A3 AND A4;
