国产一级a片免费看高清,亚洲熟女中文字幕在线视频,黄三级高清在线播放,免费黄色视频在线看

多線程編程(10) - 多線程同步之 Mutex (互斥對(duì)象)

原理分析:
　　互斥對(duì)象是系統(tǒng)內(nèi)核對(duì)象, 各線程都可以擁有它, 誰(shuí)擁有誰(shuí)就能執(zhí)行;
　　執(zhí)行完畢, 用 ReleaseMutex 函數(shù)釋放擁有權(quán), 以讓其他等待的線程使用.
　　其他線程可用 WaitForSingleObject 函數(shù)排隊(duì)等候(等候也可以理解為排隊(duì)申請(qǐng)).
　　使用過(guò)程:
var hMutex: THandle; {應(yīng)該先聲明一個(gè)全局的互斥句柄}
CreateMutex　　　　　{建立一個(gè)互斥對(duì)象}
WaitForSingleObject　{用等待函數(shù)排隊(duì)等候}
ReleaseMutex　　　　 {釋放擁有權(quán)}
CloseHandle　　　　　{最后釋放互斥對(duì)象}
　　ReleaseMutex、CloseHandle 的參數(shù)都是 CreateMutex 返回的句柄, 關(guān)鍵是 CreateMutex 函數(shù):
function CreateMutex(
　lpMutexAttributes: PSecurityAttributes;
　bInitialOwner: BOOL; {是否讓創(chuàng)建者(此例中是主線程)擁有該互斥對(duì)象}
　lpName: PWideChar　　{可以給此互斥對(duì)象取個(gè)名字, 如果不要名字可賦值為 nil}
): THandle;
{
1、第一個(gè)參數(shù)前面說(shuō)過(guò).
2、第二個(gè)參數(shù)在這里一定要是 False, 如果讓主線程擁有互斥, 從理論上講, 得等程序退出后其他線程才有機(jī)會(huì);
　 取值 False 時(shí), 第一個(gè)執(zhí)行的線程將會(huì)最先擁有互斥對(duì)象, 一旦擁有其他線程就得先等等.
3、第三個(gè)參數(shù), 如果給個(gè)名字, 函數(shù)將從系統(tǒng)中尋找是否有重名的互斥對(duì)象, 如果有則返回同名對(duì)象的存在的句柄;
　 如果賦值為 nil 將直接創(chuàng)建一個(gè)新的互斥對(duì)象; 下個(gè)例子將會(huì)有名字. }
　　本例效果圖:

代碼文件:unit Unit1;
interface
uses
　Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
　Dialogs, StdCtrls;
type
　TForm1 = class(TForm)
　　Button1: TButton;
　　procedure Button1Click(Sender: TObject);
　　procedure FormCreate(Sender: TObject);
　　procedure FormDestroy(Sender: TObject);
　end;
var
　Form1: TForm1;
implementation
{$R *.dfm}
var
　f: Integer;　　　{用這個(gè)變量協(xié)調(diào)一下各線程輸出的位置}
　hMutex: THandle; {互斥對(duì)象的句柄}
function MyThreadFun(p: Pointer): DWORD; stdcall;
var
　i,y: Integer;
begin
　Inc(f);
　y := 20 * f;
　for i := 0 to 50000 do
　begin
　　if WaitForSingleObject(hMutex, INFINITE) = WAIT_OBJECT_0 then
　　begin
　　　Form1.Canvas.Lock;
　　　Form1.Canvas.TextOut(20, y, IntToStr(i));
　　　Form1.Canvas.Unlock;
　　　Sleep(0); {稍稍耽擱一點(diǎn), 不然有時(shí) Canvas 會(huì)協(xié)調(diào)不過(guò)來(lái)}
　　　ReleaseMutex(hMutex);
　　end;
　end;
　Result := 0;
end;
procedure TForm1.Button1Click(Sender: TObject);
var
　ThreadID: DWORD;
begin
　Repaint;
　f := 0;
　CreateThread(nil, 0, @MyThreadFun, nil, 0, ThreadID);
　CreateThread(nil, 0, @MyThreadFun, nil, 0, ThreadID);
　CreateThread(nil, 0, @MyThreadFun, nil, 0, ThreadID);
　CreateThread(nil, 0, @MyThreadFun, nil, 0, ThreadID);
　CreateThread(nil, 0, @MyThreadFun, nil, 0, ThreadID);
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
　hMutex := CreateMutex(nil, False, nil);
end;
procedure TForm1.FormDestroy(Sender: TObject);
begin
　CloseHandle(hMutex);
end;
end.

窗體文件:object Form1: TForm1
　Left = 0
　Top = 0
　Caption = 'Form1'
　ClientHeight = 140
　ClientWidth = 192
　Color = clBtnFace
　Font.Charset = DEFAULT_CHARSET
　Font.Color = clWindowText
　Font.Height = -11
　Font.Name = 'Tahoma'
　Font.Style = []
　OldCreateOrder = False
　OnCreate = FormCreate
　PixelsPerInch = 96
　TextHeight = 13
　object Button1: TButton
　　Left = 109
　　Top = 107
　　Width = 75
　　Height = 25
　　Caption = 'Button1'
　　TabOrder = 0
　　OnClick = Button1Click
　end
end

　　SyncObjs 單元下有封裝好的 TMutex 類, 好像不如 Api 快, 內(nèi)部機(jī)制也稍有區(qū)別, 但使用方法差不多:unit Unit1;
interface
uses
　Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
　Dialogs, StdCtrls;
type
　TForm1 = class(TForm)
　　Button1: TButton;
　　procedure Button1Click(Sender: TObject);
　　procedure FormCreate(Sender: TObject);
　　procedure FormDestroy(Sender: TObject);
　end;
var
　Form1: TForm1;
implementation
{$R *.dfm}
uses SyncObjs;
var
　f: Integer;
　MyMutex: TMutex;
function MyThreadFun(p: Pointer): DWORD; stdcall;
var
　i,y: Integer;
begin
　Inc(f);
　y := 20 * f;
　for i := 0 to 50000 do
　begin
　　if MyMutex.WaitFor(INFINITE) = wrSignaled then
　　begin
　　　Form1.Canvas.Lock;
　　　Form1.Canvas.TextOut(20, y, IntToStr(i));
　　　Form1.Canvas.Unlock;
　　　MyMutex.Release;
　　end;
　end;
　Result := 0;
end;
procedure TForm1.Button1Click(Sender: TObject);
var
　ThreadID: DWORD;
begin
　Repaint;
　f := 0;
　CreateThread(nil, 0, @MyThreadFun, nil, 0, ThreadID);
　CreateThread(nil, 0, @MyThreadFun, nil, 0, ThreadID);
　CreateThread(nil, 0, @MyThreadFun, nil, 0, ThreadID);
　CreateThread(nil, 0, @MyThreadFun, nil, 0, ThreadID);
　CreateThread(nil, 0, @MyThreadFun, nil, 0, ThreadID);
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
　MyMutex := TMutex.Create(False);
end;
procedure TForm1.FormDestroy(Sender: TObject);
begin
　MyMutex.Free;
end;
end.