Linux下AT&T匯編語法格式簡介
AT&T 格式Linux 匯編語法格式
在 AT&T 匯編格式中，寄存器名要加上 ‘%‘ 作為前綴；而在 Intel 匯編格式中，寄存器名不需要加前綴。例如：
AT&T 格式
Intel 格式
pushl %eax
push eax
在 AT&T 匯編格式中，用 ‘$‘ 前綴表示一個立即操作數(shù)；而在 Intel 匯編格式中，立即數(shù)的表示不用帶任何前綴。例如：
AT&T 格式
Intel 格式
pushl $1
push 1
AT&T 和 Intel 格式中的源操作數(shù)和目標(biāo)操作數(shù)的位置正好相反。在 Intel 匯編格式中，目標(biāo)操作數(shù)在源操作數(shù)的左邊；而在 AT&T 匯編格式中，目標(biāo)操作數(shù)在源操作數(shù)的右邊。例如：
AT&T 格式
Intel 格式
addl $1, %eax
add eax, 1
在 AT&T 匯編格式中，操作數(shù)的字長由操作符的最后一個字母決定，后綴‘b‘、‘w‘、‘l‘分別表示操作數(shù)為字節(jié)（byte，8 比特）、字（word，16 比特）和長字（long，32比特）；而在 Intel 匯編格式中，操作數(shù)的字長是用 "byte ptr" 和 "word ptr" 等前綴來表示的。例如：
AT&T 格式
Intel 格式
movb val, %al
mov al, byte ptr val
在 AT&T 匯編格式中，絕對轉(zhuǎn)移和調(diào)用指令（jump/call）的操作數(shù)前要加上‘*‘作為前綴，而在 Intel 格式中則不需要。
遠(yuǎn)程轉(zhuǎn)移指令和遠(yuǎn)程子調(diào)用指令的操作碼，在 AT&T 匯編格式中為 "ljump" 和 "lcall"，而在 Intel 匯編格式中則為 "jmp far" 和 "call far"，即：
AT&T 格式
Intel 格式
ljump $section, $offset
jmp far section:offset
lcall $section, $offset
call far section:offset
與之相應(yīng)的遠(yuǎn)程返回指令則為：
AT&T 格式
Intel 格式
lret $stack_adjust
ret far stack_adjust
在 AT&T 匯編格式中，內(nèi)存操作數(shù)的尋址方式是
section:disp(base, index, scale)
而在 Intel 匯編格式中，內(nèi)存操作數(shù)的尋址方式為：
section:[base + index*scale + disp]
由于 Linux 工作在保護(hù)模式下，用的是 32 位線性地址，所以在計(jì)算地址時不用考慮段基址和偏移量，而是采用如下的地址計(jì)算方法：
disp + base + index * scale
下面是一些內(nèi)存操作數(shù)的例子：
AT&T 格式
Intel 格式
movl -4(%ebp), %eax
mov eax, [ebp - 4]
movl array(, %eax, 4), %eax
mov eax, [eax*4 + array]
movw array(%ebx, %eax, 4), %cx
mov cx, [ebx + 4*eax + array]
movb $4, %fs:(%eax)
mov fs:eax, 4
Hello World!
既然所有程序設(shè)計(jì)語言的第一個例子都是在屏幕上打印一個字符串 "Hello World!"，那我們也以這種方式來開始介紹 Linux 下的匯編語言程序設(shè)計(jì)。
在 Linux 操作系統(tǒng)中，你有很多辦法可以實(shí)現(xiàn)在屏幕上顯示一個字符串，但最簡潔的方式是使用 Linux 內(nèi)核提供的系統(tǒng)調(diào)用。使用這種方法最大的好處是可以直接和操作系統(tǒng)的內(nèi)核進(jìn)行通訊，不需要鏈接諸如 libc 這樣的函數(shù)庫，也不需要使用 ELF 解釋器，因而代碼尺寸小且執(zhí)行速度快。
Linux 是一個運(yùn)行在保護(hù)模式下的 32 位操作系統(tǒng)，采用 flat memory 模式，目前最常用到的是 ELF 格式的二進(jìn)制代碼。一個 ELF 格式的可執(zhí)行程序通常劃分為如下幾個部分：.text、.data 和 .bss，其中 .text 是只讀的代碼區(qū)，.data 是可讀可寫的數(shù)據(jù)區(qū)，而 .bss 則是可讀可寫且沒有初始化的數(shù)據(jù)區(qū)。代碼區(qū)和數(shù)據(jù)區(qū)在 ELF 中統(tǒng)稱為 section，根據(jù)實(shí)際需要你可以使用其它標(biāo)準(zhǔn)的 section，也可以添加自定義 section，但一個 ELF 可執(zhí)行程序至少應(yīng)該有一個 .text 部分。下面給出我們的第一個匯編程序，用的是 AT&T 匯編語言格式：
例1. AT&T 格式
#hello.s
.data # 數(shù)據(jù)段聲明
msg : .string "Hello, world!\\n" # 要輸出的字符串
len = . - msg # 字串長度
.text # 代碼段聲明
.global _start # 指定入口函數(shù)
_start: # 在屏幕上顯示一個字符串
movl $len, %edx # 參數(shù)三：字符串長度
movl $msg, %ecx # 參數(shù)二：要顯示的字符串
movl $1, %ebx # 參數(shù)一：文件描述符(stdout)
movl $4, %eax # 系統(tǒng)調(diào)用號(sys_write)
int $0x80 # 調(diào)用內(nèi)核功能
# 退出程序
movl $0,%ebx # 參數(shù)一：退出代碼
movl $1,%eax # 系統(tǒng)調(diào)用號(sys_exit)
int $0x80 # 調(diào)用內(nèi)核功能
初次接觸到 AT&T 格式的匯編代碼時，很多程序員都認(rèn)為太晦澀難懂了，沒有關(guān)系，在 Linux 平臺上你同樣可以使用 Intel 格式來編寫匯編程序：
例2. Intel 格式
; hello.asm
section .data ; 數(shù)據(jù)段聲明
msg db "Hello, world!", 0xA ; 要輸出的字符串
len equ $ - msg ; 字串長度
section .text ; 代碼段聲明
global _start ; 指定入口函數(shù)
_start: ; 在屏幕上顯示一個字符串
mov edx, len ; 參數(shù)三：字符串長度
mov ecx, msg ; 參數(shù)二：要顯示的字符串
mov ebx, 1 ; 參數(shù)一：文件描述符(stdout)
mov eax, 4 ; 系統(tǒng)調(diào)用號(sys_write)
int 0x80 ; 調(diào)用內(nèi)核功能
; 退出程序
mov ebx, 0 ; 參數(shù)一：退出代碼
mov eax, 1 ; 系統(tǒng)調(diào)用號(sys_exit)
int 0x80 ; 調(diào)用內(nèi)核功能
上 面兩個匯編程序采用的語法雖然完全不同，但功能卻都是調(diào)用 Linux 內(nèi)核提供的 sys_write 來顯示一個字符串，然后再調(diào)用 sys_exit 退出程序。在 Linux 內(nèi)核源文件 include/asm-i386/unistd.h 中，可以找到所有系統(tǒng)調(diào)用的定義。
Linux 匯編工具
Linux 平臺下的匯編工具雖然種類很多，但同 DOS/Windows 一樣，最基本的仍然是匯編器、連接器和調(diào)試器。
1. 匯編器
匯 編器（assembler）的作用是將用匯編語言編寫的源程序轉(zhuǎn)換成二進(jìn)制形式的目標(biāo)代碼。Linux 平臺的標(biāo)準(zhǔn)匯編器是 GAS，它是 GCC 所依賴的后臺匯編工具，通常包含在 binutils 軟件包中。GAS 使用標(biāo)準(zhǔn)的 AT&T 匯編語法，可以用來匯編用 AT&T 格式編寫的程序：
[xiaowp@gary code]$ as -o hello.o hello.s
Linux 平臺上另一個經(jīng)常用到的匯編器是 NASM，它提供了很好的宏指令功能，并能夠支持相當(dāng)多的目標(biāo)代碼格式，包括 bin、a.out、coff、elf、rdf 等。NASM 采用的是人工編寫的語法分析器，因而執(zhí)行速度要比 GAS 快很多，更重要的是它使用的是 Intel 匯編語法，可以用來編譯用 Intel 語法格式編寫的匯編程序：
[xiaowp@gary code]$ nasm -f elf hello.asm
2. 鏈接器
由 匯編器產(chǎn)生的目標(biāo)代碼是不能直接在計(jì)算機(jī)上運(yùn)行的，它必須經(jīng)過鏈接器的處理才能生成可執(zhí)行代碼。鏈接器通常用來將多個目標(biāo)代碼連接成一個可執(zhí)行代碼，這樣 可以先將整個程序分成幾個模塊來單獨(dú)開發(fā)，然后才將它們組合(鏈接)成一個應(yīng)用程序。 Linux 使用 ld 作為標(biāo)準(zhǔn)的鏈接程序，它同樣也包含在 binutils 軟件包中。匯編程序在成功通過 GAS 或 NASM 的編譯并生成目標(biāo)代碼后，就可以使用 ld 將其鏈接成可執(zhí)行程序了：
[xiaowp@gary code]$ ld -s -o hello hello.o
3. 調(diào)試器
有 人說程序不是編出來而是調(diào)出來的，足見調(diào)試在軟件開發(fā)中的重要作用，在用匯編語言編寫程序時尤其如此。Linux 下調(diào)試匯編代碼既可以用 GDB、DDD 這類通用的調(diào)試器，也可以使用專門用來調(diào)試匯編代碼的 ALD(Assembly Language Debugger)。
從調(diào)試的角度來看，使用 GAS 的好處是可以在生成的目標(biāo)代碼中包含符號表(symbol table)，這樣就可以使用 GDB 和 DDD 來進(jìn)行源碼級的調(diào)試了。要在生成的可執(zhí)行程序中包含符號表，可以采用下面的方式進(jìn)行編譯和鏈接：
[xiaowp@gary code]$ as --gstabs -o hello.o hello.s
[xiaowp@gary code]$ ld -o hello hello.o
執(zhí)行 as 命令時帶上參數(shù) --gstabs 可以告訴匯編器在生成的目標(biāo)代碼中加上符號表，同時需要注意的是，在用 ld 命令進(jìn)行鏈接時不要加上 -s 參數(shù)，否則目標(biāo)代碼中的符號表在鏈接時將被刪去。
匯編程序員通常面對的都是一些比較苛刻的軟硬件環(huán)境，短小精悍的ALD可能更能符合實(shí)際的需要，因此下面主要介紹一下如何用ALD來調(diào)試匯編程序。首先在命令行方式下執(zhí)行ald命令來啟動調(diào)試器，該命令的參數(shù)是將要被調(diào)試的可執(zhí)行程序：
[xiaowp@gary doc]$ ald hello
Assembly Language Debugger 0.1.3
Copyright (C) 2000-2002 Patrick Alken
hell ELF Intel 80386 (32 bit), LSB, Executable, Version 1 (current)
Loading debugging symbols...(15 symbols loaded)
ald>
當(dāng) ALD 的提示符出現(xiàn)之后，用 disassemble 命令對代碼段進(jìn)行反匯編：
ald> disassemble -s .text
Disassembling section .text (0x08048074 - 0x08048096)
08048074 BA0F000000 mov edx, 0xf
08048079 B998900408 mov ecx, 0x8049098
0804807E BB01000000 mov ebx, 0x1
08048083 B804000000 mov eax, 0x4
08048088 CD80 int 0x80
0804808A BB00000000 mov ebx, 0x0
0804808F B801000000 mov eax, 0x1
08048094 CD80 int 0x80
上述輸出信息的第一列是指令對應(yīng)的地址碼，利用它可以設(shè)置在程序執(zhí)行時的斷點(diǎn)：
ald> break 0x08048088
Breakpoint 1 set for 0x08048088
斷點(diǎn)設(shè)置好后，使用 run 命令開始執(zhí)行程序。ALD 在遇到斷點(diǎn)時將自動暫停程序的運(yùn)行，同時會顯示所有寄存器的當(dāng)前值：
ald> run
Starting program: hello
Breakpoint 1 encountered at 0x08048088
eax = 0x00000004 ebx = 0x00000001 ecx = 0x08049098 edx = 0x0000000F
esp = 0xBFFFF6C0 ebp = 0x00000000 esi = 0x00000000 edi = 0x00000000
ds = 0x0000002B es = 0x0000002B fs = 0x00000000 gs = 0x00000000
ss = 0x0000002B cs = 0x00000023 eip = 0x08048088 eflags = 0x00000246
Flags: PF ZF IF
08048088 CD80 int 0x80
如果需要對匯編代碼進(jìn)行單步調(diào)試，可以使用 next 命令：
ald> next
Hello, world!
eax = 0x0000000F ebx = 0x00000000 ecx = 0x08049098 edx = 0x0000000F
esp = 0xBFFFF6C0 ebp = 0x00000000 esi = 0x00000000 edi = 0x00000000
ds = 0x0000002B es = 0x0000002B fs = 0x00000000 gs = 0x00000000
ss = 0x0000002B cs = 0x00000023 eip = 0x0804808F eflags = 0x00000346
Flags: PF ZF TF IF
0804808F B801000000 mov eax, 0x1
若想獲得 ALD 支持的所有調(diào)試命令的詳細(xì)列表，可以使用 help 命令：
ald> help
Commands may be abbreviated.
If a blank command is entered, the last command is repeated.
Type `help <command>‘‘ for more specific information on <command>.
General commands
attach clear continue detach disassemble
enter examine file help load
next quit register run set
step unload window write
Breakpoint related commands
break delete disable enable ignore
lbreak tbreak
即 便是最簡單的匯編程序，也難免要用到諸如輸入、輸出以及退出等操作，而要進(jìn)行這些操作則需要調(diào)用操作系統(tǒng)所提供的服務(wù)，也就是系統(tǒng)調(diào)用。除非你的程序只完 成加減乘除等數(shù)學(xué)運(yùn)算，否則將很難避免使用系統(tǒng)調(diào)用，事實(shí)上除了系統(tǒng)調(diào)用不同之外，各種操作系統(tǒng)的匯編編程往往都是很類似的。
在 Linux 平臺下有兩種方式來使用系統(tǒng)調(diào)用：利用封裝后的 C 庫（libc）或者通過匯編直接調(diào)用。其中通過匯編語言來直接調(diào)用系統(tǒng)調(diào)用，是最高效地使用 Linux 內(nèi)核服務(wù)的方法，因?yàn)樽罱K生成的程序不需要與任何庫進(jìn)行鏈接，而是直接和內(nèi)核通信。
和 DOS 一樣，Linux 下的系統(tǒng)調(diào)用也是通過中斷（int 0x80）來實(shí)現(xiàn)的。在執(zhí)行 int 80 指令時，寄存器 eax 中存放的是系統(tǒng)調(diào)用的功能號，而傳給系統(tǒng)調(diào)用的參數(shù)則必須按順序放到寄存器 ebx，ecx，edx，esi，edi 中，當(dāng)系統(tǒng)調(diào)用完成之后，返回值可以在寄存器 eax 中獲得。
所有 的系統(tǒng)調(diào)用功能號都可以在文件 /usr/include/bits/syscall.h 中找到，為了便于使用，它們是用 SYS_<name> 這樣的宏來定義的，如 SYS_write、SYS_exit 等。例如，經(jīng)常用到的 write 函數(shù)是如下定義的：
ssize_t write(int fd, const void *buf, size_t count);
該 函數(shù)的功能最終是通過 SYS_write 這一系統(tǒng)調(diào)用來實(shí)現(xiàn)的。根據(jù)上面的約定，參數(shù) fb、buf 和 count 分別存在寄存器 ebx、ecx 和 edx 中，而系統(tǒng)調(diào)用號 SYS_write 則放在寄存器 eax 中，當(dāng) int 0x80 指令執(zhí)行完畢后，返回值可以從寄存器 eax 中獲得。
或許你已經(jīng)發(fā)現(xiàn)，在進(jìn)行系統(tǒng)調(diào)用時至多只有 5 個寄存器能夠用來保存參數(shù)，難道所有系統(tǒng)調(diào)用的參數(shù)個數(shù)都不超過 5 嗎？當(dāng)然不是，例如 mmap 函數(shù)就有 6 個參數(shù)，這些參數(shù)最后都需要傳遞給系統(tǒng)調(diào)用 SYS_mmap：
void * mmap(void *start, size_t length, int prot , int flags, int fd, off_t offset);c
當(dāng) 一個系統(tǒng)調(diào)用所需的參數(shù)個數(shù)大于 5 時，執(zhí)行int 0x80 指令時仍需將系統(tǒng)調(diào)用功能號保存在寄存器 eax 中，所不同的只是全部參數(shù)應(yīng)該依次放在一塊連續(xù)的內(nèi)存區(qū)域里，同時在寄存器 ebx 中保存指向該內(nèi)存區(qū)域的指針。系統(tǒng)調(diào)用完成之后，返回值仍將保存在寄存器 eax 中。
由 于只是需要一塊連續(xù)的內(nèi)存區(qū)域來保存系統(tǒng)調(diào)用的參數(shù)，因此完全可以像普通的函數(shù)調(diào)用一樣使用棧(stack)來傳遞系統(tǒng)調(diào)用所需的參數(shù)。但要注意一點(diǎn)， Linux 采用的是 C 語言的調(diào)用模式，這就意味著所有參數(shù)必須以相反的順序進(jìn)棧，即最后一個參數(shù)先入棧，而第一個參數(shù)則最后入棧。如果采用棧來傳遞系統(tǒng)調(diào)用所需的參數(shù)，在執(zhí)行 int 0x80 指令時還應(yīng)該將棧指針的當(dāng)前值復(fù)制到寄存器 ebx中。
在 Linux 操作系統(tǒng)中，當(dāng)一個可執(zhí)行程序通過命令行啟動時，其所需的參數(shù)將被保存到棧中：首先是 argc，然后是指向各個命令行參數(shù)的指針數(shù)組 argv，最后是指向環(huán)境變量的指針數(shù)據(jù) envp。在編寫匯編語言程序時，很多時候需要對這些參數(shù)進(jìn)行處理，下面的代碼示范了如何在匯編代碼中進(jìn)行命令行參數(shù)的處理：
例3. 處理命令行參數(shù)
# args.s
.text
.globl _start
_start:
popl %ecx # argc
vnext:
popl %ecx # argv
test %ecx, %ecx # 空指針表明結(jié)束
jz exit
movl %ecx, %ebx
xorl %edx, %edx
strlen:
movb (%ebx), %al
inc %edx
inc %ebx
test %al, %al
jnz strlen
movb $10, -1(%ebx)
movl $4, %eax # 系統(tǒng)調(diào)用號(sys_write)
movl $1, %ebx # 文件描述符(stdout)
int $0x80
jmp vnext
exit: movl $1,%eax # 系統(tǒng)調(diào)用號(sys_exit)
xorl %ebx, %ebx # 退出代碼
int $0x80
ret
GCC 內(nèi)聯(lián)匯編
用 匯編編寫的程序雖然運(yùn)行速度快，但開發(fā)速度非常慢，效率也很低。如果只是想對關(guān)鍵代碼段進(jìn)行優(yōu)化，或許更好的辦法是將匯編指令嵌入到 C 語言程序中，從而充分利用高級語言和匯編語言各自的特點(diǎn)。但一般來講，在 C 代碼中嵌入?yún)R編語句要比"純粹"的匯編語言代碼復(fù)雜得多，因?yàn)樾枰鉀Q如何分配寄存器，以及如何與C代碼中的變量相結(jié)合等問題。
GCC 提供了很好的內(nèi)聯(lián)匯編支持，最基本的格式是：
__asm__("asm statements");
例如：
__asm__("nop");
如果需要同時執(zhí)行多條匯編語句，則應(yīng)該用"\\n\\t"將各個語句分隔開，例如：
__asm__( "pushl %%eax \\n\\t"
"movl $0, %%eax \\n\\t"
"popl %eax");
通常嵌入到 C 代碼中的匯編語句很難做到與其它部分沒有任何關(guān)系，因此更多時候需要用到完整的內(nèi)聯(lián)匯編格式：
__asm__("asm statements" : outputs : inputs : registers-modified);
插入到 C 代碼中的匯編語句是以":"分隔的四個部分，其中第一部分就是匯編代碼本身，通常稱為指令部，其格式和在匯編語言中使用的格式基本相同。指令部分是必須的，而其它部分則可以根據(jù)實(shí)際情況而省略。
在將匯編語句嵌入到C代碼中時，操作數(shù)如何與C代碼中的變量相結(jié)合是個很大的問題。GCC采用如下方法來解決這個問題：程序員提供具體的指令，而對寄存器的使用則只需給出"樣板"和約束條件就可以了，具體如何將寄存器與變量結(jié)合起來完全由GCC和GAS來負(fù)責(zé)。
在GCC 內(nèi)聯(lián)匯編語句的指令部中，加上前綴‘‘%‘‘的數(shù)字(如%0，%1)表示的就是需要使用寄存器的"樣板"操作數(shù)。指令部中使用了幾個樣板操作數(shù)，就表明有 幾個變量需要與寄存器相結(jié)合，這樣GCC和GAS在編譯和匯編時會根據(jù)后面給定的約束條件進(jìn)行恰當(dāng)?shù)奶幚?。由于樣板操作?shù)也使用‘‘ %‘‘作為前綴，因此在涉及到具體的寄存器時，寄存器名前面應(yīng)該加上兩個‘‘%‘‘，以免產(chǎn)生混淆。
緊 跟在指令部后面的是輸出部，是規(guī)定輸出變量如何與樣板操作數(shù)進(jìn)行結(jié)合的條件，每個條件稱為一個"約束"，必要時可以包含多個約束，相互之間用逗號分隔開就 可以了。每個輸出約束都以‘‘=‘‘號開始，然后緊跟一個對操作數(shù)類型進(jìn)行說明的字后，最后是如何與變量相結(jié)合的約束。凡是與輸出部中說明的操作數(shù)相結(jié)合 的寄存器或操作數(shù)本身，在執(zhí)行完嵌入的匯編代碼后均不保留執(zhí)行之前的內(nèi)容，這是GCC在調(diào)度寄存器時所使用的依據(jù)。
輸 出部后面是輸入部，輸入約束的格式和輸出約束相似，但不帶‘‘=‘‘號。如果一個輸入約束要求使用寄存器，則GCC在預(yù)處理時就會為之分配一個寄存器，并 插入必要的指令將操作數(shù)裝入該寄存器。與輸入部中說明的操作數(shù)結(jié)合的寄存器或操作數(shù)本身，在執(zhí)行完嵌入的匯編代碼后也不保留執(zhí)行之前的內(nèi)容。
有時在進(jìn)行某些操作時，除了要用到進(jìn)行數(shù)據(jù)輸入和輸出的寄存器外，還要使用多個寄存器來保存中間計(jì)算結(jié)果，這樣就難免會破壞原有寄存器的內(nèi)容。在GCC內(nèi)聯(lián)匯編格式中的最后一個部分中，可以對將產(chǎn)生副作用的寄存器進(jìn)行說明，以便GCC能夠采用相應(yīng)的措施。
下面是一個內(nèi)聯(lián)匯編的簡單例子：
例4.內(nèi)聯(lián)匯編
/* inline.c */
int main()
{
int a = 10, b = 0;
__asm__ __volatile__("movl %1, %%eax;\\n\\r"
"movl %%eax, %0;"
:"=r"(b) /* 輸出 */
:"r"(a) /* 輸入 */
:"%eax"); /* 不受影響的寄存器 */
printf("Result: %d, %d\\n", a, b);
}
上面的程序完成將變量a的值賦予變量b，有幾點(diǎn)需要說明：
變量b是輸出操作數(shù)，通過%0來引用，而變量a是輸入操作數(shù)，通過%1來引用。
輸入操作數(shù)和輸出操作數(shù)都使用r進(jìn)行約束，表示將變量a和變量b存儲在寄存器中。輸入約束和輸出約束的不同點(diǎn)在于輸出約束多一個約束修飾符‘‘=‘‘。
在內(nèi)聯(lián)匯編語句中使用寄存器eax時，寄存器名前應(yīng)該加兩個‘‘%‘‘，即%%eax。內(nèi)聯(lián)匯編中使用%0、%1等來標(biāo)識變量，任何只帶一個‘‘%‘‘的標(biāo)識符都看成是操作數(shù)，而不是寄存器。
內(nèi)聯(lián)匯編語句的最后一個部分告訴GCC它將改變寄存器eax中的值，GCC在處理時不應(yīng)使用該寄存器來存儲任何其它的值。
由于變量b被指定成輸出操作數(shù)，當(dāng)內(nèi)聯(lián)匯編語句執(zhí)行完畢后，它所保存的值將被更新。
在 內(nèi)聯(lián)匯編中用到的操作數(shù)從輸出部的第一個約束開始編號，序號從0開始，每個約束記數(shù)一次，指令部要引用這些操作數(shù)時，只需在序號前加上‘‘%‘‘作為前綴 就可以了。需要注意的是，內(nèi)聯(lián)匯編語句的指令部在引用一個操作數(shù)時總是將其作為32位的長字使用，但實(shí)際情況可能需要的是字或字節(jié)，因此應(yīng)該在約束中指明 正確的限定符：
限定符
意義
"m"、"v"、"o"
內(nèi)存單元
"r"
任何寄存器
"q"
寄存器eax、ebx、ecx、edx之一
"i"、"h"
直接操作數(shù)
"E"和"F"
浮點(diǎn)數(shù)
"g"
任意
"a"、"b"、"c"、"d"
分別表示寄存器eax、ebx、ecx和edx
"S"和"D"
寄存器esi、edi
"I"
常數(shù)（0至31）
