『樓 主』: 非常好的for教程，看完這個保你會用for
批處理for命令詳解
FOR這條命令基本上都被用來處理文本,但還有其他一些好用的功能!
看看他的基本格式(這里我引用的是批處理中的格式,直接在命令行只需要一個%號)
FOR 參數(shù) %%變量名 IN (相關文件或命令) DO 執(zhí)行的命令
參數(shù):FOR有4個參數(shù) /d /l /r /f 他們的作用我在下面用例子解釋
%%變量名 :這個變量名可以是小寫a-z或者大寫A-Z,他們區(qū)分大小寫,FOR會把每個讀取到的值給他;
IN:命令的格式,照寫就是了;
(相關文件或命令) :FOR要把什么東西讀取然后賦值給變量,看下面的例子
do:命令的格式,照寫就是了!
執(zhí)行的命令:對每個變量的值要執(zhí)行什么操作就寫在這.
可以在CMD輸入for /?看系統(tǒng)提供的幫助!對照一下
FOR %%variable IN (set) DO command [command-parameters]
%%variable 指定一個單一字母可替換的參數(shù)。
(set) 指定一個或一組文件?？梢允褂猛ㄅ浞?。
command 指定對每個文件執(zhí)行的命令。
command-parameters
為特定命令指定參數(shù)或命令行開關。
現(xiàn)在開始講每個參數(shù)的意思
/d
僅為目錄
如果 Set (也就是我上面寫的 "相關文件或命令") 包含通配符（* 和 ?），將對與 Set 相匹配的每個目
錄（而不是指定目錄中的文件組）執(zhí)行指定的 Command。
系統(tǒng)幫助的格式:FOR /D %%variable IN (set) DO command
他主要用于目錄搜索,不會搜索文件,看這樣的例子
@echo off
for /d %%i in (*) do @echo %%i
pause
把他保存放在C盤根目錄執(zhí)行,就會把C盤目錄下的全部目錄名字打印出來,而文件名字一個也不顯示!
再來一個,比如我們要把當前路徑下文件夾的名字只有1-3個字母的打出來
@echo off
for /d %%i in (???) do @echo %%i
pause
這樣的話如果你當前目錄下有目錄名字只有1-3個字母的,就會顯示出來,沒有就不顯示了
思考題目:
@echo off
for /d %%i in (window?) do @echo %%i
pause
保存到C盤下執(zhí)行,會顯示什么呢?自己看吧!
/D參數(shù)只能顯示當前目錄下的目錄名字,這個大家要注意!
/R
遞歸
進入根目錄樹 [Drive:]Path，在樹的每個目錄中執(zhí)行 for 語句。如果在 /R 后沒有指定目錄，則認為是
當前目錄。如果 Set 只是一個句點 (.)，則只枚舉目錄樹。
系統(tǒng)幫助的格式:FOR /R [[drive:]path] %%variable IN (set) DO command
上面我們知道,/D只能顯示當前路徑下的目錄名字,那么現(xiàn)在這個/R也是和目錄有關,他能干嘛呢?放心他比
/D強大多了!
他可以把當前或者你指定路徑下的文件名字全部讀取,注意是文件名字,有什么用看例子!
@echo off
for /r c:\ %%i in (*.exe) do @echo %%i
pause
咋們把這個BAT保存到D盤隨便哪里然后執(zhí)行,我會就會看到,他把C盤根目錄,和每個目錄的子目錄下面全部
的EXE文件都列出來了,這里的c:\就是目錄了。
再來一個
@echo off
for /r %%i in (*.exe) do @echo %%i
pause
參數(shù)不一樣了，這個命令前面沒加那個C:\也就是搜索路徑,這樣他就會以當前目錄為搜索路徑,比如你這
個BAT你把他放在d:\test目錄下執(zhí)行,那么他就會把D:\test目錄和他下面的子目錄的全部EXE文件列出
來!!!
/L
迭代數(shù)值范圍
使用迭代變量設置起始值 (Start#)，然后逐步執(zhí)行一組范圍的值，直到該值超過所設置的終止值 (End#)
。/L 將通過對 Start# 與 End# 進行比較來執(zhí)行迭代變量。如果 Start# 小于 End#，就會執(zhí)行該命令。
如果迭代變量超過 End#，則命令解釋程序退出此循環(huán)。還可以使用負的 Step# 以遞減數(shù)值的方式逐步執(zhí)
行此范圍內(nèi)的值。例如，(1,1,5) 生成序列 1 2 3 4 5，而 (5,-1,1) 則生成序列 (5 4 3 2 1)。語法是：
系統(tǒng)幫助的格式:for /L %% Variable in (Start#,Step#,End#) do Command
例如：
@echo off
for /l %%i in (1,1,5) do @echo %%i
pause
保存執(zhí)行看效果,他會打印從1 2 3 4 5 這樣5個數(shù)字
(1,1,5)這個參數(shù)也就是表示從1開始每次加1直到5終止!
再看這個例子
@echo off
for /l %%i in (1,1,5) do start cmd
pause
執(zhí)行后是不是嚇了一跳,怎么多了5個CMD窗口,呵呵!如果把那個 (1,1,5)改成 (1,1,65535)會有什么結(jié)果,
我先告訴大家,會打開65535個CMD窗口....這么多你不死機算你強!
當然我們也可以把那個start cmd改成md %%i 這樣就會建立指定個目錄了!!!名字為1-65535
看完這個被我賦予破壞性質(zhì)的參數(shù)后,我們來看最后一個參數(shù)
/f
含有/F的for詳細說明
含有/F的for有很大的用處，在批處理中使用的最多，用法如下：
格式：
FOR /F ["options"] %%i IN (file) DO command
FOR /F ["options"] %%i IN ("string") DO command
FOR /F ["options"] %%i IN ('command') DO command
這個可能是最常用的，也是最強的命令，主要用來處理文件和一些命令的輸出結(jié)果。
file代表一個或多個文件
string 代表字符串
command代表命令
["options"] 可選
對于FOR /F %%i IN (file) DO command
file為文件名，按照官方的說法是，for會依次將file中的文件打開，并且在進行到下一個文件之前將每個文件讀取到內(nèi)存，按照每一行分成一個一個的元素，忽略空白的行，看個例子。
假如文件a.txt中有如下內(nèi)容：
第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列
你想顯示a.txt中的內(nèi)容，會用什么命令呢？當然是type，type a.txt
for也可以完成同樣的命令：
for /f %%i in (a.txt) do echo %%i
還是先從括號執(zhí)行，因為含有參數(shù)/f,所以for會先打開a.txt，然后讀出a.txt里面的所有內(nèi)容，把它作為一個集合，并且以每一行作為一個元素，所以會產(chǎn)生這樣的集合，
{“第1行第1列 第1行第2列 第1行第3列”， //第一個元素
“第2行第1列 第2行第2列 第2行第3列”， //第二個元素
“第3行第1列 第3行第2列 第3行第3列”} //第三個元素
集合中只有3個元素，同樣用%%i依次代替每個元素，然后執(zhí)行do后面的命令。
具體過程：
用%%i代替“第1行第1列 第1行第2列 第1行第3列”，執(zhí)行do后面的echo %%i，顯示“第1行第1列 第1行第2列 第1行第3列”，
用%%i代替“第2行第1列 第2行第2列 第2行第3列”，執(zhí)行echo %%i，顯示“第2行第1列 第2行第2列 第2行第3列”，
依次，直到每個元素都代替完為止。
為了加強理解/f的作用，請執(zhí)行一下兩個命令，對比即可明白：
for /f %%i in (a.txt) do echo %%i //這個會顯示a.txt里面的內(nèi)容，因為/f的作用，會讀出a.txt中
的內(nèi)容。
for %%i in (a.txt) do echo %%i //而這個只會顯示a.txt這個名字，并不會讀取其中的內(nèi)容。
通過上面的學習，我們發(fā)現(xiàn)for /f會默認以每一行來作為一個元素，但是如果我們還想把每一行再分解更小的內(nèi)容，該怎么辦呢？不用擔心，for命令還為我們提供了更詳細的參數(shù)，使我們將每一行分為更小的元素成為可能。
它們就是：delims和tokens
delims 用來告訴for每一行應該拿什么作為分隔符，默認的分隔符是空格和tab鍵
比如，還是上面的文件，我們執(zhí)行下面的命令：
for /f "delims= " %%i in (a.txt) do echo %%i
顯示的結(jié)果是：
第1行第1列
第2行第1列
第3行第1列
為什么是這樣的呢。因為這里有了delims這個參數(shù)，=后面有一個空格，意思是再將每個元素以空格分割，默認是只取分割之后的第一個元素。
執(zhí)行過程是：
將第一個元素“第1行第1列 第1行第2列 第1行第3列”分成三個元素：“第1行第1列” “第1行第2列” “第1行第3列”，它默認只取第一個，即“第1行第1列”，然后執(zhí)行do后面的命令，依次類推。
但是這樣還是有局限的，如果我們想要每一行的第二列元素，那又如何呢？
這時候，tokens跳出來說，我能做到。
它的作用就是當你通過delims將每一行分為更小的元素時，由它來控制要取哪一個或哪幾個。
還是上面的例子，執(zhí)行如下命令：
for /f "tokens=2 delims= " %%i in (a.txt) do echo %%i
執(zhí)行結(jié)果：
第1行第2列
第2行第2列
第3行第2列
如果要顯示第三列，那就換成tokens=3。
同時tokens支持通配符*，以及限定范圍。
如果要顯示第二列和第三列，則換成tokens=2,3或tokens=2-3,如果還有更多的則為：tokens=2-10之類的。
此時的命令為：
for /f "tokens=2,3 delims= " %%i in (a.txt) do echo %%i %%j
怎么多出一個%%j？
這是因為你的tokens后面要取每一行的兩列，用%%i來替換第二列，用%%j來替換第三列。
并且必須是按照英文字母順序排列的，%%j不能換成%%k，因為i后面是j
執(zhí)行結(jié)果為：
第1行第2列 第1行第3列
第2行第2列 第2行第3列
第3行第2列 第3行第3列
對以通配符*，就是把這一行全部或者這一行的剩余部分當作一個元素了。
比如：
for /f "tokens=* delims= " %%i in (a.txt) do echo %%i
執(zhí)行結(jié)果為：
第1行第1列 第1行第2列 第1行第3列
第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列
其實就跟for /f %%i in (a.txt) do echo %%i的執(zhí)行結(jié)果是一樣的。
再如：
for /f "tokens=2,* delims= " %%i in (a.txt) do echo %%i %%j
執(zhí)行結(jié)果為：
第1行第2列 第1行第3列
第2行第2列 第2行第3列
第3行第2列 第3行第3列
用%%i代替第二列，用%%j代替剩余的所有
最后還有skip和eol，這倆個簡單，skip就是要忽略文件的前多少行，而eol用來指定當一行以什么符號開始時，就忽略它。
比如：
for /f "skip=2 tokens=*" %%i in (a.txt) do echo %%i
結(jié)果為:
第3行第1列 第3行第2列 第3行第3列
用skip來告訴for跳過前兩行。
如果不加tokens=*的話，執(zhí)行結(jié)果為：
第3行第1列
不知道怎么回事。
再如，當a.txt內(nèi)容變成：
.第1行第1列 第1行第2列 第1行第3列
.第2行第1列 第2行第2列 第2行第3列
第3行第1列 第3行第2列 第3行第3列
執(zhí)行for /f "eol=. tokens=*" %%i in (a.txt) do echo %%i結(jié)果是：
第3行第1列 第3行第2列 第3行第3列
用eol來告訴for忽略以“.”開頭的行。
同樣也必須加tokens=*，否則只會顯示“第3行第1列
最強之dos命令 – for (是新手學習FOR語句的好資料)
這篇文章是網(wǎng)上找的，很多初學DOS的朋友對FOR語句掌握的好不是太過熟悉，希望這邊文章能夠給你開闊思路幫助你把FOR語句學好，主要的參數(shù)介紹和實例講的都很清楚，也希望對DOS越來越感興趣－－－＞發(fā)揮你的想像力吧
正文開始
以前常覺得DOS的命令行功能太弱，無法象UNIX一樣可以用命令行完成非常復雜的操作。實際上，當MS從WIN2K開始將命令行增強后，已經(jīng)借鑒了相當多UNIX的優(yōu)點，雖然還無法做到象UNIX那么靈活，但已可完成絕大多數(shù)的任務，比如用&&和 連接兩個（或更多）命令，由前一個的返回值來決定下一個是否執(zhí)行，等等。而在這些增強中，最明顯的，就是FOR命令。
舉個例子，用適當?shù)膮?shù)，可用FOR命令將 date /t 的輸出 從 "Sat 07/13/2002" 變成你想要的格式，比如， "2002-07-13"：
c:\>for /f "tokens=2,3,4 delims=/ " %a in ('date /t') do @echo %c-%a-%b
2002-07-13
該例將在（3）中詳細說明。
0. 基本應用
簡單說，F(xiàn)OR是個循環(huán)，可以用你指定的循環(huán)范圍生成一系列命令。最簡單的例子，就是人工指定循環(huán)范圍，然后對每個值執(zhí)行指定的命令。例如，想快速報告每個硬盤分區(qū)的剩余空間：
for %a in (c: d: e: f do @dir %a\ find "bytes free"
將輸出：
8 Dir(s) 1,361,334,272 bytes free
15 Dir(s) 8,505,581,568 bytes free
12 Dir(s) 12,975,149,056 bytes free
7 Dir(s) 11,658,854,400 bytes free
用它可以使一些不支持通配符的命令對一系列文件進行操作。在WIN9X中，TYPE命令（顯示文件內(nèi)容）是不支持*.txt這種格式的（WIN2K開始TYPE已支持通配）。遇到類似情況就可以用FOR：
for %a in (*.txt) do type %a
這些還不是FOR最強大的功能。我認為它最強大的功能，表現(xiàn)在以下這些高級應用：
1. 可以用 /r 參數(shù)遍歷整個目錄樹
2. 可以用 /f 參數(shù)將文本文件內(nèi)容作為循環(huán)范圍
3. 可以用 /f 參數(shù)將某一命令執(zhí)行結(jié)果作為循環(huán)范圍
4. 可以用 %~ 操作符將文件名分離成文件名、擴展名、盤符等獨立部分
現(xiàn)分別舉例說明如下：
1. 用 /r 遍歷目錄樹
當用 *.* 或 *.txt 等文件名通配符作為 for /r 的循環(huán)范圍時，可以對當前目錄下所有文件（包括子目錄里面的文件）進行操作。舉個例子，你想在當前目錄的所有txt文件（包括子目錄）內(nèi)容中查找"bluebear"字樣，但由于find本身不能遍歷子目錄，所以我們用for:
for /r . %a in (*.txt) do @find "bluebear" %a
find 前面的 @ 只是讓輸出結(jié)果不包括 find 命令本身。這是DOS很早就有的功能。和FOR無關。
當用 . 作為循環(huán)范圍時，for 只將子目錄的結(jié)構(gòu)（目錄名）作為循環(huán)范圍，而不包括里面的文件。有點象 TREE 命令，不過側(cè)重點不同。TREE 的重點是用很漂亮易讀的格式輸出，而FOR的輸出適合一些自動任務，例如，我們都知道用CVS管理的項目中，每個子目錄下都會有一個CVS目錄，有時在軟件發(fā)行時我們想把這些CVS目錄全部去掉：
for /r . %a in (.) do @if exist %a\CVS rd /s /q %a\CVS
先用 if exist 判斷一下，是因為 for 只是機械的對每個目錄進行列舉，如果有些目錄下面沒有CVS也會被執(zhí)行到。用 if exist 判斷一下比較安全。
這種刪除命令威力太大，請小心使用。最好是在真正執(zhí)行以上的刪除命令前，將 rd /s /q 換成 @echo 先列出要刪出的目錄，確認無誤后再換回rd /s /q：
for /r . %a in (.) do @if exist %a\CVS @echo %a\CVS
可能目錄中會多出一層 "."，比如 c:\proj\release\.\CVS ，但不會影響命令的執(zhí)行效果。
2. 將某一文件內(nèi)容或命令執(zhí)行結(jié)果作為循環(huán)范圍：
假如你有一個文件 todel.txt，里面是所有要刪除的文件列表，現(xiàn)在你想將里面列出的每個文件都刪掉。假設這個文件是每個文件名占一行，象這樣：
c:\temp\a1.txt
c:\temp\a2.txt
c:\temp\subdir\b3.txt
c:\temp\subdir\b4.txt
那么可以用FOR來完成：
for /f %a in (todel.txt) do del %a
這個命令還可以更強大。比如你的 todel.txt 并不是象上面例子那么干凈，而是由DIR直接生成，有一些沒用的信息，比如這樣：
Volume in drive D is DATA
Volume Serial Number is C47C-9908
Directory of D:\tmp
09/26/2001 12:50 PM 18,426 alg0925.txt
12/02/2001 04:29 AM 795 bsample.txt
04/11/2002 04:18 AM 2,043 invitation.txt
4 File(s) 25,651 bytes
0 Dir(s) 4,060,700,672 bytes free
for 仍然可以解出其中的文件名并進行操作：
for /f "skip=5 tokens=5" %a in (todel.txt) do @if exist %a DEL %a
當然，上面這個命令是在進行刪除，如果你只是想看看哪些文件將被操作，把DEL換成echo:
for /f "skip=5 tokens=5" %a in (todel.txt) do @if exist %a echo %a
你將看到：
alg0925.txt
bsample.txt
invitation.txt
skip=5表示跳過前5行（就是DIR輸出的頭部信息），tokens=5表示將每行的第5列作為循環(huán)值放入%a，正好是文件名。在這里我加了一個文件存在判斷，是因為最后一行的"free"剛好也是第5列，目前還想不出好的辦法來濾掉最后兩行，所以檢查一下可保萬無一失。
3. 可以用 /f 參數(shù)將某一命令執(zhí)行結(jié)果作為循環(huán)范圍
非常有用的功能。比如，我們想知道目前的環(huán)境變量有哪些名字（我們只要名字，不要值）?？墒荢ET命令的輸出是“名字=值”的格式，現(xiàn)在可以用FOR來只取得名字部分：
FOR /F "delims==" %i IN ('set') DO @echo %i
將看到：
ALLUSERSPROFILE
APPDATA
CLASSPATH
CommonProgramFiles
COMPUTERNAME
ComSpec
dircmd
HOMEDRIVE
......
這里是將set命令執(zhí)行的結(jié)果拿來作為循環(huán)范圍。delims==表示用=作為分隔符，由于FOR /F默認是用每行第一個TOKEN，所以可以分離出變量名。如果是想僅列出值：
FOR /F "delims== tokens=2" %i IN ('set') DO @echo %i
tokens=2和前例相同，表示將第二列（由=作為分隔符）作為循環(huán)值。
再來個更有用的例子：
我們知道 date /t （/t表示不要詢問用戶輸入）的輸出是象這樣的：
Sat 07/13/2002
現(xiàn)在我想分離出日期部分，也就是13：
for /f "tokens=3 delims=/ " %a in ('date /t') do @echo %a
實際上把 tokens后面換成1,2,3或4，你將分別得到Sat, 07, 13和2002。注意delims=/后面還有個空格，表示/和空格都是分隔符。由于這個空格delims必須是/f選項的最后一項。
再靈活一點，象本文開頭提到的，將日期用2002-07-13的格式輸出：
for /f "tokens=2,3,4 delims=/ " %a in ('date /t') do @echo %c-%a-%b
當tokens后跟多個值時，將分別映射到%a, %b, %c等。實際上跟你指定的變量有關，如果你指定的是 %i, 它們就會用%i, %j, %k等。
靈活應用這一點，幾乎沒有做不了的事。
4. 可以用 %~ 操作符將文件名分離成文件名、擴展名、盤符等獨立部分
這個比較簡單，就是說將循環(huán)變量的值自動分離成只要文件名，只要擴展名，或只要盤符等等。
例：要將 c:\mp3下所有mp3的歌名列出，如果用一般的 dir /b/s 或 for /r ，將會是這樣：
g:\mp3\Archived\05-18-01-A\游鴻明-下沙\游鴻明-01 下沙.mp3
g:\mp3\Archived\05-18-01-A\游鴻明-下沙\游鴻明-02 21個人.mp3
......
g:\mp3\Archived\05-18-01-A\王菲-寓言\王菲-阿修羅.mp3
g:\mp3\Archived\05-18-01-A\王菲-寓言\王菲-彼岸花.mp3
g:\mp3\Archived\05-18-01-A\王菲-寓言\王菲-不愛我的我不愛.mp3
......
如果我只要歌名（不要路徑和".mp3"）：
游鴻明-01 下沙
游鴻明-02 21個人
......
王菲-阿修羅
王菲-彼岸花
王菲-不愛我的我不愛
......
那么可以用FOR命令：
for /r g:\mp3 %a in (*.mp3) do @echo %~na
凡是 %~ 開頭的操作符，都是文件名的分離操作。具體請看 for /? 幫助。
本文舉的例子有些可能沒有實際用處，或可用其它辦法完成。僅用于體現(xiàn)FOR可以不借助其它工具，僅用DOS命令組合，就可完成相當靈活的任務
