多線程編程(1) - 先入門再說。
多線程應該是編程工作者的基礎(chǔ)技能, 但這個基礎(chǔ)對我來講的確有點難(起碼昨天以前是這樣).
開始本應該是一篇洋洋灑灑的文字, 不過我還是提倡先做起來, 在嘗試中去理解.
先試試這個:
procedure TForm1.Button1Click(Sender: TObject);
var
i: Integer;
begin
for i := 0 to 500000 do
begin
Canvas.TextOut(10, 10, IntToStr(i));
end;
end;
上面程序運行時, 我們的窗體基本是 "死" 的, 可以在你在程序運行期間拖動窗體試試...
Delphi 為我們提供了一個簡單的辦法(Application.ProcessMessages)來解決這個問題:
procedure TForm1.Button1Click(Sender: TObject);
var
i: Integer;
begin
for i := 0 to 500000 do
begin
Canvas.TextOut(10, 10, IntToStr(i));
Application.ProcessMessages;
end;
end;
這個 Application.ProcessMessages; 一般用在比較費時的循環(huán)中, 它會檢查并先處理消息隊列中的其他消息.
但這算不上多線程, 譬如: 運行中你拖動窗體, 循環(huán)會暫停下來...
在使用多線程以前, 讓我們先簡單修改一下程序:
function MyFun: Integer;
var
i: Integer;
begin
for i := 0 to 500000 do
begin
Form1.Canvas.Lock;
Form1.Canvas.TextOut(10, 10, IntToStr(i));
Form1.Canvas.Unlock;
end;
Result := 0;
end;
procedure TForm1.Button1Click(Sender: TObject);
begin
MyFun;
end;
細數(shù)上面程序的變化:
1、首先這還不是多線程的, 也會讓窗體假 "死" 一會;
2、把執(zhí)行代碼寫在了一個函數(shù)里, 但這個函數(shù)不屬于 TForm1 的方法, 所以使用 Canvas 是必須冠以名稱(Form1);
3、既然是個函數(shù), (不管是否必要)都應該有返回值;
4、使用了 500001 次 Lock 和 Unlock.
Canvas.Lock 好比在說: Canvas(繪圖表面)正忙著呢, 其他想用 Canvas 的等會;
Canvas.Unlock : 用完了, 解鎖!
在 Canvas 中使用 Lock 和 Unlock 是個好習慣, 在不使用多線程的情況下這無所謂, 但保不準哪天程序會擴展為多線程的; 我們現(xiàn)在學習多線程, 當然應該用.
在 Delphi 中使用多線程有兩種方法: 調(diào)用 API、使用 TThread 類; 使用 API 的代碼更簡單.
function MyFun(p: Pointer): Integer; stdcall;
var
i: Integer;
begin
for i := 0 to 500000 do
begin
Form1.Canvas.Lock;
Form1.Canvas.TextOut(10, 10, IntToStr(i));
Form1.Canvas.Unlock;
end;
Result := 0;
end;
procedure TForm1.Button1Click(Sender: TObject);
var
ID: THandle;
begin
CreateThread(nil, 0, @MyFun, nil, 0, ID);
end;
代碼分析:
CreateThread 一個線程后, 算上原來的主線程, 這樣程序就有兩個線程、是標準的多線程了;
CreateThread 第三個參數(shù)是函數(shù)指針, 新線程建立后將立即執(zhí)行該函數(shù), 函數(shù)執(zhí)行完畢, 系統(tǒng)將銷毀此線程從而結(jié)束多線程的故事.
CreateThread 要使用的函數(shù)是系統(tǒng)級別的, 不能是某個類(譬如: TForm1)的方法, 并且有嚴格的格式(參數(shù)、返回值)要求, 不管你暫時是不是需要都必須按格式來;
因為是系統(tǒng)級調(diào)用, 還要綴上 stdcall, stdcall 是協(xié)調(diào)參數(shù)順序的, 雖然這里只有一個參數(shù)沒有順序可言, 但這是使用系統(tǒng)函數(shù)的慣例.
CreateThread 還需要一個 var 參數(shù)來接受新建線程的 ID, 盡管暫時沒用, 但這也是格式; 其他參數(shù)以后再說吧.
這樣一個最簡單的多線程程序就出來了, 咱們再用 TThread 類實現(xiàn)一次
type
TMyThread = class(TThread)
protected
procedure Execute; override;
end;
procedure TMyThread.Execute;
var
i: Integer;
begin
FreeOnTerminate := True; {這可以讓線程執(zhí)行完畢后隨即釋放}
for i := 0 to 500000 do
begin
Form1.Canvas.Lock;
Form1.Canvas.TextOut(10, 10, IntToStr(i));
Form1.Canvas.Unlock;
end;
end;
procedure TForm1.Button1Click(Sender: TObject);
begin
TMyThread.Create(False);
end;
TThread 類有一個抽象方法(Execute), 因而是個抽象類, 抽象類只能繼承使用, 上面是繼承為 TMyThread.
繼承 TThread 主要就是實現(xiàn)抽象方法 Execute(把我們的代碼寫在里面), 等我們的 TMyThread 實例化后, 首先就會執(zhí)行 Execute 方法中的代碼.
按常規(guī)我們一般這樣去實例化:
procedure TForm1.Button1Click(Sender: TObject);
var
MyThread: TMyThread;
begin
MyThread := TMyThread.Create(False);
end;
因為 MyThread 變量在這里毫無用處(并且編譯器還有提示), 所以不如直接寫做 TMyThread.Create(False);
我們還可以輕松解決一個問題, 如果: TMyThread.Create(True) ?
procedure TForm1.Button1Click(Sender: TObject);
var
MyThread: TMyThread;
begin
MyThread := TMyThread.Create(True);
MyThread.Resume;
end;
//可簡化為:
procedure TForm1.Button1Click(Sender: TObject);
begin
with TMyThread.Create(True) do Resume;
end;
使用 TThread 類時, Delphi 有提供的模板, 但用 IDE 寫代碼很方便, 我重寫一遍錄下來給大家看:
多線程編程(1) - 先入門再說
期間使用了 Ctrl+J、Shift+Ctrl+C、Ctrl+Alt+P 等快捷鍵.
重要的修正與補充: 在 TThread 類的例子中, 應該有這句: FreeOnTerminate := True; (原來漏掉, 代碼中已加上; 但動畫加不上了).
先說它什么意思:
類 Create 了就要 Free;
但 TThread(的子類) 有特殊性, 很多時候我們不能確定新建的線程什么時候執(zhí)行完(也就是什么時候該釋放);
如果線程執(zhí)行完畢自己知道釋放就好了, 所以 TThread 給了一個布爾屬性 FreeOnTerminate, 如果為 True, 線程執(zhí)行完畢后就會自釋放.
我怎么會忽略了這么重要的問題呢? 原因有二:
1、我一直在追求最精煉的代碼;
2、我手頭上不只一本書上介紹說: FreeOnTerminate 的默認值是 True(錯誤!), 經(jīng)落實, 應該是 False, 起碼在 Delphi 2007 和 2009 中是這樣; 或許以前的某個版本和現(xiàn)在不一樣
多線程編程(2) - 從 CreateThread 說起。
function CreateThread(
lpThreadAttributes: Pointer; {安全設(shè)置}
dwStackSize: DWORD; {堆棧大小}
lpStartAddress: TFNThreadStartRoutine; {入口函數(shù)}
lpParameter: Pointer; {函數(shù)參數(shù)}
dwCreationFlags: DWORD; {啟動選項}
var lpThreadId: DWORD {輸出線程 ID }
): THandle; stdcall; {返回線程句柄}
在 Windows 上建立一個線程, 離不開 CreateThread 函數(shù);
TThread.Create 就是先調(diào)用了 BeginThread (Delphi 自定義的), BeginThread 又調(diào)用的 CreateThread.
既然有建立, 就該有釋放, CreateThread 對應的釋放函數(shù)是: ExitThread, 譬如下面代碼:
procedure TForm1.Button1Click(Sender: TObject);
begin
ExitThread(0); {此句即可退出當前程序, 但不建議這樣使用}
end;
代碼注釋:
當前程序是一個進程, 進程只是一個工作環(huán)境, 線程是工作者;
每個進程都會有一個啟動線程(或叫主線程), 也就是說: 我們之前大量的編碼都是寫給這個主線程的;
上面的 ExitThread(0); 就是退出這個主線程;
系統(tǒng)不允許一個沒有線程的進程存在, 所以程序就退出了.
另外: ExitThread 函數(shù)的參數(shù)是一個退出碼, 這個退出碼是給之后的其他函數(shù)用的, 這里隨便給個無符號整數(shù)即可.
或許你會說: 這個 ExitThread 挺好用的; 其實不管是用 API 還是用 TThread 類寫多線程, 我們很少用到它; 因為:
1、假如直接使用 API 的 CreateThread, 它執(zhí)行完入口函數(shù)后會自動退出, 無需 ExitThread;
2、用 TThread 類建立的線程又絕不能使用 ExitThread 退出; 因為使用 TThread 建立線程時會同時分配更多資源(譬如你自定義的成員、還有它的祖先類(TObject)分配的資源等等), 如果用 ExitThread 給草草退出了, 這些資源將得不到釋放而導致內(nèi)存泄露. 盡管 Delphi 提供了 EndThread(其內(nèi)部調(diào)用 ExitThread), 這也不需要我們手動操作(假如非要手動操作也是件很麻煩的事情, 因為很多時候你不知道線程是什么時候執(zhí)行完畢的).
除了 CreateThread, 還有一個 CreateRemoteThread, 可在其他進程中建立線程, 這不應該是現(xiàn)在學習的重點;
現(xiàn)在先集中精力把 CreateThread 的參數(shù)搞徹底.
倒著來吧, 先談談 CreateThread 將要返回的 "線程句柄".
"句柄" 類似指針, 但通過指針可讀寫對象, 通過句柄只是使用對象;
有句柄的對象一般都是系統(tǒng)級別的對象(或叫內(nèi)核對象); 之所以給我們的是句柄而不是指針, 目的只有一個: "安全";
貌似通過句柄能做很多事情, 但一般把句柄提交到某個函數(shù)(一般是系統(tǒng)函數(shù))后, 我們也就到此為止很難了解更多了; 事實上是系統(tǒng)并不相信我們.
不管是指針還是句柄, 都不過是內(nèi)存中的一小塊數(shù)據(jù)(一般用結(jié)構(gòu)描述), 微軟并沒有公開句柄的結(jié)構(gòu)細節(jié), 猜一下它應該包括: 真實的指針地址、訪問權(quán)限設(shè)置、引用計數(shù)等等.
既然 CreateThread 可以返回一個句柄, 說明線程屬于 "內(nèi)核對象".
實際上不管線程屬于哪個進程, 它們在系統(tǒng)的懷抱中是平等的; 在優(yōu)先級(后面詳談)相同的情況下, 系統(tǒng)會在相同的時間間隔內(nèi)來運行一下每個線程, 不過這個間隔很小很小, 以至于讓我們誤以為程序是在不間斷地運行.
這時你應該有一個疑問: 系統(tǒng)在去執(zhí)行其他線程的時候, 是怎么記住前一個線程的數(shù)據(jù)狀態(tài)的?
有這樣一個結(jié)構(gòu) TContext, 它基本上是一個 CPU 寄存器的**, 線程是數(shù)據(jù)就是通過這個結(jié)構(gòu)切換的, 我們也可以通過 GetThreadContext 函數(shù)讀取寄存器看看.
附上這個結(jié)構(gòu) TContext(或叫: CONTEXT、_CONTEXT) 的定義
