(Excel)常用函數(shù)公式及操作技巧之三：
時(shí)間和日期應(yīng)用
——通過知識共享樹立個(gè)人品牌。
自動顯示當(dāng)前日期公式
=YEAR(NOW()) 當(dāng)前年
=MONTH(NOW()) 當(dāng)前月
=DAY((NOW())) 當(dāng)前日
如何在單元格中自動填入當(dāng)前日期
Ctrl+;
如何判斷某日是否星期天
=WEEKDAY(A2,2)
=TEXT(A1,"aaaa")
=MOD(A1,7)<2
某個(gè)日期是星期幾
比如2007年2月9日，在一單元格內(nèi)顯示星期幾。
=TEXT(A1,"aaa") （五）
=TEXT(A1,"aaaa") （星期五）
=TEXT(A1,"ddd") （Fri）
=TEXT(A1,"dddd") （Friday）
什么函數(shù)可以顯示當(dāng)前星期
如：星期二 10:41:56
=TEXT(NOW(),"aaaa hh:mm:ss")
求本月天數(shù)
設(shè)A1為2006-8-4 求本月天數(shù)
A1=DAY(DATE(YEAR(A1),MONTH(A1)+1,0))
也有更簡便的公式：=DAY(EOMONTH(NOW(),0)) 需加載分析工具箱。
當(dāng)前月天數(shù)： =DATE(YEAR(TODAY()),MONTH(TODAY())+1,1)-DATE(YEAR(TODAY()),MONTH(TODAY()),1)
用公式算出除去當(dāng)月星期六、星期日以外的天數(shù)
=SUMPRODUCT(--(MOD(ROW(INDIRECT(DATE(YEAR(NOW()),MONTH(NOW()),1)&":"&DATE(YEAR(NOW()),MONTH(NOW())+1,0))),7)>1))
顯示昨天的日期
每天需要單元格內(nèi)顯示昨天的日期，但雙休日除外。
例如，今天是7月3號的話，就顯示7月2號，如果是7月9號，就顯示7月6號。
=IF(TEXT(TODAY(),"AAA")="一",TODAY()-3,IF(TEXT(TODAY(),"AAA")="日",TODAY()-2,TODAY()-1))
=IF(TEXT(TODAY(),"AAA")="一",TODAY()-3,TODAY()-1)
關(guān)于取日期
怎么設(shè)個(gè)公式使A1在年月日向后推5年,變成2011-7-15
=DATE(YEAR(A1)+5,MONTH(A1),DAY(A1))
=EDATE(A1,12*5)
如何對日期進(jìn)行上、中、下旬區(qū)分
=LOOKUP(DAY(A1),{0,11,21,31},{"上旬","中旬","下旬","下旬"})
如何獲取一個(gè)月的最大天數(shù)
"=DAY(DATE(2002,3,1)-1)"或"=DAY(B1-1)",B1為"2001-03-01
日期格式轉(zhuǎn)換公式
將 “01/12/2005” 轉(zhuǎn)換成“20050112”格式
＝RIGHT(A1,4)&MID(A1,4,2)&LEFT(A1,2)
＝YEAR($A2)&TEXT(MONTH($A2),"00")&TEXT(DAY($A2),"00") 該公式不用設(shè)置數(shù)據(jù)有效性,但要設(shè)置儲存格格式。
也可以用下列兩方法：
1、先轉(zhuǎn)換成文本, 然后再用字符處理函數(shù)。
2、[數(shù)據(jù)]-[分列] [日期]-[MDY]
將“2005年9月”轉(zhuǎn)換成“200509”格式
先用公式：=text(a1,"yyyymm")+0 然后將單元格格式為常規(guī)。
將“2005-8-6”格式轉(zhuǎn)換為“20050806”格式
用公式：=TEXT(A1,"YYYYMMDD")
反之，將20050806轉(zhuǎn)為日期2005-8-6格式，可用公式：
=DATE(LEFT(A1,4),MID(A1,5,2),RIGHT(A1,2))
另四種公式：
＝text(a1,"0000-00-00") 顯示：2005-08-06
＝--TEXT(A1,"#-00-00")，把單元格設(shè)置為日期格式 顯示：2005-8-6
＝TEXT(20050806,"0000-00-00")*1，單元格設(shè)置日期型 顯示：2005-8-6
＝VALUE(LEFT(A1,4)&"-"&MID(A1,5,2)&"-"&RIGHT(A1,2)) 顯示：2005-8-6
將“20060501”轉(zhuǎn)換為“2006-05-01”格式
=DATE(LEFT(A2,4),MID(A2,5,2),RIGHT(A2,2))
將“199306”轉(zhuǎn)換為“1993-6”
公式1：=LEFT(A3,4)&"-"&RIGHT(A3,2)*1
公式2：=--TEXT(A3*100+1,"#-00-00") 公式2需要設(shè)置單元格格式，自定義：e-m
公式3：=TEXT(TEXT(A3&"01","0000-00-00"),"e-m")
把198405轉(zhuǎn)換成1984.05
一、查找—1984，替換—1984.
二、如果全部是年月的話，我個(gè)人建議，
1、采取輔助＝mid(xxxxxx,1,4) & "." & right(xxxxxx,2)
2、選中這列，用數(shù)據(jù)中的分列。然后……………
三、單元格格式／數(shù)字／自定義，類型下面輸入：####"."##
將文本“2004.01.02” 轉(zhuǎn)換為日期格式：2004-1-2
=DATE(MID(A1,1,4),MID(A1,6,2),MID(A1,9,2))
將2005-8-6轉(zhuǎn)換為2005年8月6日格式
=TEXT(A1,"yyyy""年""m""月""d""日"";@")
象22怎樣轉(zhuǎn)換成22日？轉(zhuǎn)成當(dāng)年當(dāng)月的日子
公式為：=date(year(now()),month(now()),22)
將“2006年5月”轉(zhuǎn)換成“2006年05月”
公式為：=TEXT(A8,"yyyy""年""mm""月"";@")
也可以這樣處理：選中單元格，設(shè)置單元格公式－數(shù)字－自定義，將yyyy“年”m“月”改為：yyyy“年”mm“月”，即可。但這方法打印出來顯示為：2006/5/
將“1968年6月12日”轉(zhuǎn)換為“1968/6/12”格式
=YEAR(A1)&"/"&MONTH(A1)&"/"&DAY(A1) 顯示：1968/6/12
=TEXT(A1,"yyyy/mm/dd") 顯示：1968/06/12
將“1968年6月12日”轉(zhuǎn)換為“1968-6-12”格式
=YEAR(A1)&"-"&MONTH(A1)&"-"&DAY(A1) 顯示：1968-6-12
=TEXT(A1,"yyyy-mm-dd") 顯示：1968-06-12
將1993-12-28的日期格式轉(zhuǎn)換成1993年12月
=CONCATENATE(YEAR(A1),"年",MONTH(A1),"月")
=YEAR(A1)&"年"&MONTH(A1)&"月"
也可以自定義格式 [$-404]e"年"m"月"
將“1978-5-2”包含年月日的日期轉(zhuǎn)換成“197805”只有年月的格式
＝year(A1)&text(month(A1),"00")
要將“99.08.15” 格式轉(zhuǎn)換成“1999.08.15”如何做
選中列，數(shù)據(jù)菜單中選分列，分列過程中“格式”選“日期YMD”，結(jié)束。
要保持2005/8/6格式
當(dāng)輸入2005/8/6后系統(tǒng)自動變成2005-8-6，要保持2005/8/6格式，可以使用強(qiáng)制文本（前面加'號）或使用公式=TEXT(A1,"YYYY/MM/DD")。也可以用另一種公式：=IF(ISERROR(TEXT(A1,"yyyy/mm/dd")),TEXT(A1,"0000!/00!/00"),TEXT(A1,"yyyy/mm/dd"))
將“二○○三年十二月二十五日”轉(zhuǎn)為“2003-12-25”格式，
1、可以用數(shù)組公式將中文日期轉(zhuǎn)化為日期系列數(shù)｛=14610+MATCH(SUBSTITUTE(A3,"元","一"),TEXT(ROW($14611:$55153),"[DBNum1]yyyy年m月d日"),0)｝
該公式速度較慢。
2、改進(jìn)后的公式，速度要快的多：
｛=DATE(1899+MATCH(LEFT(A7,4),TEXT(ROW($1900:$2100),"[DBNum1]0000"),0),MONTH(MATCH(SUBSTITUTE(MID(A7,6,7),"元","一"),TEXT(ROW($1:$366),"[DBNum1]m月d日"),0)),DAY(MATCH(SUBSTITUTE(MID(A7,6,7),"元","一"),TEXT(ROW($1:$366),"[DBNum1]m月d日"),0)))｝
要設(shè)置為1900年的日期格式。
日期格式轉(zhuǎn)換
如A列是月份數(shù)為8，B列是日期數(shù)為18，如何在C列顯示“8月18日”
=A1&"月"&B1&"日"
反之，要將C列的“8月18日” 直接分別到D、E列，顯示月份和日期，
月數(shù)份=LEFT(C5,FIND("月",C5)-1)
日期數(shù)=MID(C5,FIND("月",C5)+1,FIND("日",C5)-FIND("月",C5)-1)
也可分別用公式：
=month(--c5)
=day(--c5)
日期格式轉(zhuǎn)換問題
輸入的日期是:04-07-26. 與另一格的"001"合并,合并出來是:040726001.
=TEXT(A1,"YYMMDD")&"001"
要想自動取得“編制日期：XXXX年X月X日”
可在該單元格輸入 ="編制日期："&TEXT(TODAY(),"yyyy年m月d日")
